Contrôle de la saisie dans une INPUTBOX

Version imprimable

Bonjour,

Je développe actuellement mon premier fichier VBA, je connais les grandes lignes mais j'ai des difficultés à écrire certaines instructions faute d’expérience.

Je m'explique, j'ai créé une Inputbox à l'intérieur de laquelle je saisis un mois de l'année.

Voici le code:
Code:

1 2 3 4 5 6 7 8 9 10 11 Sub Insf_controlmois() b = InputBox("Indiquez le mois que vous saisissez?", "Comptes") If b <> "" Then Sheets("PARAM").Range("E2") = b Call Insf_nommernouvellefeuille End If End Sub
Dans une feuille masquée nommée PARAM, entre F2 et F13, j'ai tous les mois de l'année: JANVIER, FEVRIER,etc...

Je souhaite créer une condition du type
Code:

1 2 while b <> Sheets("PARAM").Range("F2:F13").Value wend
Mais le code est invalidé par l'éditeur..

Si vous avez une soluce.

PS: j'ai cherché un sujet sans le trouver.:)

Merci

Bonjour,

Essayez le code suivant

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Insf_controlmois()
Dim Mois As Variant
Dim rep
Dim i&
Dim A$
'---
Mois = Array("JANVIER", "FEVRIER", "MARS", "AVRIL", "MAI", "JUIN", _
  "JUILLET", "AOUT", "SEPTEMBRE", "OCTOBRE", "NOVEMBRE", "DECEMBRE")
 
Do
  rep = InputBox("Indiquez le mois que vous saisissez (en toutes lettres et sans accent)", "Comptes")
  For i& = LBound(Mois) To UBound(Mois)
    If UCase(rep) = Mois(i&) Then
      A$ = Mois(i&)
      Exit Do
    End If
  Next i&
Loop
 
MsgBox A$
 
End Sub

Bonjour,

Demande à tes utilisateur d'indiquer le mois sous forme numérique, la fonction "MonthName" inscrira le nom du mois correspondant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Sub Insf_controlmois()
 
    Dim b As String
 
    b = InputBox("Indiquez le nombre du mois, 1 pour janvier, 2 pour février, etc...", "Comptes")
 
    If Not IsNumeric(b) Then
 
        MsgBox "Valeur non conforme !", vbExclamation
        Exit Sub
 
    End If
 
    Sheets("PARAM").Range("E2") = MonthName(b)
 
    Insf_nommernouvellefeuille
 
End Sub

Oups,

J'ai oublié de gérer les deux bornes donc :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub Insf_controlmois()
 
    Dim b As String
 
    b = InputBox("Indiquez le nombre du mois, 1 pour janvier, 2 pour février, etc...", "Comptes")
 
    If Not IsNumeric(b) Then
 
        MsgBox "Valeur non conforme !", vbExclamation
        Exit Sub
 
    Else
 
        If b < 1 Or b > 12 Then
 
            MsgBox "La valeur doit être située de 1 à 12 !", vbExclamation
            Exit Sub
 
        End If
    End If
 
    Sheets("PARAM").Range("E2") = MonthName(b)
 
    Insf_nommernouvellefeuille
 
End Sub

04/10/2015, 14h29
ThomasVIGIER

Merci Theze et PMO 2017..

Grâce à vos précieux conseils, j'ai pu trouver la solution que je cherchais et en prenant les codes de chacun, j'avais envisager la solution de Theze mais sans pouvoir la formaliser.

Il est donc impossible de demander au code de vérifier avec Find si la valeur saisie correspond à des valeurs que j'aurai enregistrées?

je vais envisager également une solution Listbox..dès que j'aurai lu le chapitre à ce sujet :question:

l'idée finale est de développer des formulaires permettant la saisie, la consultation et l'affichage de graphique.

avec mon niveau actuel; réalisation prévue Mars 2245...8O:

mais la persévérance finit par payer...

a bientôt sur le forum.

....
04/10/2015, 14h33
Philippe Tulliez

Bonjour,

Citation:

Il est donc impossible de demander au code de vérifier avec Find?

Bien entendu et également avec Application.Match mais je crois que dans ton cas les solutions proposées sont plus pertinentes me semble-t-il