Algo de fusion de tableaux

Version imprimable

10/06/2016, 14h09
mnlin88

1 pièce(s) jointe(s)

Algo de fusion de tableaux

Bonjour,
novice dans la programmation procédurale pl/sql, j'essaie de m'exercer depuis peu mais je reste bloqué depuis plusieurs jours sur mon tout premier programme que voici :
Pièce jointe 212412

On me d'écrire le bloc PL/SQL qui programme la fusion de deux tableaux (déjà triés par ordre croissant) en un seul (utiliser des structures WHILE…).
Je vous prie de bien vouloir m'aider à le réaliser.
merci
10/06/2016, 14h13
Ikebukuro

Dans quel ordre se fait la fusion?
Le tableau final n'est pas trié ou alors je ne sais pas comment; pourquoi on doit avoir Alitalia après Aeris et avant Air France?
10/06/2016, 14h21
mnlin88

oui le tableau final doit être trié
10/06/2016, 15h00
Ikebukuro

OK, je comprends que le tableau final doit être trié mais trié selon quel critère? Critère alphabétique? Les noms en majuscules avant les minuscules? Tri selon l'ordre binaire ou de langue?

Si c'est un critère alphabétique, ALITALIA devrait être après Air France.
10/06/2016, 15h42
mnlin88

le tableau doit être trié de façon alphabétique...la casse n'a pas vraiment d'importance
10/06/2016, 16h59
Ikebukuro

Dans ce cas là, dans l'image, TAB_RESULTAT est faux; Alitalia doit être juste avant Quantas.

Après plusieurs recherches, j'ai pu trouver la solution que voici :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
SET SERVEROUTPUT ON
DECLARE
TYPE nomComp_tytab IS TABLE OF VARCHAR2(15) INDEX BY BINARY_INTEGER;
-- tableaux
  tab_compFrance nomComp_tytab;
  tab_compMonde nomComp_tytab;
  tab_résultat nomComp_tytab;
  v_indiceFrance NUMBER(1) := 1;
  v_indiceMonde NUMBER(1) := 1;
  v_indiceRésultat NUMBER(2) := 1;
BEGIN
  tab_compFrance(1) := 'AERIS';
  tab_compFrance(2) := 'Air France';
  tab_compFrance(3) := 'Air Littoral';
  tab_compFrance(4) := 'Regional';
  tab_compMonde(1) := 'ALITALIA';
  tab_compMonde(2) := 'Quantas';
  tab_compMonde(3) := 'SABENA';
  tab_compMonde(3) := 'SABENA';
-- parcours des deux tableaux en parallèle (stop à la fin d’un des 2)
  WHILE (tab_compFrance.EXISTS(v_indiceFrance) AND tab_compMonde.EXISTS(v_indiceMonde)) LOOP
    IF tab_compFrance(v_indiceFrance) > tab_compMonde(v_indiceMonde)THEN
      tab_résultat(v_indiceRésultat) := tab_compMonde(v_indiceMonde);
      v_indiceMonde := v_indiceMonde + 1;
    ELSE
      tab_résultat(v_indiceRésultat) := tab_compFrance(v_indiceFrance);
      v_indiceFrance := v_indiceFrance + 1;
    END IF;
      v_indiceRésultat := v_indiceRésultat + 1;
  END LOOP;
-- Traitement de la fin du tableau qui reste à parcourir
  WHILE (tab_compFrance.EXISTS(v_indiceFrance)) LOOP
    tab_résultat(v_indiceRésultat) := tab_compFrance(v_indiceFrance);
    v_indiceRésultat := v_indiceRésultat + 1;
    v_indiceFrance := v_indiceFrance + 1;
  END LOOP;
  WHILE (tab_compMonde.EXISTS(v_indiceMonde)) LOOP
    tab_résultat(v_indiceRésultat) := tab_compMonde(v_indiceMonde);
    v_indiceRésultat := v_indiceRésultat + 1;
    v_indiceMonde := v_indiceMonde + 1;
  END LOOP;
-- Affichage des résultats
  DBMS_OUTPUT.PUT_LINE('Nombre éléments de tab_résultat ' || tab_résultat.COUNT);
  FOR v_entier IN 1 ..tab_résultat.COUNT LOOP
    DBMS_OUTPUT.PUT_LINE('tab_résultat(' || v_entier || ') : ' || tab_résultat(v_entier));
  END LOOP;
END;

Utilisez des collections et opérateurs ensembliste des collections et laissez le moteur SQL faire le tri

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
Connected to Oracle Database 11g Enterprise Edition Release 11.2.0.3.0 
 
SQL> CREATE OR REPLACE Type varchar2_tt As Table Of Varchar2(30)
  2  /
Type created
 
SQL> alter session set NLS_SORT = Binary
  2  /
Session altered
 
SQL> set serveroutput on
SQL> 
SQL> DECLARE
  2  -- tableaux
  3    tab_compFrance varchar2_tt := varchar2_tt('AERIS', 'Air France', 'Air Littoral', 'Regional');
  4    tab_compMonde  varchar2_tt := varchar2_tt('ALITALIA', 'Quantas', 'SABENA', 'SABENA');
  5    tab_resultat   varchar2_tt;
  6  BEGIN
  7    tab_resultat := tab_compFrance Multiset Union Distinct tab_compMonde;
  8    --
  9    select cast ( multiset( select *
 10                            from table( tab_resultat)
 11                            order by 1
 12                           ) as varchar2_tt)
 13     into tab_resultat
 14     from dual;
 15    --
 16    FOR v_entier IN 1 ..tab_resultat.COUNT LOOP
 17      DBMS_OUTPUT.PUT_LINE('tab_résultat(' || v_entier || ') : ' || tab_resultat(v_entier));
 18    END LOOP;
 19  End;
 20  /
tab_résultat(1) : AERIS
tab_résultat(2) : ALITALIA
tab_résultat(3) : Air France
tab_résultat(4) : Air Littoral
tab_résultat(5) : Quantas
tab_résultat(6) : Regional
tab_résultat(7) : SABENA
PL/SQL procedure successfully completed
 
SQL>