Filtre par textbox

Bonjour le forum

Je cherche à faire un filtre d'une zone via un textbox

mais cela ne fonctionne pas tt à fait .....
qqn aurait une idée

Code:

---

1 2 3 4 5 6 7 8

Private Sub Tx_Recherche_Change()   If Tx_Recherche <> "" Then ActiveSheet.Range("$b$3:$d$1000").AutoFilter Field:=2, Criteria1:= _ "=*" & Tx_Recherche & "*", Operator:=xlAnd End If   End Sub ?

---

---

Fichiers joints dans les discussions

---

Bonjour,
Très intrigué par le fait que tu signales que ton code ne fonctionne pas, j'ai voulu tester sur une de mes liste de données et je n'ai pas de problème
Pour le test, j'ai utilisé une variable objet nommée rng et pour définir la liste des données j'utilise la propriété CurrentRegion (ma liste commence en cellule A1 et les étiquettes de colonnes en première ligne)

Code:

---

1 2 3 4 5 6 7

Private Sub Tx_Recherche_Change() Dim rng As Range Set rng = ActiveSheet.Range("A1").CurrentRegion If Tx_Recherche <> "" Then rng.AutoFilter Field:=2, Criteria1:="=*" & Tx_Recherche & "*", Operator:=xlAnd End If End Sub

---

Cependant dans ta remarque,

Citation:

---

mais cela ne fonctionne pas tt à fait .....
qqn aurait une idée

---

tu n'es pas très précis.
Qu'est-ce qui ne fonctionne pas tout à fait ?

Bonjour Philippe,

Citation:

---

Envoyé par Philippe Tulliez

Bonjour,

Cependant dans ta remarque,

tu n'es pas très précis.
Qu'est-ce qui ne fonctionne pas tout à fait ?

---

Hélas, ce n'est pas la première fois. :(

De plus, il n'avait sûrement pas pensé que son fichier-joint pourrait prendre le chemin des oubliettes; malgré l'avertissement de Pierre Fauconnier. Il a maintenant le lien direct; si jamais, il ne l'a pas déjà lu.

bonjour à Tous

Désolé de ne pas avoir été assez clair, je vais faire un effort ;-)

Pour ce qu'il est du fichier joint, je n'avais pas vu le message en début de forum...
Mes données du fichier joint ne sont pas sensibles

Bon reprenons
j'ai suvi les conseil de Philippe Tulliez http://www.developpez.net/forums/d15...x/#post8396842
(ma liste commence en cellule A1 et les étiquettes de colonnes en première ligne)

Code:

---

1 2 3 4 5 6 7

Private Sub Tx_Recherche_Change() Dim rng As Range Set rng = ActiveSheet.Range("A1").CurrentRegion If Tx_Recherche <> "" Then rng.AutoFilter Field:=2, Criteria1:="=*" & Tx_Recherche & "*", Operator:=xlAnd End If End Sub

---

mais cela ne fonctionne pas :
Si par exemple je tape "tel" je m'attends à ce que les lignes 2 et 5 uniquement soit visibles ... mais je n'ais q'une ligne vide

autres exemples :
avec "AI" les lignes 1 2 et 3 devraient être visible
avec "Mi" uniquement la ligne 4 devrait être visible



Est-ce plus clair comme cela ? ;-)

Bonjour,
Comme écrit plus haut, je n'ai pas de soucis le filtre s'effectue parfaitement. Si je tape "au", j'ai bien toutes les lignes ayant en colonne 2, une chaîne contenant "AU".
La seule chose qui ne fait pas, c'est libérer le filtre si la chaîne de recherche (TextBox) est vide mais j'ai ajouté une ligne pour cela.

Code:

---

1 2 3 4 5 6 7 8 9 10 11

Private Sub Tx_Recherche_Change() Dim rng As Range Set rng = ActiveSheet.Range("A1").CurrentRegion With rng If Tx_Recherche <> "" Then .AutoFilter Field:=2, Criteria1:="=*" & Tx_Recherche & "*", Operator:=xlAnd Else .Worksheet.ShowAllData End If End With End Sub

---

J'ai compris.....
effectivement je me suis mal exprimé

tu me précise que cela tri sur la colonne 2

moi je voulais que cela filtre sur toutes les colonnes.... que la recherche fouille dans toutes les cellules de la base et que les lignes filtrées soient celles qui comportenent la recherche du textbox peu importe la colonne .

sorry de la mauvaise expression

Bonjour,
Alors tu as choisi le mauvais outil.
Normalement le filtre simple d'excel filtre la ligne sur les éléments d'une colonne et permet ainsi de réduire le nombre de lignes si je cherche les personnes habitant "Paris" ou "Marseille" (colonne 4) et étant célibataire (colonne 6), etc.
Avant de programmer en VBA, tente de voir si manuellement avec l'outil tu peux réaliser ce que tu cherches à obtenir.
On peut bien entendu faire une recherche colonne par colonne comme tu le ferais manuellement mais je pense que cela va alourdir la recherche et que faire si tu fais la recherche sur une colonne contenant des dates, etc.
Sans connaître l'organisation de tes données pour comprendre la raison qui te pousse à faire un filtre sur l'ensemble des colonnes, il est difficile d'apporter une réponse pertinente.
Le filtre avancé d'excel sera sans doute plus proche de ce que tu cherches.
La méthode Find permet également de faire une recherche sur l'ensemble des données mais ne permet pas de filtrer.

[EDIT]

Citation:

---

tu me précise que cela tri sur la colonne 2

---

Oui et chez toi également (voir code dans ton premier Post).
Dans cette ligne de code

Code:

---

AutoFilter Field:=2, Criteria1:="=*" & Tx_Recherche & "*", Operator:=xlAnd

---

A ton avis, à quoi sert cet argument nommé Field et dont on a donné comme valeur 2 (2ème colonne) si ce n'est de demander au filtre simple de faire une sélection sur le champ de la colonne 2 de la liste de données par rapport au critère n° 1 (Argument nommé Criteria1)

Citation:

---

moi je voulais que cela filtre sur toutes les colonnes.... que la recherche fouille dans toutes les cellules de la base et que les lignes filtrées soient celles qui comportenent la recherche du textbox peu importe la colonne .

---

Je te confirme que le filtre avancé est la solution.

Merci Philippe pour cette réponse détaillée ....
Je vais me pencher sur la question ce We !


Passes un bon We !

Bonjour,
Comme expliqué plus haut, la solution est dans le filtre avancé d'excel avec un critère nommé (calculé)
A lire éventuellement Les filtres avancés ou élaborés dans Excel

Après lecture, tu pourras comprendre ce qui suit
Pour l'exemple, imagine une liste de données (zone des données) comprenant six colonnes (A->F) et plusieurs lignes (avec en première ligne les étiquettes de colonnes).
Nous allons appliquer un critère (zone des critères) en cellule H1:H2) pour filtrer les lignes où valeur que l'on place en K2 (pour l'exemple *leu* est présente dans une des cellules des colonnes B à F.
L'étiquette de la zone des critères _fn_ (H1) et la formule placée comme critère (H2)

Code:

---

=NON(ESTNA(EQUIV($K$2;$B2:$F2;0)))

---

Dès que tu auras testé manuellement, je déposerai ici, le code VBA à appliquer pour ton cas.

Illustration
Pièce jointe 189271

Après avoir activé le filtre
Pièce jointe 189272

Hello
J'ai testé ta solution et je la trouve bien
pas tt à fait adaptée à mon besoin alors g bosssé de mon côté avec un autre code trouvé sur le net

Ca donne cela :
une barre de recherche

Pièce jointe 189414

Je tape le mot recherché dans la barre de recherche (Tx_Recherch) et je valide avec ok (Cx_BoutonOk)
J'ai procédé comme cela car si je fait directement le filtre en tapant les lettres le filtre se calculer à chaque lettre ct pénible.

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14

Private Sub Cx_BoutonOk_Click()   Application.ScreenUpdating = False [BDD].EntireRow.Hidden = False 'RAZ If Tx_Recherche <> "" Then Dim r As Range, masque As Range For Each r In [BDD].Rows If r.Find(Tx_Recherche, , xlValues, xlPart) Is Nothing _ Then Set masque = Union(r, IIf(masque Is Nothing, r, masque)) Next If Not masque Is Nothing Then masque.EntireRow.Hidden = True End If Application.ScreenUpdating = True End Sub

---

Je RAZ la recherche avec le bouton RAZ (Cx_BoutonRAZ)

Code:

---

1 2 3 4

Private Sub Cx_BoutonRAZ_Click() Tx_Recherche.Value = "" Cx_BoutonOk_Click End Sub

---

Il me reste deux soucis :

- Définir dynamiquement BDD : A2: BB derniére ligne.
Pour l'instant j'ai définie nom de la plage A2:BB4000.... c'est pas super propre
--> Comment améliorer le code ?, je suis pas encore très l'aise avec cette notion


- Gérer la recherche en tenant compte des accents --> Là je sais pas quoi faire
--> As-tu une piste ?, pas forcement me fournir le code

J'ai bien trouvé ce code, mais ce n'est pas adapté

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27

' Déclaration des variables obligatoire ' Option Explicit   ' Fonction de suppression des accents au sein d\'une chaîne de texte ' Function SUPPRACCENT(texte As String) As String   Dim strAccent, strNoAccent, strFrom, strTo As String, i As Integer   ' Listes des caractères accentués et leurs équivalents non accentués ' strAccent = "àâçéèêëîïôùûüÿÀÂÇÉÈÊËÎÏÔÙÛÜŸ" strNoAccent = "aaceeeeiiouuuyAACEEEEIIOUUUY"   For i = 1 To Len(strAccent)   ' On récupére un caractère de "strAccent" et de "strNoAccent" à la position i ' strFrom = Mid(strAccent, i, 1) strTo = Mid(strNoAccent, i, 1)   ' On remplace dans la chaîne "texte" les caractères accentués par leurs équivalents non accentués ' texte = Replace(texte, strFrom, strTo)   Next   ' On renvoie la chaîne "texte" sans accents ' SUPPRACCENT = texte   End Function

---

J'espére que mon explication à été assez claire ;-)

Bonjour Seb,
Voici les procédures que j'utilise pour une recherche basée sur le filtre avancé d'excel.
La formule placée dans la zone des critères est crée automatiquement. Basée sur un masque (Constante nommée myFormula) contenant deux balises nommées respectivement LookUpValue (valeur à chercher qui est construite par le contrôle TextBox nommé Tx_Recherche) et Address qui permettra de calculer automatiquement l'adresse de la zone de recherche (pour l'exemple $B2:$F2).
Pour comprendre comment construire une formule avec des balises à lire ce billet Ecrire une formule dans Excel à l'aide d'une procédure VBA (Part 2) qui est la suite de Ecrire une formule dans Excel à l'aide d'une procédure VBA

Le formulaire est constitué de deux TextBox nommés respectivement Tx_Recherche (contenant la chaîne de caractères à chercher) et txtFormula (Affiche le résultat de la fonction NewFormula

Les procédures sont à placer dans le formulaire (UserForm)
L'exemple est basé sur la liste de données illustrée dans ma réponse précédente.

Lignes à placer en-tête de module

Code:

---

1 2 3

Option Explicit Dim areaData As Range, areaCriteria As Range Const myFormula As String = "=NOT(ISNA(MATCH([LookUpValue],[Address],0)))" ' Masque de formule

---

Fonction nommée NewFormula qui crée dynamiquement la formule servant de critères

Code:

---

1 2 3 4

Private Function NewFormula(LookUpValue As String) NewFormula = Replace(myFormula, "[Address]", areaData.Offset(1, 1).Resize(1, 5).Address(RowAbsolute:=False)) NewFormula = Replace(NewFormula, "[LookUpValue]", Chr(34) & "*" & LookUpValue & "*" & Chr(34)) End Function

---

Procédure événementielle Tx_Recherche_Change (A remplacer éventuellement par une autre si elle est trop lente)

Code:

---

1 2 3 4 5 6 7 8 9

Private Sub Tx_Recherche_Change() Dim f As String With areaData f = NewFormula(Tx_Recherche) areaCriteria(2) = f Me.txtFormula = f ' areaCriteria(2) .AdvancedFilter xlFilterInPlace, areaCriteria End With End Sub

---

Procédure d'initialisation du formulaire

Code:

---

1 2 3 4 5 6 7 8

Private Sub UserForm_Initialize() ' Attibution des référence aux variables objets Set areaData = ActiveSheet.Range("A1").CurrentRegion With areaData Set areaCriteria = .Offset(columnOffset:=.Columns.Count + 2).Resize(2, 1) End With areaCriteria(1) = "_fn_" End Sub

---

La procédure événementielle Terminate

Code:

---

1 2 3 4 5 6 7

Private Sub UserForm_Terminate() areaCriteria.Clear ' Supprime la zone des critères On Error Resume Next areaData.Worksheet.ShowAllData ' Supprime le filtre On Error GoTo 0 Set areaData = Nothing: Set areaCriteria = Nothing End Sub

---

A la fermeture du formulaire, le filtre est effacé. Si l'on souhaite conservé celui-ci, il suffit de mettre en remarque la ligne 4

[EDIT]
Ajouté le fichier exemple + ajouté l'effacement du filtre dans la procédure événementielle Terminate

Bonjour Phillipe,

Oula, tu es d'un niveau bien supérieur au mien .... quand cela part dans les fonctions je décroche .... ;-)

Bonjour,

c'est pour cela qu'avant de programmer efficacement en VBA mieux vaut connaître le B-A-BA d'Excel ‼



_____________________________________________________________________________________________________
Je suis Charlie, Bardo, Sousse

Je sais Je sais

C'est pour cela que je suis en pleine phase d’apprentissage ;-)

Bonjour Seb,

Citation:

---

Bonjour Phillipe,
Oula, tu es d'un niveau bien supérieur au mien .... quand cela part dans les fonctions je décroche .... ;-)

---

Comme l'a bien écrit :plusser: Marc que je salue au passage, une bonne connaissance d'excel est un prérequit avant de passer au VBA.

Bonjour Philippe et merci,

tu es trop bon avec moi !

Bonjour,
J'ai ajouté le fichier exemple et modifié la procédure événementielle Terminate pour permettre l'effacement du filtre à la fermeture du formulaire à la discussion #11