Colonne à largeur fixe

Version imprimable

11/10/2016, 13h47
ozzii

Colonne à largeur fixe
Bonjour,

dans un fichier j'ai ceci :
Code:

1 2 132 ;absdfrh ;45678 ;gdhtf 132 ;absdfrh;45678 ;gdhtf
Donc voici ma question :
Comment faire pour que ma colonne 2 aie toujours une largeur de 10 ? Mais que la seconde colonne.

J'ai bien cette commande, mais la largeur résulatante est la même pour toutes les colonnes. Je n'arrive pas à changer pour ne mettre que la seconde colonne de mon fichier.
If me faudrais surement un "if i=2" dans le awk, mais incapable de le faire.

Code:

awk -F ';' '{ for (i=1; i<=NF; i++) { printf("%-10s", $i); } print ""; }' fic.txt

Et quoi que pendant que j'y suis ; serait-t-il possible d'avoir ce même genre de chose avec la possibilité de saisir la largeur de chaque colonne ?
J'ai trouvé cela, mais je ne comprends pas comment l'intégrer ;(

Code:

BEGIN { widthlist = "20 10 30 12 ..."; split(widthlist,widths," ") } { ... printf "%-*s", widths[i],$i ...
11/10/2016, 15h48
disedorgue
Bonjour,
Voici une solution:

Code:

awk -F\; 'BEGIN{OFS=FS;split("12,20,30,40",A,",")}{i=0;while(++i<=NF)$i=sprintf("%-"A[i]"s",$i)}1' file.txt

ou par passage de variable (pas testée):
Code:

1 2 XX="12,20,30,40" awk -F\; -vIDT="$XX" 'BEGIN{OFS=FS;split(IDT,A,",")}{i=0;while(++i<=NF)$i=sprintf("%-"A[i]"s",$i)}1' file.txt
11/10/2016, 15h50
jack-ft
Citation:
Envoyé par ozzii

dans un fichier j'ai ceci :

Code:

1 2 132 ;absdfrh ;45678 ;gdhtf 132 ;absdfrh;45678 ;gdhtf

Donc voici ma question :
Comment faire pour que ma colonne 2 aie toujours une largeur de 10 ? Mais que la seconde colonne.
Le plus simple, ce serait quand même de demander au producteur du fichier de le mettre au bon format au moment de la production!

Citation:

If me faudrais surement un "if i=2" dans le awk, mais incapable de le faire.

Code:

awk -F ';' '{ for (i=1; i<=NF; i++) { printf("%-10s", $i); } print ""; }' fic.txt

J'ai supposé que tu voulais garder les ";" entre les champs:

Code:

awk -F ';' '{ for (i=1; i<=NF; i++) { if ( i == 2) { printf("%-10s", $i); } else { printf("%s", $i); if ( i != NF ) {printf(";")} }} print "" }' fic.txt

Citation:

Et quoi que pendant que j'y suis ; serait-t-il possible d'avoir ce même genre de chose avec la possibilité de saisir la largeur de chaque colonne ?
J'ai trouvé cela, mais je ne comprends pas comment l'intégrer ;(

Code:

BEGIN { widthlist = "20 10 30 12 ..."; split(widthlist,widths," ") } { ... printf "%-*s", widths[i],$i ...

Comme ça?

Code:

awk -F ';' 'BEGIN { widthlist = "20 10 30 12 ..."; split(widthlist,widths," ") } { for (i=1; i<=NF; i++) { printf("%-*s", widths[i],$i); if ( i != NF ) {printf(";")} }; print "" }' fic.txt
11/10/2016, 16h30
ozzii

Citation:

Envoyé par jack-ft

Le plus simple, ce serait quand même de demander au producteur du fichier de le mettre au bon format au moment de la production!

Oui, mais non. Là on s'attaque à un gros morceau. Dans le fichier il y a "seulement" 1% d'erreur.
Et faire un changement, c'est comme demandé à Orange de baisser ses prix ; impossible ;)

Citation:

Envoyé par jack-ft

Code:

awk -F ';' '{ for (i=1; i<=NF; i++) { if ( i == 2) { printf("%-10s", $i); } else { printf("%s", $i); if ( i != NF ) {printf(";")} }} print "" }' fic.txt

Ici le ; après la zone 2 est perdu. J'ai juste rajouté un point virgule ici. Cela à l'aire de faire l'affaire.

Code:

printf("%-10s;", $i); }

Citation:

Envoyé par jack-ft

Code:

awk -F ';' 'BEGIN { widthlist = "20 10 30 12 ..."; split(widthlist,widths," ") } { for (i=1; i<=NF; i++) { printf("%-*s", widths[i],$i); if ( i != NF ) {printf(";")} }; print "" }' fic.txt

Trop cool.

Merci jack-ft pour ton aide précieuse :lol:
11/10/2016, 20h38
jack-ft

Citation:

Envoyé par ozzii

Ici le ; après la zone 2 est perdu. J'ai juste rajouté un point virgule ici. Cela à l'aire de faire l'affaire.

Code:

printf("%-10s;", $i); }

En fait, c'était une erreur de parenthésage (je n'aime pas les commandes multiples sur une seule ligne!!!).
Je voulais dire:

Code:

awk -F ';' '{ for (i=1; i<=NF; i++) { if ( i == 2) { printf("%-10s", $i) } else { printf("%s", $i) } if ( i != NF ) {printf(";")} } print "" }' fic.txt
12/10/2016, 16h20
ozzii

Merci encore @jack-ft ;)

P.S. : Désolé @disedorgue je ne sais comment j'ai raté ton post :calim2:
Merci pour cette solution un peut plus courte.
12/10/2016, 18h51
Flodelarab

Bonjour :coucou:

Le script awk du premier message veut dire: "Pour chaque champ, écrire au moins 10 caractères".

Donc, changer pour "Pour chaque champ, si le champ est 2 alors écrire au moins 10 caractères" est ridicule. Il fallait enlever (la boucle) et non rajouter (du code).

Code:

awk -F ';' '{$2=printf("%-10s", $2);} 1' fic.txt

(pas testé)

Nota bene: 10 caractères, c'est bien, mais ... justifiés à droite ou justifiés à gauche ?

Ensuite, on peut tiquer car les deux questions posées sont opposées.
En effet les champs de longueur fixe permettent de s'en sortir avec un fichier sans délimiteur ';'.
Or le fichier en a !! (des points-virgules)
Est-ce que tu transformes ton fichier texte pour supprimer les délimiteurs ?
Sinon, tu avais déjà repéré les champs.
Bizarre.
12/10/2016, 18h58
ozzii
@Flodelarab
Alors pour être encore plus précis :
J'ai un fichier avec des champs fixes ET avec délimiteurs.
Cependant de temps en temps dans le fichier le champs 2 n'est plus en longueur fixe.
De ce fait, il me fallait une commande qui me permette de passer ce champs en fixe.
Et comme c'est avec délimiteur, c'est en justifié à gauche (comme dans mon exemple en début de discussion).

Voici le résultat de ta commande :
Code:

1 2 3 4 5 syntax error The source line is 1. The error context is >>> {$2=printf <<< ("%-10s", $2);} 1 awk: The statement cannot be correctly parsed. The source line is 1.
13/10/2016, 07h24
BufferBob
salut,
Citation:
Envoyé par ozzii

Voici le résultat de ta commande :

Code:

1 2 3 4 5 syntax error The source line is 1. The error context is >>> {$2=printf <<< ("%-10s", $2);} 1 awk: The statement cannot be correctly parsed. The source line is 1.
je pense que c'est une typo, il fallait lire sprintf au lieu de printf, mais il faut aussi spécifier explicitement un délimiteur de champs en sortie sans quoi les point-virgule disparaissent :

Code:

awk -F ';' '{OFS=";"; $2=sprintf("%-10s", $2);} 1' fichier
17/10/2016, 10h56
ozzii

Désolé pour la réponse tardive ;(

@BufferBob
C'est bien cela.
Ta commande fonctionne très bien.

Merci encore à tous pour votre aide :D