Positionner un OLEObject par macro

Version imprimable

Bonjour à tous,

J'aimerais créer et positionner dynamiquement des OLEObject dans des cellules précices à l'image de ce qui a été fait sur des contrôles de formulaire :
http://excel.developpez.com/faq/?pag...laireDynamique
Code:

1 2 3 4 5 6 7 8 9 10 11 12 For i = 2 To 11 'création des boutons dans la Feuil1 With Feuil1 Set S = .Shapes.AddFormControl(xlButtonControl, .Cells(i, 2).Left, .Cells(i, 2).Top, _ .Cells(i, 2).Width, .Cells(i, 2).Height) End With 'Définit le texte qui va s'afficher dans le bouton. S.TextFrame.Characters.Caption = "bouton " & i 'Attache une macro au bouton S.OnAction = "MacroBouton" Next i
Est-il possible de faire l'équivalent avec des OLEObject?
Merci d'avance

Bonjour,

Une piste, création de 5 boutons avec écriture de leur code respectif dans le module de la feuille. Pour le test, c'est le Caption du bouton dans un Msgbox. Pour plus de souplesse, un module de classe serait mieux indiqué. OnAction ne fonctionne par pour des ActiveX (enfin, à ma connaissance) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Sub Test()
 
    Dim BtnOle As OLEObject
    Dim Btn As MSForms.CommandButton
    Dim I As Integer
    Dim Ligne As String
 
    For I = 1 To 5
 
        'création des boutons dans la Feuil1
        With Feuil1.Cells(I, 2)
 
            Set BtnOle = Feuil1.OLEObjects.Add("Forms.CommandButton.1", , False, False, , , , .Left, .Top, .Width, .Height)
 
        End With
 
        BtnOle.Name = "MonBouton" & I
 
        Set Btn = BtnOle.Object
 
        Btn.Caption = "Bouton " & I
 
        'écrit dans le module de la feuille "Feuil1" les lignes de code...
        With ThisWorkbook.VBProject.VBComponents(Feuil1.CodeName).CodeModule
 
            Ligne = vbCrLf & "Private Sub " & BtnOle.Name & "_Click()" & vbCrLf & vbCrLf _
                           & "    MsgBox " & BtnOle.Name & ".Caption" & vbCrLf & vbCrLf _
                           & "End Sub" & vbCrLf
 
            .InsertLines .CountOfLines + 1, Ligne
 
        End With
 
    Next I
 
End Sub

21/12/2015, 13h14
yanisdev

Bonjour,

Merci pour l'aide:) . J'ai quand même eu un petit soucis avec la macro. J'avais une erreur qui me disait que le type MSForms.CommandButton n'était pas défini.
Du coup j'ai jeté un coup d'oeil du côté des références et j'ai coché "ActiveX Data Objects 6.1 library" puis j'ai fermé le classeur. Je l'ai de nouveau ouvert et en relançant la macro j'avais toujours cette erreur.
J'ai mis en commentaire tout ce qui concerné ce type d'objet et je n'ai eu aucun problème d'exécution. J'ai enlevé les commentaires et la mystère tout fonctionnait !
Du coup j'ai une question, quelles sont les références, s'il y en a, qu'il faut activer pour le type MSForms?
21/12/2015, 21h23
clementmarcotte

Citation:

Envoyé par yanisdev

Bonjour,

Du coup j'ai une question, quelles sont les références, s'il y en a, qu'il faut activer pour le type MSForms?

M'est avis que c'est "Microsoft Forms 2.0 Object Library"
22/12/2015, 07h44
Theze

Bonjour,

C'est comme le dit Clément mais il y à plus simple, tu ajoutes un UserForm à ton projet et tu le supprimes ensuite. L'ajout de cet UserForm induit l'ajout de la référence !
22/12/2015, 10h11
yanisdev

En effet ! Hier je n'avais pas coché cette case et en regardant aujourd'hui je me suis aperçu que la référence été activée.
Merci pour vôtre aide.