Script pour supprimer ligne dans Excel

Version imprimable

05/10/2016, 23h14
bishope

Script pour supprimer ligne dans Excel

Bonjour,

Je souhaiterais supprimer la première ligne de plusieurs fichiers Excel em même temps par le biais d'un script.
Je ne sais pas comment m'y prendre.

Merci encore pour votre aide.

Salut,
commence par construire la liste des fichiers concernés : Liste des fichiers d'un dossier + Liens
Utilise l'enregistreur de macro pour dégrossir la syntaxe de suppression de ligne : Excel et l'enregistreur de macro
Ensuite en balayant la liste des fichiers concernés avec la procédure idoine tu devrais arriver au résultat.

Re, Un embryon de réponse, affecte un bouton à la procédure SelectionFichier

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Option Explicit
 
Sub SelectionFichier()
Dim FD As FileDialog
 
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = ThisWorkbook.Path & "\"
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "xls", "*.xls*", 1
        .ButtonName = "Ouvrir fichier"
        .Title = "Sélectionner un fichier Excel"
    End With
 
    If FD.Show = True Then
        DoEvents
        DelLigne FD.SelectedItems(1)
    End If
 
    Set FD = Nothing
End Sub
 
Private Sub DelLigne(sFichier As String)
Dim Wkb As Workbook, Wsh As Worksheet
    Application.ScreenUpdating = False
    Set Wkb = Workbooks.Open(sFichier)
    Set Wsh = Wkb.Worksheets(1)
 
    Wsh.Rows("1:1").Delete Shift:=xlUp
 
    Application.DisplayAlerts = False
    Wkb.SaveAs Filename:=sFichier
    Wkb.Close
    With Application
        .DisplayAlerts = True
        .ScreenUpdating = True
    End With
    Set Wsh = Nothing
    Set Wkb = Nothing
End Sub

06/10/2016, 04h04
bishope
Merci je vais essayer cela.
On pourrait générer un exe ou en powershell pour effectuer l'action ?

J'avais trouvé ce code la em vba qui faisait le boulot
Code:

1 2 3 Sub sbVBS_To_Delete_EntireRow() Rows(1).EntireRow.Delete End Sub
Mais je sais pas comment automatiser ça sur plusieurs fichiers Excel différent.

Re, toujours un embryon mais plus élaboré, ici la feuille "Feuil2" est concernée si elle existe.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Option Explicit
 
Sub SelectionFichier()
Dim FD As FileDialog
 
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = ThisWorkbook.Path & "\"
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "xls", "*.xls*", 1
        .ButtonName = "Ouvrir fichier"
        .Title = "Sélectionner un fichier Excel"
    End With
 
    If FD.Show = True Then
        DoEvents
        Application.StatusBar = ""
        DelLigne FD.SelectedItems(1)
    End If
 
    Set FD = Nothing
End Sub
 
Private Sub DelLigne(sFichier As String)
Dim Wkb As Workbook, Wsh As Worksheet, sFeuille As String
 
    Application.ScreenUpdating = False
 
    sFeuille = "Feuil2"
 
    Set Wkb = Workbooks.Open(sFichier)
 
    If FeuilleExiste(Wkb.Name, sFeuille) Then
        Set Wsh = Wkb.Worksheets(sFeuille)
        Wsh.Rows("1:1").Delete Shift:=xlUp
        Application.DisplayAlerts = False
        Wkb.SaveAs Filename:=sFichier
        Application.DisplayAlerts = True
        Set Wsh = Nothing
    End If
 
    Wkb.Close
    Set Wkb = Nothing
 
    Application.ScreenUpdating = True
End Sub
 
 
Private Function FeuilleExiste(sClasseur As String, sFeuille As String) As Boolean
Dim v As Variant
    v = Evaluate("ISREF('[" & sClasseur & "]" & sFeuille & "'!A1)")
    FeuilleExiste = IIf(IsError(v), False, v)
End Function

Salut, pour traiter des fichiers en masse voir lien du post# 2 et l'adapter à ton contexte.

06/10/2016, 06h17
bishope

Je vais tester tt ça demain
Je te tiens au courant.
En tt cas merci merci bien
06/10/2016, 06h50
kiki29

2 pièce(s) jointe(s)

Salut, une version qui fonctionne ici sur les "Feuil2" de mes tests, donc à adapter à ton contexte ( dans Private Sub DelLigne(sFichier As String) sFeuille = .... ). Bref cela fait un peu marteau-pilon pour écraser des noisettes .....
06/10/2016, 20h03
bishope

Hey :)))
Ca fonctionne c'est super merci beaucoup.
Penses-tu qu'il est possible de script cela maintenant ?
Genre je lance un exe et bam ca execute l'action qui est faite par le bouton "Supprimer Ligne".

Merci encore c'est super sympa
06/10/2016, 21h34
Marc-L

Bonjour.

Citation:

Envoyé par bishope

Penses-tu qu'il est possible de script cela maintenant ?

Cela veut dire en français ?

Citation:

Envoyé par bishope

On pourrait générer un exe ou en powershell pour effectuer l'action ?

Citation:

Envoyé par bishope

Genre je lance un exe

Cela n'existe pas en VBA, erreur de casting de forum !

_________________________________________________________________________________________________________
Je suis Paris, Nice, Bruxelles, Charlie, …
06/10/2016, 21h41
bishope

En fait le fichier correspond exactement à ce que je veux. Cependant il reste 2 actions manuels à effectuer.
1- mettre une croix devant chaque fichier dont on veut enlever la ligne (colonne A)
2- cliquer sur "supprimer ligne"

Au lieu de faire les 2 actions suivantes J'aimerais une commande pouvant être lancée de façon automatique.

Re, un embryon de VBS à adapter à ton contexte, en te rappelant ceci.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim sChemin,i,lR
sChemin = "C:\Essais\Supprimer_Ligne.xls"
Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run chr(34) & sChemin & chr(34)
WScript.sleep 250
set xl =GetObject(, "Excel.application")
lR = xl.worksheets("Param").UsedRange.Rows.Count
for i= 6 to lR
xl.worksheets("Param").cells(i,1)="x"
Next
xl.Workbooks("Supprimer_Ligne.xls").Application.Run "Delete"
xl.DisplayAlerts=false
xl.ActiveWorkbook.SaveAs sChemin
xl.Workbooks.Close
xl.Application.Quit

10/10/2016, 07h33
clementmarcotte

Mais de toutes façons, c'est impossible de le faire en même temps avec VBA ou avec VBS. Ils sont mono-tâches.

:lol:
10/10/2016, 09h04
kiki29

Salut, je te laisse le soin d'œuvrer avec les options idoines dans le SCRIPT VBS pour WshShell.Run ... et xl. ... pour en réduire l'impact visuel.
11/10/2016, 13h59
Igloobel

Bonjour,

Citation:

Envoyé par bishope

En fait le fichier correspond exactement à ce que je veux. Cependant il reste 2 actions manuels à effectuer.
1- mettre une croix devant chaque fichier dont on veut enlever la ligne (colonne A)
2- cliquer sur "supprimer ligne"

Au lieu de faire les 2 actions suivantes J'aimerais une commande pouvant être lancée de façon automatique.

je ne mettrais pas une croix devant chaque fichier mais j'utiliserai : les FileDialog et en particulier msoFileDialogFilePicker qui permet de sélectionner plusieurs fichiers et de les gérer les uns après les autres de façon automatique
il y a plein d'Excel dans l'aide en ligne :f1: