Création d'un événement dynamique sur Timer

Version imprimable

Bonjour,

J'aimerais réaliser un petit programme (non graphique) qui utilise un timer... J'ai beau rechercher sur internet, je ne vois pas comment faire.
Au niveau de la déclaration je pense que je suis sur la bonne voie, mais pour affecter dynamiquement l'événement OnTimer à l'objet TFPTimer, là, je sèche.

Voilà ce que j'ai fait, si quelqu'un peut me donner des pistes pour affecter l’événement au timer, ce serait sympa...
(Je ne suis même pas certain que je sois obligé de déclarer le type TTps...)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 program Project1; {$mode objfpc}{$H+} uses {$IFDEF UNIX}{$IFDEF UseCThreads} cthreads, {$ENDIF}{$ENDIF} Classes, fptimer { you can add units after this }; type TTps = class(TFPTimer) end; var tps : TTps; begin try tps := TTps.Create(nil); writeln('Avant Timer :'); tps.Interval:=30000; tps.Enabled:=true; writeln('Apres timer :'); finally tps.Free; end; end.
Merci

hello,
dans le répertoire de lazarus lazarus_xxxx\fpc\x.x.x\source\packages\fcl-base\examples il y a un exemple d'utilisation d'un timer sous un programme console (testtimer.pp)
voici son contenu :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{$mode objfpc}
{$H+}
program testtimer;
 
uses 
{$ifdef unix}
  cthreads,
{$endif}
  sysutils,classes,custapp,fptimer;
 
Type
  TTestTimerApp = Class(TCustomApplication)
  Private
    FTimer : TFPTimer;
    FCount : Integer;
    FTick : Integer;
    N : TDateTime;
  Public  
    Procedure DoRun; override;
    Procedure DoTick(Sender : TObject);
  end;
 
Procedure TTestTimerApp.DoRun; 
 
begin
  FTimer:=TFPTimer.Create(Self);
  FTimer.Interval:=100;
  FTimer.OnTimer:=@DoTick;
  FTimer.Enabled:=True;
  Try
    FTick:=0;
    FCount:=0;
    N:=Now;
    While (FCount<10) do
      begin
      Inc(FTick);
      Sleep(1);
      CheckSynchronize; // Needed, because we are not running in a GUI loop.
      end;
  Finally
    FTimer.Enabled:=False;
    FreeAndNil(FTimer);
  end;
  Terminate;
end;
 
Procedure TTestTimerApp.DoTick(Sender : TObject);
 
Var
  D : TDateTime;
 
begin
  Inc(FCount);
  D:=Now-N;
  Writeln('Received timer event ',FCount,' after ',FTick,' ticks. (Elapsed time: ',FormatDateTime('ss.zzz',D),')');
  FTick:=0;
  N:=Now;
end;
 
 
begin
  With TTestTimerApp.Create(Nil) do
    Try
      Run
    finally
      Free;
    end;  
end.

L'affectation de la procédure appelée par le timer se fait par :

Code:

FTimer.OnTimer:=@DoTick;

ami calmant, J.P

29/06/2016, 10h03
Manusm

Merci beaucoup ! Je n'ai pas du tout pensé à regarder ici