Vbs chercher et remplacer mais pas le texte recherché

Version imprimable

Bonjour,

N'étant pas trop familiarisé avec le vbs,

Je souhaite rechercher un texte dans un fichier txt puis remplacer une autre valeur si elle est trouvée sur la même ligne.
J'ai déjà trouvé ce script sui me permet de remplacer du texte
Code:

1 2 3 4 5 6 7 8 9 10 Const ForReading = 1 Const ForWriting = 2 Set objFSO = CreateObject("Scripting.FileSystemObject" ) Set objFile = objFSO.OpenTextFile("CHEMIN\FICHIER.TXT", ForReading) strText = objFile.ReadAll objFile.Close strNewText = Replace(strText, "backup", "OK backup") Set objFile = objFSO.OpenTextFile("CHEMIN\FICHIER2.TXT", ForWriting) objFile.WriteLine strNewText objFile.Close
dans ce scipt, le mot backup est remplacé par OK backup

ce que je souhaite faire c'est rechercher le mot success et remplacer le mot backup par OK backup en fonction de la réussite de la recherche du mot success.
exemple :
backup xxx success
backup yyy failed

après modification :
OK backup xxx success
backup yyy failed

cela fait un moment que je cherche sans trouver.

Merci d'avance pour votre aide !
batist3

Salut

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Const ForReading = 1
Const ForWriting = 2
Set objFSO = CreateObject("Scripting.FileSystemObject" )
Set objFile = objFSO.OpenTextFile("CHEMIN\FICHIER.TXT", ForReading)
strText = objFile.ReadAll
objFile.Close
If InStr(1, strText, "success", vbTextCompare) <> 0 Then 'si une occurrence été trouvée, une position a été retournée
	strNewText = Replace(strText, "backup", "OK backup")
	Set objFile = objFSO.OpenTextFile("CHEMIN\FICHIER2.TXT", ForWriting)
	objFile.WriteLine strNewText
	objFile.Close
End If

Merci pour cette réponse rapide

Cependant, en faisant le test cela ne fonctionne pas.
voici le test que j'ai fait

texte du fichier1.txt
backup success
backup failed

contenu du fichier vbs
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Const ForReading = 1 Const ForWriting = 2 Set objFSO = CreateObject("Scripting.FileSystemObject" ) Set objFile = objFSO.OpenTextFile("C:\Users\Utilisateur\Desktop\fichier1.txt", ForReading) strText = objFile.ReadAll objFile.Close If InStr(1, strText, "success", vbTextCompare) <> 0 Then 'si une occurrence été trouvée, une position a été retournée strNewText = Replace(strText, "backup", "OK backup") Set objFile = objFSO.OpenTextFile("C:\Users\Utilisateur\Desktop\fichier2.txt", ForWriting) objFile.WriteLine strNewText objFile.Close End If
Résultat du fichier2.txt
OK backup success
OK backup failed

le résultat attendu étant :
OK backup success
backup failed

Je me suis trompé quelque part ?

30/08/2016, 19h40
ProgElecT

Essais, ligne 8, avec ce code légèrement modifié

Code:

strNewText = Replace(strText, "backup", "OK backup", 1, -1, vbTextCompare)
30/08/2016, 20h17
ProgElecT

:oops: toujours ligne 8

Code:

strNewText = Replace(strText, "backup", "OK backup", 1, 1, vbTextCompare)

comme quoi un moins (le signe - du 6° paramètre) te donnais un + dans le remplacement :mouarf:
30/08/2016, 20h41
batist3

Désolé mais cela ne marche toujours pas

après différents test, ce script permet de vérifier la présence du terme success
s'i est présent cela modifie toutes les lignes contenant le mot backup
s'il est absent, le texte n'est pas modifié

exemple
fichier1 :
backup xxx success
backup yyy failed
backup zzz success

vu qu'il y a au moins un success dans le fichier, toutes les lignes seront modifiées avec OK backup
J'aimerai mettre le OK backup seulement devant les lignes contenant success
et un autre script avec KO backup failed

avec tes dernières instructions, cela ne modifie que la première ligne.
si le texte1 contient :
backup xxx failed
backup yyy success

le résultat sera
OK backup xxx failed

Je pense que si il existe une commande pour vérifier ligne par ligne si le terme existe et remplace le mot backup par OK backup, cela fonctionnera
A priori je vois des références à split mais je ne sais pas si ça a un rapport avec ce que je cherche

Merci en tout cas de ton intérêt
je me répète mais je suis novice en vbs.

Peut-être avec ce

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Const ForReading = 1
Const ForWriting = 2
Set objFSO = CreateObject("Scripting.FileSystemObject" )
Set objFile = objFSO.OpenTextFile("C:\Users\Utilisateur\Desktop\fichier1.txt", ForReading)
 
    Do While  Not objFile.AtEndOfStream
        strText = objFile.ReadLine
        If InStr(1, LCase(strText), "success", vbTextCompare) <> 0 Then 'si une occurrence été trouvée, une position a été retournée
            strNewText = strNewText & Replace(strText, "backup", "OK backup")  & vbNewLine
        Else
            strNewText = strNewText & strText & vbNewLine
        End If
    Loop
    objFile.Close
 
    Set objFile = objFSO.OpenTextFile("C:\Users\Utilisateur\Desktop\fichier1.txt", ForWriting)
    objFile.Write strNewText
    objFile.Close

[EDIT] Mais attention, si on ré-exécute le script, on va avoir 'OK OK backup' et à chaque exécution, un autre OK est ajouté.
Pour y remédier, on doit rajouter une condition sur la ligne lue : La ligne 8 deviendrait

Code:

1
2
If InStr(1, LCase(strText), "success", vbTextCompare) <> 0 And _
            InStr(1, LCase(strText), "ok backup", vbTextCompare) = 0 Then

30/08/2016, 22h08
ProgElecT

batist3 ton debut de discussion

Citation:

ce que je souhaite faire c'est rechercher le mot success et remplacer le mot backup par OK backup en fonction de la réussite de la recherche du mot success.
exemple :
backup xxx success
backup yyy failed

après modification :
OK backup xxx success
backup yyy failed

cela fait un moment que je cherche sans trouver.

Merci d'avance pour votre aide !
batist3

j'avais compris que le fichier ne contenait que 2 lignes.
l_autodidacte,:coucou:, te propose une bonne solution pour un fichier de x nombre de lignes.

Désolé , je n'ai vu la remarque concernant le KO qu'après avoir modifié le post
En somme, voici le script final si j'ose dire :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Const ForReading = 1
Const ForWriting = 2
Set objFSO = CreateObject("Scripting.FileSystemObject" )
Set objFile = objFSO.OpenTextFile("C:\Users\Utilisateur\Desktop\fichier1.txt", ForReading)
 
    Do While  Not objFile.AtEndOfStream
        strText = objFile.ReadLine
        If InStr(1, LCase(strText), "success", vbTextCompare) <> 0 And _
            InStr(1, LCase(strText), "ok backup", vbTextCompare) = 0 Then 
            strNewText = strNewText & Replace(strText, "backup", "OK backup")  & vbNewLine
        ElseIf InStr(1, LCase(strText), "failed", vbTextCompare) <> 0 And _
            InStr(1, LCase(strText), "ko backup", vbTextCompare) = 0 Then 
            strNewText = strNewText & Replace(strText, "backup", "KO backup")  & vbNewLine
        Else
            strNewText= strNewText & strText & vbNewLine
        End If
    Loop
    objFile.Close
 
    Set objFile = objFSO.OpenTextFile("C:\Users\Utilisateur\Desktop\fichier1.txt", ForWriting)
    objFile.Write strNewText
    objFile.Close

30/08/2016, 22h13
batist3

Magnifique !!

Ca fonctionne parfaitement.

Un grand MERCI à vous deux ! :D
30/08/2016, 22h26
l_autodidacte

Citation:

Je lance ce script pour les OK Sauvegarde success
et un autre pour les KO Sauvegarde failed
Y-a t'il un moyen de fusionner les deux script en un seul ?

:koi: Un peu plus d'explications ou un début de code serait plus explicite...:koi:
S'il s'agit de remplacer Sauvegarde par OK Sauvegarde et/ou KO sauvegarde, il suffit d'ajouter des conditions telles que celles dans le dernier script.
30/08/2016, 22h39
batist3

Citation:

Envoyé par l_autodidacte

:koi: Un peu plus d'explications ou un début de code serait plus explicite...:koi:
S'il s'agit de remplacer Sauvegarde par OK Sauvegarde et/ou KO sauvegarde, il suffit d'ajouter des conditions telles que celles dans le dernier script.

En fait je cherchais en réalité à ajouter un texte avant le mot backup en fonction du résultat du log de sauvegarde (success ou failed situé à la fin de la ligne)

Pour mon premier post, je me suis surement mal exprimé.
de plus, le début de code aurait été très compliqué (pour moi) à expliquer.
je passe par un batch qui reprend une trentaine de fichier log pour fusionner la première ligne dans un seul fichier puis 2 vbs dont celui ci pour le franciser et le formater au format html et enfin l'envoyer par mail.

J'essaierai d'être plus précis la prochaine fois.