Creer un batch qui me parait complexe

Version imprimable

22/01/2016, 19h40
orphen

Creer un batch qui me parait complexe

Bonjour a tous,

J'essaye de créer un bath qui pourrait faire ceci.

Un dossier qui s'appelle "a traiter" et qui contient une liste de fichier .7z (ces fichiers ne comportent pas de sous répertoire).

J'aimerai que en lançant mon batch il fasse ceci.

- 1 Récupération du nom du fichier 1.z7
- Extraction du contenu du fichier z7 dans un dossier temporaire
- Renommage du fichier.cue en lui donnant le nom du fichier récupérer de la première étape
- rezipage en z7 du contenu en kui donnant le nom de la première étape
- Déplacement du nouveau fichier a un endroit de mon disque dur
- suppression du dossier temporaire
-Et ainsi de suite pour tout les fichiers

Pouvez vous m'aider je ne sais pas du tout comment faire même si je sais que c'est possible.

Merci par avance

Bonjour,
Essaye ceci:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
@echo off & cls
setlocal EnableDelayedExpansion
 
set current_path=%~dp0
set current_path_modified=%current_path:~0,-1%
set "TempDir=%systemdrive%\Temp"
set "FinalDir=%systemdrive%\Final"
 
if not exist "%current_path_modified%\7z.exe" (
    echo 7z.exe est introuvable dans %current_path_modified%
    echo Extinction du script dans 10 secondes.
    timeout 10
    exit
)
if not exist "!TempDir!" md "!TempDir!"
if not exist "!FinalDir!" md "!FinalDir!"
 
for /F "delims=" %%I in ('dir /b *.7z') do (
    set "Current7zFileName=%%~nI"
    set "Current7zFileExtension=%%~xI"
    set "Current7zFullName=!Current7zFileName!!Current7zFileExtension!"
    echo Fichier en cours de traitement: !Current7zFileName!
    echo Extraction de !Current7zFullName! dans !TempDir!
    7z e !Current7zFullName! -o!TempDir! * -r
    for /F "delims=" %%J in ('dir /b !TempDir!\*.cue') do (
        echo Renommage de %%J en !Current7zFileName!%%~xJ
        move "!TempDir!\%%J" "!TempDir!\!Current7zFileName!%%~xJ"
    )
    echo On cree l'archive !Current7zFileName!.7z et on la deplace dans !FinalDir!
    7z a -t7z "!TempDir!\!Current7zFileName!.7z" "!TempDir!\*"
    move "!TempDir!\!Current7zFileName!.7z" "!FinalDir!"
    echo On nettoie le dossier temporaire
    rd /S /Q "!TempDir!"
)
 
pause
exit

Tu n'as qu'à place le fichier "7z.exe" dans le même dossier que ton .bat et à modifier les chemins à ta guise.

24/01/2016, 19h26
orphen

Merci beaucoup,

j'ai du corriger quelque trucs pour que ca fonctionne chez moi mais tu ma donner la demarche.

Merci encore :)

Orphen