Detecter le control d'un Userform sur clic

Version imprimable

Voir 40 message(s) de cette discussion en une page

cerede2000, Patrick

Pourquoi ne pas se contenter de ficher dans ton tableau cerede2000 seulement la position des labels ajoutés dynamiquent

Exemple autrement et simplement 9Fonction FindLabel)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
Option Explicit
 
'Généralisation des dimensions et nombre de labels
Const Nc As Integer = 9    'nombre de labels en colonnes
Const Nl As Integer = 12     'nombre de labels en lignes
Const L As Integer = 30     'largeur des labels
Const H As Integer = 20    'hauteur des labels
Const Ec As Integer = 5    'Ecart horizontal entre labels
Const El As Integer = 2    'Ecart vertical entre labels
 
Private Type LeLabel
    Nom As String
    X As Single
    Y As Single
End Type
 
Dim Tb() As LeLabel
 
Private Sub UserForm_Initialize()
Dim i As Integer, j As Integer, k As Integer
Dim Lbl As Control
 
'Règlage de la taille et la position du contrôle image
With Me.Image1
    .Left = 0
    .Top = 0
    .Width = Nc * (L + Ec) + 2 * Ec
    .Height = Nl * (H + El) + 2 * El
    .ZOrder 0
    .BackStyle = 0
    .BorderStyle = 0
End With
 
'Ajout des labels dans l'userform et dans le tableau TB
ReDim Tb(1 To Nc * Nl)
For i = 1 To Nl
    For j = 1 To Nc
        k = Nc * (i - 1) + j
        Set Lbl = Me.Controls.Add("Forms.Label.1", "LB" & k, True)
        With Lbl
            .Left = Ec + ((L + Ec) * (j - 1))
            .Top = El + ((H + El) * (i - 1))
            .Width = L
            .Height = H
            .Caption = "LB" & k
            .TextAlign = 2
            .BorderStyle = 1
            .ZOrder 1
        End With
        'On ajoute dans Tb la caption et les coordonnées du TopLeft
        With Tb(k)
            .Nom = Lbl.Name
            .X = Lbl.Left
            .Y = Lbl.Top
        End With
    Next j
Next i
End Sub
 
Private Sub Image1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
 
Me.Caption = "Label survolé: " & FindLabel(Tb, X, Y)
End Sub
 
Private Sub Image1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim Tmp As String
 
Tmp = FindLabel(Tb, X, Y)
If Tmp <> "" Then MsgBox Tmp
End Sub
 
'Cherche le label dans TB() dont le curseur de la souris se trouve à l'interieur
Private Function FindLabel(Tb() As LeLabel, ByVal xX As Single, ByVal yY As Single) As String
Dim i As Integer
 
If xX * yY > 0 Then
    For i = 1 To UBound(Tb)
        With Tb(i)
            If xX >= .X And xX <= .X + L Then
                If yY >= .Y And yY <= .Y + H Then
                    FindLabel = .Nom
                    Exit For
                End If
            End If
        End With
    Next i
End If
End Function

20/03/2016, 14h44
guypsia

Bonjour rdurupt

Peux-tu nous éclairer sur l'explication que tu donnes autour du modulo ?
Je n'arrive pas à comprendre à quoi cela sert par rapport au problème posé ...
merci pour ton aide.

Citation:

Envoyé par mercatog

cerede2000, Patrick

Pourquoi ne pas se contenter de ficher dans ton tableau cerede2000 seulement la position des labels ajoutés dynamiquent

Exemple autrement et simplement 9Fonction FindLabel)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
Option Explicit
 
'Généralisation des dimensions et nombre de labels
Const Nc As Integer = 9    'nombre de labels en colonnes
Const Nl As Integer = 12     'nombre de labels en lignes
Const L As Integer = 30     'largeur des labels
Const H As Integer = 20    'hauteur des labels
Const Ec As Integer = 5    'Ecart horizontal entre labels
Const El As Integer = 2    'Ecart vertical entre labels
 
Private Type LeLabel
    Nom As String
    X As Single
    Y As Single
End Type
 
Dim Tb() As LeLabel
 
Private Sub UserForm_Initialize()
Dim i As Integer, j As Integer, k As Integer
Dim Lbl As Control
 
'Règlage de la taille et la position du contrôle image
With Me.Image1
    .Left = 0
    .Top = 0
    .Width = Nc * (L + Ec) + 2 * Ec
    .Height = Nl * (H + El) + 2 * El
    .ZOrder 0
    .BackStyle = 0
    .BorderStyle = 0
End With
 
'Ajout des labels dans l'userform et dans le tableau TB
ReDim Tb(1 To Nc * Nl)
For i = 1 To Nl
    For j = 1 To Nc
        k = Nc * (i - 1) + j
        Set Lbl = Me.Controls.Add("Forms.Label.1", "LB" & k, True)
        With Lbl
            .Left = Ec + ((L + Ec) * (j - 1))
            .Top = El + ((H + El) * (i - 1))
            .Width = L
            .Height = H
            .Caption = "LB" & k
            .TextAlign = 2
            .BorderStyle = 1
            .ZOrder 1
        End With
        'On ajoute dans Tb la caption et les coordonnées du TopLeft
        With Tb(k)
            .Nom = Lbl.Name
            .X = Lbl.Left
            .Y = Lbl.Top
        End With
    Next j
Next i
End Sub
 
Private Sub Image1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
 
Me.Caption = "Label survolé: " & FindLabel(Tb, X, Y)
End Sub
 
Private Sub Image1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim Tmp As String
 
Tmp = FindLabel(Tb, X, Y)
If Tmp <> "" Then MsgBox Tmp
End Sub
 
'Cherche le label dans TB() dont le curseur de la souris se trouve à l'interieur
Private Function FindLabel(Tb() As LeLabel, ByVal xX As Single, ByVal yY As Single) As String
Dim i As Integer
 
If xX * yY > 0 Then
    For i = 1 To UBound(Tb)
        With Tb(i)
            If xX >= .X And xX <= .X + L Then
                If yY >= .Y And yY <= .Y + H Then
                    FindLabel = .Nom
                    Exit For
                End If
            End If
        End With
    Next i
End If
End Function

Je viens de tester ton code, c'est excellent !!!!!!
Super rapide et sans effet de vibration.

20/03/2016, 16h05
guypsia

1 pièce(s) jointe(s)

Et voilà le fichier XL en version 1.5 avec la méthode de mercatog (à qui on peut dire merci) et la gestion des couleurs (merci patricktoulon) !
Testé sur un celeron et fonctionne sans latence (la dernière version de patricktoulon qui était tout de même une bonne idée pour nous faire tous avancer dans la réflexion, sur le celeron, entrainait lag voire plantage aléatoire d'excel)

Pièce jointe 204447

Pour rester dans la même logique, on ajoute la couleur aux type LeLabel et sans utiliser le Tag

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
Option Explicit
 
'Généralisation des dimensions et nombre de labels
Const Nc As Integer = 9    'nombre de labels en colonnes
Const Nl As Integer = 12     'nombre de labels en lignes
Const L As Integer = 30     'largeur des labels
Const H As Integer = 20    'hauteur des labels
Const Ec As Integer = 5    'Ecart horizontal entre labels
Const El As Integer = 2    'Ecart vertical entre labels
 
Private Type LeLabel
    Nom As String
    X As Single
    Y As Single
    Couleur As Long
End Type
 
Dim Tb() As LeLabel
Dim Old As LeLabel
 
Private Sub UserForm_Initialize()
Dim i As Integer, j As Integer, k As Integer
Dim Lbl As Control
 
'Règlage de la taille et la position du contrôle image
With Me.Image1
    .Left = 0
    .Top = 0
    .Width = Nc * (L + Ec) + 2 * Ec
    .Height = Nl * (H + El) + 2 * El
    .ZOrder 0
    .BackStyle = 0
    .BorderStyle = 0
End With
 
'Ajout des labels dans l'userform et dans le tableau TB
ReDim Tb(1 To Nc * Nl)
For i = 1 To Nl
    For j = 1 To Nc
        k = Nc * (i - 1) + j
        Set Lbl = Me.Controls.Add("Forms.Label.1", "LB" & k, True)
        With Lbl
            .Left = Ec + ((L + Ec) * (j - 1))
            .Top = El + ((H + El) * (i - 1))
            .Width = L
            .Height = H
            .Caption = "LB" & k
            .TextAlign = 2
            .BorderStyle = 1
            .ZOrder 1
            .BackColor = ThisWorkbook.Colors(3 + (Rnd * 30))
        End With
        'On ajoute dans Tb la caption et les coordonnées du TopLeft
        With Tb(k)
            .Nom = Lbl.Name
            .X = Lbl.Left
            .Y = Lbl.Top
            .Couleur = Lbl.BackColor
        End With
    Next j
Next i
End Sub
 
Private Sub Image1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim Tmp As String
 
If Old.Nom <> vbNullString Then Me(Old.Nom).BackColor = Old.Couleur
 
Tmp = FindLabel(Tb, X, Y)
Me.Caption = "Label survolé: " & Tmp
If Tmp <> vbNullString Then
    Old.Nom = Tmp
    Old.Couleur = Me(Tmp).BackColor
    Me(Tmp).BackColor = vbWhite
End If
End Sub
 
Private Sub Image1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim Tmp As String
 
Tmp = FindLabel(Tb, X, Y)
If Tmp <> "" Then MsgBox Tmp
End Sub
 
'Cherche le label dans TB() dont le curseur de la souris se trouve à l'interieur
Private Function FindLabel(Tb() As LeLabel, ByVal xX As Single, ByVal yY As Single) As String
Dim i As Integer
 
If xX * yY > 0 Then
    For i = 1 To UBound(Tb)
        With Tb(i)
            If xX >= .X And xX <= .X + L Then
                If yY >= .Y And yY <= .Y + H Then
                    FindLabel = .Nom
                    Exit For
                End If
            End If
        End With
    Next i
End If
End Function

20/03/2016, 17h59
patricktoulon

re

re
bon me voila rentré
la version de Mercatog me plait beaucoup
les variable private type pour rassembler les propriété ca j'aime
après le principe est le même que ma version a savoir la comparaison du x ou y dans le tbl.x ou .Y dans une boucle

jolie l'ecriture +1

cerede j'ai regardé ta version j'ai pas bien analyser mais il y a des chose que je ne comprends pas tout du moins a quoi elles te servent
je vais étudier ca j'ai pas vu la boucle mais comme tu m'a dis qu'il y en avait pas je suis curieux de savoir comment tu find le bon control

mercatog respect :plusser:
attention tout de même au dimensionnement de l'image la elle est restreint au label dynamique ,peut être ajouter une variable en haut de module et dans le with image1"if ......)

dans ma next version il était question de pourvoir implanter le haut de module et le bas dans n'importe quel userform avec contrôles dynamique et non dynamique
c'est pour cela qu'il y avait le jeux avec zorder pour les controls non pris en charge par la pseudo classe

après étude du model de Mercatog ca me plait encore plus

le test du xX>=.x and xX<.X +l'(largeur) fait que l'on a pas besoins de gérer les zone mortes bien vu!!!!
et finalement pas si lourd que je le pensait hier
20/03/2016, 19h03
patricktoulon

re

re bon
alors cerede2000 c'est catégoriquement non pour ta solution et il est impossible qu'il n'y est pas le vibrato

mais tu es allé pécher ou qu'il était nécessaire de placer dans tabcoord tout les point de chaque contrôles c'est yper lourd comme truc non?
tu imagine 1000 item
avec mes précédente versions 190 item(bouton et interstices) pour 100 boutons
avec la version de mercatog qui lui gère le left et iwdth et top et height donc pas de zone mortes a gérer 100 item dans tbl pour 100 boutons

ensuite perso a quoi bon chercher en pixel puisque en point ca marche aussi bien

non la j'ai pas compris en quoi c'est mieux

conclusion
version de Mercatog boucle sur 100 pour 100 bouton
ou mes premières version avec arraylist et dico qui elle était encore moins gourmande puisque je bouclais sur 10 colonne "LEFTO" et X top dans la valeur lefto(X)du dico en la splitant
soit au total une boucle de 20 iteration au maximum pour 100 boutons
exemple pour le bouton lb100

for i= 0 to ubound(lefto)'lefto contien les lefts de chaque colonne soit 19 (10 bouton 9 interstices
ensuite split dicoleft(lefto(X)) et une boucle sur ce tableau soit 10 puisque mes exemples faisait 10 colonnes sur 10 lignes
voila
20/03/2016, 20h32
cerede2000

En effet la version de Mercatog est je trouve super top.

Ton idée patricktoulon est aussi top mais pourtant celle de Mercatog me parait plus rapide dans les tests que j'ai fais avec beaucoup beaucoup de LBL (100*100) :)

En effet, le test que j'ai fais avec le stockage de toutes les coordonnées est beaucoup trop lourde et devient vite ingérable :(
Le passage en PX était pour éviter les décimale avec les PT, car un index de tableau en décimale moi sais pas faire :D
20/03/2016, 20h39
patricktoulon

re

re

c'est la ou tu fait erreur dans ton raisonnement en point se ne sont pas les index des variables tableaux qui sont décimales mais leur valeur

et ici dans cette exercice il n'y a pas de décimales puisque le placement n'est fait que par des opérandes rondes

j'ai même trouvé une solution encore hyper ultra plus simple ( a tu déjà joué a la bataille navale ???) réfléchi tu va comprendre
tiens toi bien avec seulement 2 variable pour la comparaison
je mémorise rien d'autre ;)
20/03/2016, 21h01
cerede2000

Ah bon ?!?

Eu non je ne vois pas...

A moins que, tu détermine la zone dans laquel se situe le label dès le départ ?

Genre tout ceux de la colonne 1 on un tag 1 et ligne 1 tag 1 donc 1-1 et tu regarde juste dans quelle colonnes tu te situe et dans quelle ligne ?

mais non !!!
tiens celle la tu la pas vu venir!!!!!!!!!!!!!!!!!!!!!!!!!!!
ca va faire rire Mercatog :ptdr::mouarf:
plus simple que ca tu meurs

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Option Explicit
'Généralisation des dimensions et nombre de labels
Const nBcol As Integer = 10    'nombre de labels en colonnes
Const nBliG As Integer = 10     'nombre de labels en lignes
Const Larg As Integer = 30     'largeur des labels
Const haut As Integer = 20    'hauteur des labels
Const Ec As Integer = 5    'Ecart vertical entre labels
Dim theleft
Dim thetop
Private Sub UserForm_Activate()
    Dim i As Integer, j As Integer, k As Long, lbl As Object
    ReDim theleft(nBcol + 1)
    ReDim thetop(nBliG + 1)
    'Règlage de la taille et la position du contrôle image
    With Me.Image1
        .Left = 0: .Top = 0
        .Width = InsideWidth: .Height = InsideHeight
        .ZOrder 0
        .BackStyle = 0
        .BorderStyle = 0
    End With
    For i = 1 To nBliG
 
        For j = 1 To nBcol
            k = nBcol * (i - 1) + j
            Set lbl = Me.Controls.Add("Forms.Label.1", "LB" & k, True)
            With lbl
                .Left = Ec + ((Larg + Ec) * (j - 1))
                .Top = Ec + ((haut + Ec) * (i - 1))
                .Width = Larg
                .Height = haut
                If i = 1 Then theleft(j) = .Left & "|" & .Left + .Width
                If j = 1 Then thetop(i) = Ec + ((haut + Ec) * (i - 1)) & "|" & Ec + ((haut + Ec) * (i - 1)) + haut
                .Caption = "LB" & k
                .TextAlign = 2
                .BorderStyle = 1
                .ZOrder 1
                .BackColor = ThisWorkbook.Colors(3 + (Rnd * 53))
            End With
        Next
    Next
  End Sub
Private Sub Image1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim i As Long, col As Long, ligne As Long, e As Long
For i = 1 To UBound(theleft) - 1
If X > Val(Split(theleft(i), "|")(0)) And X < Val(Split(theleft(i), "|")(1)) Then col = i
Next
For e = 1 To UBound(thetop) - 1
If Y > Val(Split(thetop(e), "|")(0)) And Y < Val(Split(thetop(e), "|")(1)) Then ligne = e
Next
MsgBox " colonne  " & col & "   ligne  : " & ligne & vbCrLf & "LB" & nBliG * ligne - (nBcol - col)
End Sub

au final
pour trouver le bouton le plus bas et plus a gauche soit en l'occurrence ici le lb100
je boucle donc sur mes 10 theleft(X)
ensuite je boucle sur mes thetop donc 10
jai donc bouclé 20 fois pour 100 boutons au lieu de 100 chez mercatog ou 190 avec ma dernière méthode
pour trouver le nom et bien c'est simple puisqu'ils ont été cré de la mama facon que pour les left et top (par i et j)

donc si je tombe sur la colonne10 et ligne10
je fait nBliG * ligne - (nBcol - col) au quel je prefixe "LB" et je te le donne dans le mille emile ca nous donne quoi

LB100 !!!!!!!

Patrick, on n'arrêtera pas de sitôt. Bonne idée même si le gain en temps pour ce cas est négligeable

Pour ta dernière idée, j'utilise un tableau de tableaux au lieux des splits avec en plus un Exit For. Eh oui, il faudra optimiser

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
Option Explicit
 
'Généralisation des dimensions et nombre de labels
Const Nc As Integer = 40    'nombre de labels en colonnes
Const Nl As Integer = 23     'nombre de labels en lignes
Const L As Integer = 15     'largeur des labels
Const H As Integer = 20    'hauteur des labels
Const Ec As Integer = 1    'Ecart horizontal entre labels
Const El As Integer = 1    'Ecart vertical entre labels
 
Dim TheTop()
Dim TheLeft()
Dim Couleur() As Long
 
Private Sub UserForm_Initialize()
Dim i As Integer, j As Integer, k As Integer
Dim Lbl As Control
 
'Règlage de la taille et la position du contrôle image
With Me.Image1
    .Left = 0
    .Top = 0
    .Width = Nc * (L + Ec) + 2 * Ec
    .Height = Nl * (H + El) + 2 * El
    .ZOrder 0
    .BackStyle = 0
    .BorderStyle = 0
End With
 
'Ajout des labels dans l'userform et dans le tableau TB
ReDim TheTop(1 To Nl)
ReDim TheLeft(1 To Nc)
ReDim Couleur(1 To Nc * Nl)
For i = 1 To Nl
    For j = 1 To Nc
        k = Nc * (i - 1) + j
        Set Lbl = Me.Controls.Add("Forms.Label.1", "LB" & k, True)
        With Lbl
            .Left = Ec + ((L + Ec) * (j - 1))
            .Top = El + ((H + El) * (i - 1))
            .Width = L
            .Height = H
            .Caption = "LB" & k
            .TextAlign = 2
            .BorderStyle = 1
            .ZOrder 1
            .BackColor = 225
            If i = 1 Then TheLeft(j) = Array(.Left, .Left + L + Ec)
            Couleur(k) = .BackColor
        End With
    Next j
    TheTop(i) = Array(Lbl.Top, Lbl.Top + H + El)
Next i
End Sub
 
Private Sub Image1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Static Old As Integer
Dim Tmp As Integer
 
If Old <> 0 Then Me("LB" & Old).BackColor = Couleur(Old)
 
Tmp = FindLabelIndex(TheLeft, TheTop, X, Y)
Me.Caption = "Label survolé: LB" & Tmp
If Tmp <> 0 Then
    Old = Tmp
    Me("LB" & Tmp).BackColor = vbWhite
End If
End Sub
 
Private Function FindLabelIndex(TbLeft(), TbTop(), ByVal xX As Single, ByVal yY As Single) As Integer
Dim i As Integer, TheLig As Integer, TheCol As Integer
 
For i = 1 To UBound(TheLeft)
    If xX > TbLeft(i)(0) And xX < TbLeft(i)(1) Then
        TheCol = i
        Exit For
    End If
Next i
 
For i = 1 To UBound(TbTop)
    If yY > TbTop(i)(0) And yY < TbTop(i)(1) Then
        TheLig = i
        Exit For
    End If
Next i
 
If TheLig * TheCol > 0 Then FindLabelIndex = Nc * (TheLig - 1) + TheCol
End Function

20/03/2016, 23h00
patricktoulon

re

re
bonsoir Mercatog

Citation:

Patrick, on n'arrêtera pas de sitôt. Bonne idée même si le gain en temps pour ce cas est négligeable

Pour ta dernière idée, j'utilise un tableau de tableaux au lieux des splits avec en plus un Exit For. Eh oui, il faudra optimiser

oui c'est sur le gain de temps est négligeable visiblement sur nos pc
j'étais en train de réfléchir qui a utiliser des variable tableaux tant qu'a faire stoker aussi les noms et tout y cointi

j'ai juste voulu démontrer que l'on pouvait considérablement diminuer les boucles et de travailler en colonne/ligne ce qui nous fait 10+10 et non 10*10 pour 100 boutons

c'est pour cela que je parlais de bataille navale tout a l'heure

et puis

Citation:

il faudra optimiser

ho!...... je sais pas : un ( for /next) sur 10 items je sais pas qu'en pense tu ?:mouarf:

je vais potasser et rechercher des solutions pour améliorer
20/03/2016, 23h30
mercatog

Oui je te l'accorde le Toulonais, les idées de ce poste sont les tiennes

Par optimiser, je ne parlais pas des boucles que tu as allégé, mais de l'utilisation d'un tableau de strings qu'on split par la suite à chaque tour de boucle ou bien utiliser un tableau de tableau où on va chercher directement l'information.
21/03/2016, 00h08
patricktoulon

re

a oui ca c'est sur tes tableaux de tableaux je garde c'est plus propre en terme de lisibilité dans le code
21/03/2016, 08h39
cerede2000

Le post de rdurupt a tourné dans ma tête cette nuit :)

En effet avec un simple calcul sur division, connaissant la hauteur et la largeur des labels, on peu savoir rapidement de manière approximative dans quelle ligne et quelle colonne on se situe.

Du coup plus besoin de boucle, ex :
avec des labels de 20x20 espacés de 5, si ma souris est en 215x74
215/25 = 8.6 donc je suis dans la 8ieme colonne
74/25 = 2.96 donc je suis dans la 2ieme ligne

Reste juste a vérifier précisément entre deux labels pour être sur.

Non ? :)
21/03/2016, 08h56
Philippe PONS

1 pièce(s) jointe(s)

Salut,

Ma petite version, avec un algorithme un peu différent:
' on remarque que la matrice des contrôles découpe les axes X et Y en segments
' a chaque segment est associé un couple de nombres: la valeurs des 2 extrémités du segment
' je stocke ces 2 valeurs dans un tableau
' je met les tableaux de X dans un dicoSegmentsX, avec pour clé le numéro de la colonne
' je met les tableaux de Y dans un dicoSegmentsY, avec pour clé le numéro de la ligne
' sur click souris, je cherche si X est dans un segment de dicoSegmentsX
' si oui, je récupère le numCol, et je cherche si Y est dans un segment de dicoSegmentsY
' si oui, je récupère le numLigne et je calcul le numéro du contrôle

cordialement,
21/03/2016, 09h11
cerede2000

:) Merci à toi pour ta participation !

Plus on est de fous plus on rit non ? :mrgreen:

Tu peux rajouter des Exit For dans tes deux boucles afin de ne pas parcourir toutes les valeurs lorsque tu as trouvé la bonne ;)
21/03/2016, 09h54
cerede2000

1 pièce(s) jointe(s)

Tada!!!!!!

V1.7 avec recherche sans boucle :)

Calcul sur la position de la souris par division, me reste à rajouter la gestion des interstice :)
Et à voir pour changer la récupération des labels dans les tableau de manière à simplifier la récupération des labels pour faire juste Ligne-Colonne.

Edit : 1.7.1 avec gestion des interstices :)
Pièce jointe 204493
21/03/2016, 10h27
Philippe PONS

ma solution est plus simple!
Il n'y a quasiment pas de calcul!
:P:P:P:P:P

Voir 40 message(s) de cette discussion en une page