Supprimer ligne contenant un mot précis

Version imprimable

22/03/2016, 13h26
Francis L

Supprimer ligne contenant un mot précis
Bonjour,

J'ai lu cette discussion.
Citation:
Envoyé par DjiLow

Ben je viens de trouver une solution qui fonctionne à l'instant

Code:

1 2 3 4 5 6 Sub SupLign() Dim i As Long For i = Range("B65536").End(xlUp).Row To 1 Step -1 If Not UCase(Cells(i, 2).Value) Like UCase("*ordinateur*") Then Rows(i).Delete Next i End Sub

Merci quand même zyhack :ccool:
Effectivement cette macro fonctionne très bien.

J'aimerais savoir comment on peut l'appliquer sur toutes les feuilles d'un même fichier.

En parcourant simplement toutes les feuilles de ton classeur :)
Code:

1 2 3 4 5 6 Dim sheet As Worksheet For Each sheet In Sheets sheet.Activate 'Ici le code à faire..... Next

22/03/2016, 13h59
Francis L

Super. Fonctionne très bien.

Je ne suis pas un expert en VBA. Si je voudrait y ajouter des mots, je m'y prend comment. Exemple: si je voudrais en plus du mot 'ordinateur' les mots 'clavier' et 'souris'. Je suppose que c'est simple, mais je suis débutant.
22/03/2016, 14h01
cerede2000

Il faudrait partir sur la gestion de ces mots dans un tableau par exemple pour les stocker et les modifier de manière simple.
Et dans le traitement parcourir ce tableau pour vérifier chaque mots.
22/03/2016, 14h12
Francis L

Malheureusement je dois inclure ces mots dans la macro, même si la gestion est un peu plus difficile. Le fichier est exporté d'un autre logiciel et cette liste de mots ne viens pas avec. Concrètement, j'exporte vers Excel une cédule d'ordonnancement de travaux à partir d'un logiciel de planification et par une macro je conserve les équipements qui demande une libération.
22/03/2016, 14h17
cerede2000

Quand je parle de tableau je ne parle pas de feuilles et de cellules mais bien d'un tableau en VBA.
Une Array quoi.

Qui te servira de paramètre dans ton code pour simplifier l'ajout ou la suppression de mots :)

Voir ici
22/03/2016, 14h54
Francis L

Je suis ouvert à toutes solutions. Mais je débute avec le VBA et je n'y connait pas grand chose pour l'instant. Si tu peux me fournir le code, cela serait très apprécié. Sinon, en attendant de perfectionner mes connaissances en VBA, je suis prêt à le faire avec la macro actuel. J'ai juste besoin de savoir comment ajouter d'autres mots.

Merci pour le lien, je vais en prendre connaissance.

Ok je regarde ça.

Edit : je te propose ça :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public Const mesMots = "toto:tot:titi:tata:tutu"
 
Sub SupLign()
    Dim i As Long
    Dim arMesMots() As String
    Dim mot As Variant
 
    arMesMots = Split(UCase(mesMots), ":")
 
    For i = Range("B65536").End(xlUp).Row To 1 Step -1
        For Each mot In arMesMots
            If UCase(Cells(i, 2).Value) Like "*" & mot & "*" Then
                Rows(i).Delete
                Exit For
            End If
        Next
    Next i
End Sub

22/03/2016, 15h48
Francis L

Si j'ai bien compris, je dois remplacer les mots toto, titi, ... par les mots que j'ai besoin. Si c'est bien cela, je perds toutes mes données.
22/03/2016, 15h51
cerede2000

J'ai éditer le code, j'étais parti sur l'inverse :)

Du coup c'est plus simple, quand un mots de la liste est trouvé dans la cellule courante, la ligne est supprimée.

Tu place dans mesMots les mots qui doivent engendrer une suppression de la ligne.
22/03/2016, 15h57
Francis L

EUH...Je désire conserver les lignes qui contiennent ces mots et non les supprimer. Désolé pour la confusion. Je croyais à tort que mes explications était correct.:(

Le post dans lequel tu est à un titre qui indique :

Citation:

Supprimer ligne contenant un mot précis

Si tu reprends ce code du coup :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Public Const mesMots = "toto:titi:tata:tutu"
 
Sub SupLign()
    Dim i As Long
    Dim arMesMots() As String
    Dim mot As Variant
    Dim trouveMot As Boolean
 
    arMesMots = Split(UCase(mesMots), ":")
 
    For i = Range("B65536").End(xlUp).Row To 1 Step -1
        trouveMot = False
        For Each mot In arMesMots
            If UCase(Cells(i, 2).Value) Like "*" & mot & "*" Then
                trouveMot = True
                Exit For
            End If
        Next
        If Not trouveMot Then
            Rows(i).Delete
        End If
    Next i
End Sub

C'est bien ce que tu veux, si la cellule courante ne contient pas le mot alors sa ligne est supprimée.

22/03/2016, 16h24
Francis L

Effectivement, j'airais probablement du démarrer un autre post et ne pas partir d'un qui existe déjà.

Excellent. Fonctionne à la perfection. Un gros merci, tu viens de rendre quelqu'un heureux.:D

Dernière question. Est-il possible de conserver les cellules vides. J'ai essayer en ne mettant pas de mot dans la liste. Ça ne fonctionne pas.
22/03/2016, 16h26
cerede2000

Code:

If UCase(Cells(i, 2).Value) Like "*" & mot & "*" Then

=>

Code:

If UCase(Cells(i, 2).Value) Like "*" & mot & "*" Or IsEmpty(Cells(i, 2).Value) Then
22/03/2016, 16h30
Francis L

Super. Encore une fois, merci.