Probleme pour creer un tableau word depuis excel VBA

Version imprimable

Bonjour à tous,

je tente désespérément de créer un tableau word depuis une commande VBA sur excel, mon programme crée un nouveau document, ajoute du texte et est censé insérer un tableau, voici mon code :

erreur d'exécution '438':
Propriété ou méthode non gérée par cet objet

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
 
Sub creerFichierWord()
 
Dim WordApp As Object
Dim WordDoc As Object
 
 
        'Set WordApp = CreateObject("Word.Application")     '-- ouvre une session Word
        On Error Resume Next
        Set WordApp = GetObject(, "Word.Application")
        If WordApp Is Nothing Then
        Set WordApp = CreateObject("Word.Application")
        End If
        On Error GoTo 0
 
    Set WordDoc = WordApp.Documents.Add
 
    WordApp.Visible = True
    WordApp.Application.Caption = "document"  ' titre entête du document
 
        With WordApp.Selection  'Ecriture dans word
        .TypeText Text:="Procédure pour écrire dans Word "
        .TypeParagraph 'Saut de paragraphe
        .TypeText Text:="aaaaaaaaaaaaaaaaaaaaaa"
        End With
 
' NE MARCHE PAS
    WordApp.Tables.Add Range:=WordDoc.Selection.Range, NumRows:=9, NumColumns:=6
 
    WordDoc.SaveAs adresse & "\" & NomFich & ".doc"    '-- enregistre le nouveau doc
 
 
    WordDoc.Close 'fermeture document Word
    WordApp.Quit  'fermeture session Word
 
 
End Sub

Sachant que j'ai deja essayé la syntaxe en modifiant WordDoc.Selection par Selection

Code:

WordApp.Tables.Add Range:=Selection.Range, NumRows:=9, NumColumns:=6

et ca

Code:

1
2
 Dim objTable As Table
Set objTable = WordDoc.Tables.Add(Range:=Selection.Range, NumRows:=5, NumColumns:=3)

Un grand Merci d'avance

16/02/2016, 20h18
Gdal
Salut,

As-tu essayé ceci
Code:

1 2 Set MyDoc = WordApp.Documents("test1.doc").ActiveWindow
Sinon il y a le FAQ

Gdal
16/02/2016, 21h28
amiralbhar

Salut Gdal

Oui merci pour ta réponse, j'ai bien essayé ce code, j'arrive a écrire sur mon document mais pas à inserer un tableau j'ai vraiment passé toute la journée a essayé tout ce que je trouvé sur les forums sans succès

Il y a pas un template déja fait que tu peux me proposer ?

Salut,

Voici:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
Sub FnAddTableToWordDocument()
 
    Dim intNoOfRows
    Dim intNoOfColumns
    Dim objWord
    Dim objDoc
    Dim objRange
    Dim objTable
 
    intNoOfRows = 5
    intNoOfColumns = 3
 
    Set objWord = CreateObject("Word.Application")
    objWord.Visible = True
 
    Set objDoc = objWord.Documents.Add
    Set objRange = objDoc.Range
 
    objDoc.Tables.Add objRange, intNoOfRows, intNoOfColumns, DefaultTableBehavior:=wdWord9TableBehavior, _
                    AutoFitBehavior:=wdAutoFitFixed
 
    Set objTable = objDoc.Tables(1)
 
    With objTable
        If .Style <> "Grille du tableau" Then
            .Style = "Grille du tableau"
        End If
        .ApplyStyleHeadingRows = True
        .ApplyStyleLastRow = False
        .ApplyStyleFirstColumn = True
        .ApplyStyleLastColumn = False
        .ApplyStyleRowBands = True
        .ApplyStyleColumnBands = False
        .Style = "Tableau Grille*4 - Accentuation*6"
    End With
 
    For i = 1 To intNoOfRows
 
        For j = 1 To intNoOfColumns
 
        objTable.Cell(i, j).Range.Text = "Sumit_" & i & j
 
        Next
 
    Next
 
End Sub

Source: Excel-Macro, @TutorialHorizon

Ce que tu peux faire:
Ouvrir Word
Affichage / Macro / Enregistrer une macro
Tu insères un tableau ou tu le modifies
Affichage / Macro / Arrêt l'enregistrement
Touche [Atl]+[F11]
Tu verras le code créer qui sera à adapter.

Gdal
PS: Il faut ajouter la référence Word (dans VBE, Outils / Références)

18/02/2016, 20h54
amiralbhar

ca marche !! :))) Merci d'avoir pris le temps de m'aider ca me fais gagner un temps fou :ppp