Trouver le nom de la fenetre d'un programme en connaissant le processus

Version imprimable

16/02/2016, 22h33
Jean-Philippe44

Trouver le nom de la fenetre d'un programme en connaissant le processus

Bonjour,

J'ai trouvé une solution efficace en envoyant des senkeys en vba.
Je suis bloqué.

C'est un programme de calcul qui a deux fenêtres de même nom.

Par contre elles ont un processus différent.

Il ne peut y en avoir qu'une par processus.

S'avez vous s'il est possible d'identifier le nom d'une fenêtre en connaissant le nom du processus?

C'est clair que ça m'aiderai beaucoup !!!!

Merci
16/02/2016, 22h54
patricktoulon

heu...

Bonsoir
Les Apis Windows
findwondowA
getwondowtext
getwindowlong
setwindowlongA
allez je te laisse faire tes recherche ;) tu a plein d' exemples ici sur le forum
02/03/2016, 22h12
Jean-Philippe44

Ca avance...

Bonsoir

Bon ben, c'est un peu mieux...

Par contre est il possible de savoir si l' action de sendkey est terminée pcq j'ai l'impression
que la macro continue sans s'en préoccuper.

Pour être plus clair: Je vais copier des feuilles dans un programme avec des senkeys et je les colle dans excel
mais j'ai l impression que ca les colle même si ça a pas eu le temps de les copier.

Je sais c'est un peu con comme situation.... :weird:
02/03/2016, 22h28
Jean-Philippe44

Presse papier

je vais voir en faisant une boucle avec le presse papier

Le vider entre chaque copier coller et tant qu il est vide ne pas avancer dans la macro...

C'est le plus simple?
06/03/2016, 18h22
Jean-Philippe44

win32_process

C'est ok pour la boucle sur le presse papier.

Par contre je n ai pas de solution pour activer la bonne fenêtre.

J ai deux fenetres avec le meme nom. Une a pour processus C2.exe et l'autre a pour processus prepi.exe

Avec Win32_Process class je peux avoir le bon handle du processus mais est possible avec ce handle de retouver le handle de la fenetre associée a ce processus.

Je galère grave....:calim2:
07/03/2016, 08h33
Invité

Bonjour,
Tu parle de processus en connaissant son nom.
Ok avec les api on peut trouver un processus par son nom mais pas définir lequel est le bon si plusieurs sont exécutés!

En revanche sur le processus est exécuter par ton programme l'api shellexecute te permets de mémoriser la fenêtre d'exécution dans une variable objet.

Note que les api te donneront les identifiants du nom du processus et que si tu ne dispose pas déformations de permettant de faire le distinguo...

bonjour fait moi plaisir met ca dans un module et

ouvre autant d'aplications que tu veux

et lance test ou test 2

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
' Déclaration des API utilisées
Public Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
 Public Declare Function EnumWindows Lib "user32" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long
' Variable temporaire utilisée uniquement par la fonction GetWindowsList
 ' pour stocker les fenêtres.
Public stGetWindowsList As String
Public Function GetWindowsList()
' Cette fonction retourne sous forme de tableau l'ensemble
 ' des titres des fenêtres de premier niveau ouvertes sous windows.
Dim lgRep As Long
stGetWindowsList = vbNullString
' Appel de l'API et envoi du pointeur vers notre fonction de rappel
lgRep = EnumWindows(AddressOf EnumWindowsProc, 0)
' Découpage de la chaîne pour retourner un tableau
GetWindowsList = Split(stGetWindowsList, vbCrLf)
End Function
' Déclaration de la fonction de rappel
Public Function EnumWindowsProc(ByVal lgHwnd As Long, ByVal lgParam As Long) As Long
 Dim stTmp As String, lgTmp As Long, lgRet As Long
stTmp = Space$(120)
 lgTmp = 119
' On récupère le titre de la fenêtre à partir du handle
lgRet = GetWindowText(lgHwnd, stTmp, lgTmp)
 stTmp = Replace(stTmp, Chr$(0), vbNullString)
' Stockage du résultat dans la chaine temporaire (ajout au texte existant).
 ' On pourrait imaginer construire une chaîne plus complexe en ajoutant également le handle
 ' de la fenêtre, ce qui permettrait des manipulations externes (comme une fermeture par exemple).
If (Trim$(stTmp) <> vbNullString) Then stGetWindowsList = stGetWindowsList & "handle:" & lgHwnd & " la caption de la fenetre est  : " & stTmp & vbCrLf
' Retourne 1 systématiquement
EnumWindowsProc = 1
End Function
'exemple 1 te liste les fenetre ouverte dans un msgbox  handle et caption !!!!!
Sub test()
GetWindowsList
MsgBox stGetWindowsList
End Sub
' Exemple2
Sub test2()
 Dim tablofenetre
  tablofenetre = GetWindowsList
MsgBox tablofenetre(0) 'affiche la fenetre qui est en premier plan dans la hierarchie de l'affichage
End Sub

exemple 2
un peu comme la suggérer rdurupt avec shell mais je préfère la 1 ere car on a aussi les app qui ont été lancer ailleurs que par excel

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Public Const GW_HWNDNEXT = 2
Public Declare Function GetParent Lib "user32" (ByVal hwnd As Long) As Long
Public Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, ByVal wCmd As Long) As Long
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Public Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwprocessid As Long) As Long
Public hWndApp As Long
Sub test_VLC()
   Dim hInst As Long             ' Instance handle from Shell function.
            ' Window handle from GetWinHandle.
   Dim buffer As String          ' Holds caption of Window.
   Dim numChars As Integer       ' Count of bytes returned.
 
   ' Shell to an application
   hInst = Shell("C:\Program Files\VideoLAN\VLC\vlc.exe")
 
   ' Begin search for handle
   hWndApp = GetWinHandle(hInst)
 
 
   If hWndApp <> 0 Then
      ' Init buffer
      buffer = Space$(2)
 
      ' Get caption of window
      numChars = GetWindowText(hWndApp, buffer, Len(buffer))
 
      ' Display window's caption
      MsgBox "vous avez demarrer avec shell l'application ou le fichier  " & Left$(buffer, 10) & vbCrLf & "et" & vbCrLf & "son handle est  :" & hWndApp
   End If
End Sub
Function ProcIDFromWnd(ByVal hwnd As Long) As Long
   Dim idProc As Long
      ' Get PID for this HWnd
   GetWindowThreadProcessId hwnd, idProc
      ' Return PID
   ProcIDFromWnd = idProc
End Function
 
Function GetWinHandle(hInstance As Long) As Long
   Dim tempHwnd As Long
      ' Grab the first window handle that Windows finds:
   tempHwnd = FindWindow(vbNullString, vbNullString)
      ' Loop until you find a match or there are no more window handles:
   Do Until tempHwnd = 0
      ' Check if no parent for this window
      If GetParent(tempHwnd) = 0 Then
         ' Check for PID match
         If hInstance = ProcIDFromWnd(tempHwnd) Then
            ' Return found handle
            GetWinHandle = tempHwnd
            ' Exit search loop
            Exit Do
         End If
      End If
 
      ' Get the next window handle
      tempHwnd = GetWindow(tempHwnd, GW_HWNDNEXT)
   Loop
End Function

Ps il te faudra adapter les api pour 64 bit peut etre
"ptrsafe"

;)

Merci

bon ben au final, on m a aidé et ca marche au top, un petit probleme pour activer la fenetre mais comme ca marche

merci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
 
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal IpClassName As Any, ByVal IpWindowName As Any) As Long
Public Declare Function GetParent Lib "user32" (ByVal hwnd As Long) As Long
Public Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, ByRef IpdwProcessId As Long) As Long
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, ByVal wCmd As Long) As Long
 
Public Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
Public Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Public Declare Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long
 
 
Public Const GW_HWNDNEXT = 2
 
Public Sub InputActivate()
    Dim pid As Long
    Dim h_wnd As Long
    Dim buf As String
    Dim buf_len As Long
    Dim textpgrm As String
    Dim objprocess
 
    Handle_PST = Application.hwnd
 
    pid = 0
 
    ' Recherche du PID du pro
    objprocess = "prepip.exe"
    For Each process In GetObject("winmgmts:").instancesof("Win32_process")
        If (process.Name = objprocess) Then
            pid = process.processid
            Exit For
        End If
    Next
    '
 
    If pid = 0 Then
        SetForegroundWindow Handle_C2
        ShowWindow Handle_C2, 3
        SetFocus Handle_C2
        MsgBox "Vous devez Ouvrir l'Input"
        End
    End If
 
    ' Get the window handle.
    h_wnd = InstanceToWnd(pid)
 
    ' Display the program's caption.
    buf = Space$(256)
    buf_len = GetWindowText(h_wnd, buf, Len(buf))
    buf = Left$(buf, buf_len)
 
    ' Actions
    'Debug.Print pid, h_wnd, buf
    'AppActivate buf
 
    Handle_C2 = h_wnd
    ShowWindow Handle_C2, 0
    ShowWindow Handle_C2, 3
    SetForegroundWindow Handle_C2
    SetFocus Handle_C2
 
End Sub
 
' Return the window handle for an instance handle.
Private Function InstanceToWnd(ByVal target_pid As Long) As _
    Long
Dim test_hwnd As Long
Dim test_pid As Long
Dim test_thread_id As Long
 
    ' Get the first window handle.
    test_hwnd = FindWindow(ByVal 0&, ByVal 0&)
 
    ' Loop until we find the target or we run out
    ' of windows.
    Do While test_hwnd <> 0
        ' See if this window has a parent. If not,
        ' it is a top-level window.
        If GetParent(test_hwnd) = 0 Then
            ' This is a top-level window. See if
            ' it has the target instance handle.
            test_thread_id = _
                GetWindowThreadProcessId(test_hwnd, _
                test_pid)
 
            If test_pid = target_pid Then
                ' This is the target.
                InstanceToWnd = test_hwnd
                Exit Do
            End If
        End If
 
        ' Examine the next window.
        test_hwnd = GetWindow(test_hwnd, GW_HWNDNEXT)
    Loop
End Function