Union de range

Version imprimable

14/12/2015, 16h38
pubbins

Union de range
Bonjour à tous,

Je reviens vers vous avec un problème que je n'arrive pas à résoudre :

Je veux rassembler plusieurs lignes d'un classeur dans un range sur lequel je vais travailler ensuite. J'ai tout d'abord rassemblé les lignes qui m'intéresse dans un tableau Tblo composé des index des lignes à inclure dans le range. Ensuite j'utilise la fonction union pour créer ma range :
Code:

1 2 3 4 5 Set PlageSelect = Nothing For k = 1 To UBound(TbloFin, 1) Set PlageSelect = Application.Union(PlageSelect, FeuilA.Rows(Tblo(k, 3))) Next k
Mais quoi que je fasse, mon range PlageSelect reste "Nothing" et je ne comprends absolument pas pourquoi. Pouvez-vous m'éclairer ?

Bonjour,

Que donnerait ce code ? :

Code:

1
2
3
4
Set PlageSelect = Nothing
For k = 1 To UBound(TbloFin, 1)
Set PlageSelect = Application.Union(FeuilA.Rows(Tblo(k, 3)))
Next k

Ca ne marche pas parce que Union nécessite deux arguments obligatoires (sinon pas d'union : ce qui parait en somme plutôt logique !). En revanche, en faisant cela :

Code:

1
2
3
4
5
6
7
8
9
 
                        Set PlageSelect = Nothing
                        For k = 1 To UBound(Tblo, 1)
                            If k = 1 Then
                                Set PlageSelect = FeuilA.Rows(Tblo(k, 3))
                            Else
                                Set PlageSelect = Application.Union(PlageSelect, FeuilA.Rows(Tblo(k, 3)))
                            End If
                        Next k

Ca marche ! Mais je trouve cela complètement moche. Si vous avez une suggestion plus élégante, je suis preneur !

Merci en tout cas pour votre aide,

Pubbins.

Bonjour,

Soit u concatène les numéros de ligne puis tu le passe en argument à Range() :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub Test()
 
    Dim PlageSelect As Range
    Dim TbloFin(1 To 5) As Long
    Dim K As Integer
    Dim Lignes As String
 
    TbloFin(1) = 3
    TbloFin(2) = 5
    TbloFin(3) = 8
    TbloFin(4) = 15
    TbloFin(5) = 22
 
    For K = 1 To UBound(TbloFin)
        Lignes = Lignes & TbloFin(K) & ":" & TbloFin(K) & ","
    Next K
 
    'supprime la virgule de fin
    Lignes = Left(Lignes, Len(Lignes) - 1)
 
    Set PlageSelect = Range(Lignes)
 
    PlageSelect.Select
 
End Sub

Soit il te faut définir la première plage avant de boucler :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub Test()
 
    Dim PlageSelect As Range
    Dim TbloFin(1 To 1, 1 To 5) As Long
    Dim K As Integer
 
    TbloFin(1, 1) = 3
    TbloFin(1, 2) = 5
    TbloFin(1, 3) = 8
    TbloFin(1, 4) = 15
    TbloFin(1, 5) = 22
 
    'défini la première plage
    Set PlageSelect = Rows(TbloFin(1, 1))
 
    'boucle sur les autres
    For K = 2 To UBound(TbloFin, 2)
        Set PlageSelect = Application.Union(PlageSelect, Rows(TbloFin(1, K)))
    Next K
 
    'sur la feuille active
    PlageSelect.Select
 
End Sub

et puis, tu obliges la déclaration des variables de façon explicite et tu trouvera plus facilement les erreurs !
"For k = 1 To UBound(TbloFin, 1)"-->"Application.Union(PlageSelect, FeuilA.Rows(Tblo(k, 3)))"