Tableau indicé par des string

Version imprimable

13/07/2016, 13h06
ponteprimo

Tableau indicé par des string
Bonjour,
Je voudrais indicer mon tableau par des string.
Exemple : ( On saisit le mois et on stocke dans la chaine MoisEnCours ).

Je veux constituer un tableau :
Code:

1 2 3 monTAB ("Légumes" , MoisEnCours ) = "10 kg" monTAB ("Fromages" , MoisEnCours ) = "8,5 kg" monTAB ("Fruits" , MoisEnCours ) = "2 kg"
Quand je fais :

Code:

monTAB ("Fruits" , MoisEnCours ) = monTAB ("Fruits" , MoisEnCours ) + 5 ' Ajout de 5 kg pour le mois en cours

J'ai un message popup : "Incompatibilité de type"

J'ai déjà fait ça en PHP mais en VBA ... (???).
Merci de votre aide.
13/07/2016, 18h16
Jean-Philippe André
Salut,

je pense que tu cherches l'object Collection :
Code:

1 2 3 4 5 Sub piou() Dim a As New Collection a.Add "plop", "plip" Debug.Print a("plip") End Sub
13/07/2016, 18h28
Slooby

Bonjour,

Je ne suis pas sûr qu'une collection fasse l'affaire, car il y a 2 paramètres.
A la rigueur un Dico de dico, mais c'est complexe.

Car ce que tu veux c'est obtenir un nombre (le poids) en utilisant 2 clés de type String (le nom du légume, et la date)

Pleins de choix s'offrent à toi, tous avec des avantages/défauts et différents niveaux de complexité.

Le mieux serait un Dico de Dico je pense, mais sinon, si tu est débutant, tu peux penser à utiliser une feuille Excel comme tableau de stockage.
Et utiliser le tableau Excel comme un tableau (tes fruits/légumes en tête de tableau) et en colonne les Dates.

C'est pas optimal, mais si ça peut marcher pourquoi pas. Tout dépend de ton niveau.

Désolé de ne pas pouvoir t'aider plus.

Slooby
13/07/2016, 18h35
Jean-Philippe André

Pour gerer la double cle, perso j'utilise une concatenation avec un | en separateur

Code:

a.Add "plop", "plip|plap"

mais le debat reste ouvert sur le dico de dico :aie:
13/07/2016, 18h47
Marc-L

Bonjour,

tout dépend du volume de données et le traitement à réaliser mais avec une présentation si légère …

Car déjà avec juste une variable tableau supplémentaire stockant les noms
et via la simple fonction de formule de calculs EQUIV (et oui, même en VBA !) on a l'indice de la position du nom …
Là aussi on peut utiliser une collection pour juste ressortir cet indice …

Le nombre d'éléments (les noms) doit être connu pour pouvoir dimensionner la première dimension du tableau MonTAB
au préalable car elle n'est pas redimensionnable en cours de traitement, cf l'aide VBA …

Diverses autres possibilités comme effectivement la clef concaténée avec une collection ou un dictionnaire …

_________________________________________________________________________________________________________
Je suis Paris, Charlie, Bruxelles, …
14/07/2016, 00h02
patricktoulon

re

bonsoir en vba on peut pas faire comme ca

Code:

monTAB ("Légumes" , MoisEnCours ) = "10 kg"

si on considère que montab est un tableau il doit etre indicé par des numériques (ligne, colonne) et on ne peut pas lui attribuer une valeur (=5)

je pense qu'il va falloir soit faire un tableau de tableau soit un dico voir dico de dico

Code:

set mondico=createobject("Scripting.Dictionary")

'on créé l'entré de mes patates

Code:

mondico("légumes" & moisencours)=5

si demain je reviens au marché et que j'en rachète un peu plus parce que mes patates elles étaient bonnes et même si il m'en reste encore
alors j'ajoute

Code:

mondico("légumes" & moisencours)=mondico("légumes" & moisencours)+2

ce matin j'en ai fait cuir 3 kilos
alors

Code:

mondico("légumes" & moisencours)=mondico("légumes" & moisencours)-3

le mois prochain je refait mes courses
je rachète donc des patates (j'aime beaucoup les patates ) mais attention il m'en reste du mois dernier alors
j'achète 10 kilo (purré qu'est ce que j'en bouffe de cucurbitacée)
et je met mon stock a jour

Code:

mondico("légumes" & moisencours)=mondico("légumes" & moisencours-1)+10

attention cependant a enregistrer les donné sur sheets pour les recalculer par la suite a l'ouverture du fichier ou autre un dico travaillant principalement en mémoire se détruit a la fermeture d'Excel on est pas en PHP hein!!!!!

demain j'aimerais bien une bonne purrée faite maison avec un peut de beurre salée au sel de Guérande
tu m'appelle quand c'est prêt
;)
04/08/2016, 08h53
ponteprimo

Dico de purée alors ...

Je vais effectivement utiliser le dico de purée ...
Merci patricktoulon, et merci aux autres contributeurs ...

Bonjour,

Citation:

Envoyé par ponteprimo

Code:

1
2
3
monTAB ("Légumes" , MoisEnCours ) = "10 kg"
monTAB ("Fromages" , MoisEnCours ) = "8,5 kg"
monTAB ("Fruits"     , MoisEnCours ) = "2 kg"

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public Dico As Object
 
Property Let monTAB(TypeArticle As String, MoisEnCours As String, Value As String)
    If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
     Dico(TypeArticle & "_" & MoisEnCours) = Value
End Property
 
Property Get monTAB(TypeArticle As String, MoisEnCours As String) As String
    If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
 monTAB = Dico(TypeArticle & "_" & MoisEnCours)
End Property
 
Sub test()
Dim MoisEnCours As String
MoisEnCours = "Janvier"
    monTAB("Légumes", "Janvier") = "10 kg"
   Debug.Print monTAB("Légumes", "Janvier")
 
monTAB ("Légumes" , MoisEnCours ) = "10 kg"
monTAB ("Fromages" , MoisEnCours ) = "8,5 kg"
monTAB ("Fruits"     , MoisEnCours ) = "2 kg"
End Sub

Édite:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Public Dico As Object
 
Property Let monTAB(TypeArticle As String, MoisEnCours As String, Value As Double)
    If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
     Dico(TypeArticle & "©" & MoisEnCours) = Value
End Property
 
Property Get monTAB(TypeArticle As String, MoisEnCours As String) As Double
    If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
 monTAB = Dico(TypeArticle & "©" & MoisEnCours)
End Property
 
Sub test()
Dim MoisEnCours As String
MoisEnCours = "Janvier"
monTAB("Légumes", MoisEnCours) = monTAB("Légumes", MoisEnCours) + 5
Debug.Print monTAB("Légumes", MoisEnCours)
monTAB("Légumes", MoisEnCours) = monTAB("Légumes", MoisEnCours) + 2
Debug.Print monTAB("Légumes", MoisEnCours)
monTAB("Légumes", MoisEnCours) = monTAB("Légumes", MoisEnCours) * 100
Debug.Print monTAB("Légumes", MoisEnCours)
monTAB("Légumes", MoisEnCours) = monTAB("Légumes", MoisEnCours) + -100
Debug.Print monTAB("Légumes", MoisEnCours)
Set Dico = Nothing
End Sub