DoCmd.TransferDatabase : export de table - Ajout numéro incrémenté si table destination existe déjà

Version imprimable

Bonjour!

Je bute sur un petit problème pour exporter un table vers une autre base de données : mon code me permet d'exporter MATABLE vers MABASE_DESTINATION en y créant une nouvelle table appelée "Export"
Code:

1 2 3 4 5 6 7 8 9 10 11 Private Sub Commande30_Click() Dim strFile As String strFile = "E:\MONDOSSIER\MABASE_DESTINATION.accdb" If CurrentProject.Name Like "MABASE*.accdb" Then DoCmd.TransferDatabase acExport, "Microsoft Access", strFile, acTable, "MATABLE", "Export" End If End Sub
Le problème, c'est que la table "Export" peut déjà exister dans MABASE_DESTINATION. Dans ce cas :
- La table "Export" doit être conservée
- J'aimerais que MATABLE soit exportée sous le nom "Export1"

De même, si des tables "Export" et "Export1" existent déjà dans MABASE_DESTINATION, j'aimerais que MATABLE soit exportée sous le nom "Export2"...et ainsi de suite :aie:.

Je sais qu'il est possible de tester l'existence d'une table précise, mais je ne vois pas comment utiliser ce genre de fonction pour résoudre mon problème, et encore moins pour accoler un numéro incrémenté au nom de ma table de destination!

Merci d'avance pour vos lumières, je n'ai pas encore l'électricité :roll: !
Et bonne soirée à tous!

Bonsoir,

C'est du pur VBA avec exploration des objets de la base en utilisant DAO:

Déclaration d'une fonction pour tester si la table existe dans un module indépendant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Public Function FindTable(db As DAO.Database, nomTable As String) As Boolean
Dim i As Long
 
For i = 0 To db.TableDefs.Count - 1
 
   If db.TableDefs(i).Name = nomTable Then
      FindTable = True
      Exit Function
   End If
 
Next i
 
FindTable = False
 
End Function

Puis, votre code devient :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub Commande30_Click()
Dim strFile As String
Dim db As DAO.Database
Dim i As Long
Dim nomTable As String
 
strFile = "E:\MONDOSSIER\MABASE_DESTINATION.accdb"
 
Set db = OpenDatabase(strFile)
 
nomTable = "Export"
 
i = 0
 
Do While FindTable(db, nomTable) ' recherche du nom libre pour la table export
   i = i + 1
   nomTable = "Export" & i
Loop
 
db.Close ' fermeture de la base
Set db = Nothing
 
   If CurrentProject.Name Like "MABASE*.accdb" Then
      DoCmd.TransferDatabase acExport, "Microsoft Access", strFile, acTable, "MATABLE", nomTable
   End If
 
End Sub

Cdlt,

16/09/2016, 11h43
Capileba

Merci beaucoup pour ton aide, ça marche parfaitement!

:D:D:mrgreen::mrgreen::D:D

Bonne journée!
16/09/2016, 20h49
User

Tant mieux :ccool: