Remplir un combobox avec un nom variable

Version imprimable

Salut forum,

J'ai une feuille de calcul qui contient 100 combo box.
Comment faut-il s'y prendre pour les remplir?
J'arrive à adresser les shapes je ne sais pas comment adresser les objets pour utiliser leurs méthodes.
Dans le code ci-dessous, je peux rendre visible ou invisible les combo box mais dès que j'essaye d'utiliser clear ou additem j'ai biensûr une erreur d'exécution 438: Propriété ou méthode non gérée par cet objet.
Code:

1 2 3 4 5 6 7 8 9 10 11 Sub Worksheet_Change(ByVal Target As Range) If Target.Row = 1 Then If Sheets("Colonnes").Cells(Target.Row, Target.Column).Value = "" Then Sheets("Colonnes").Shapes("CBFormat" & Target.Column - 1).Visible = False Else Sheets("Colonnes").Shapes("CBFormat" & Target.Column - 1).Visible = True End If End If End Sub
Merci d'avance,
Jean

Bonjour,

Regarde du coté de la propriété "ControlFormat" :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Sub Test()
 
    Dim Combo As Shape
 
    'défini la variable objet
    Set Combo = Sheets("Colonnes").Shapes("CBFormat" & Target.Column - 1)
 
    'remplissage style RowSource d'un ComboBox ActiveX
    Combo.ControlFormat.ListFillRange = "Feuil2!A1:A10"
 
    'remplissage avec une boucle
    For I = 1 To 10
        Combo.ControlFormat.AddItem "Elément n° " & I
    Next
 
    'élément choisi
    With Combo.ControlFormat
        MsgBox .List(.ListIndex)
    End With
 
    'supprime tout
    Combo.ControlFormat.RemoveAllItems
 
    'supprime 1 élément (ne fonctionne pas si le remplissage est effectué avec "ListFillRange")
    Combo.ControlFormat.RemoveItem 3
 
    'en gras
    Combo.TextEffect.FontBold = msoCTrue
 
    'Etc...
 
End Sub

23/09/2015, 14h30
jpclabaux

Salut Theze,

Merci de t'intéresser à mon problème.
J'ai testé ta solution mais j'ai toujours la même erreur.
Ce qui est bizarre c'est que lorsque je saisie "combo.controlformat." dans la fenêtre d'exécution en debuggage, le système m'offre bien la possibilité d'utiliser les propriétés du combobox (additem, list, removeitem,...) mais quand je les utilise il me dit que la Propriété ou la méthode est non gérée par cet objet???!!!
23/09/2015, 20h29
Theze

poste un classeur exemple avec deux ou trois ComboBox !
24/09/2015, 14h41
jpclabaux

1 pièce(s) jointe(s)

Voilà le classeur.

Bonjour,

Tes ComboBox sont en fait des contrôles ActiveX qui sont aussi considérés comme des Shapes mais qu'il est préférable de traités comme des objets OLE (objets intégrés à la feuille) donc, le code du bouton "Afficher" devient :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 Private Sub CBAfficher_Click() Dim Objet As OLEObject 'tous contrôles ActiveX Dim Combo As MSForms.ComboBox Dim i As Integer 'cache/affiche si le nom du contrôle contient "CBFormat" For Each Objet In OLEObjects If InStr(Objet.Name, "CBFormat") <> 0 Then Objet.Visible = Not Objet.Visible Next Objet 'défini le contrôle comme ComboBox afin d'utiliser les propriétés propres à ce type de contrôle 'de ce fait, le contrôle n'est plus un contrôle générique mais bien un ComboBox Set Combo = Me.OLEObjects("CBFormat1").Object Combo.Clear For i = 1 To 10 Combo.AddItem "Elément n° " & i Next End Sub
On pourrait très bien utiliser le code de cette façon (en ce passant de la variable "Combo") :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 Private Sub CBAfficher_Click2() Dim Objet As OLEObject 'tous contrôles ActiveX Dim i As Integer 'cache/affiche si le nom du contrôle contient "CBFormat" For Each Objet In OLEObjects If InStr(Objet.Name, "CBFormat") <> 0 Then Objet.Visible = Not Objet.Visible Next Objet Me.OLEObjects("CBFormat1").Object.Clear For i = 1 To 10 Me.OLEObjects("CBFormat1").Object.AddItem "Elément n° " & i Next End Sub
mais dans ce cas, on se prive de l'intellisense qui nous permets d'avoir la liste des propriétés et méthodes de l'objet.
Si tu as un soucis avec "Dim Combo As MSForms.ComboBox" il te suffit juste d'ajouter à ton projet un UserForm afin d'activer la référence et ensuite, tu peux le supprimer, la référence restera liée au classeur.

24/09/2015, 18h37
jpclabaux

Super, ça fonctionne parfaitement! Merci!
Je profite de ta générosité pour te demander si je peux définir une seule sub "change" pour l'ensemble des combobox?
Pour l'instant j'ai dupliqué 99 fois CBFormat1_Change() mais ce n'est pas très élégant, sans parler de la maintenance.

Bonjour,

Pour ça, il faut utiliser un module de classe. Dans le module de la feuille, le code devient (avec "Dim Cb() As New Classe1" en tête de module) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Dim Cb() As New Classe1
 
Private Sub CBAfficher_Click()
 
    Dim Objet As OLEObject 'tous contrôles ActiveX
    Dim Combo As MSForms.ComboBox
    Dim I As Integer
 
    For Each Objet In OLEObjects
 
        'cache/affiche si le nom du contrôle contient "CBFormat"
        If InStr(Objet.Name, "CBFormat") <> 0 Then
 
            Objet.Visible = Not Objet.Visible
 
            If Objet.Visible = True Then
 
                Set Combo = Objet.Object
 
                I = I + 1
                ReDim Preserve Cb(1 To I)
                Set Cb(I).GroupeCombo = Combo
 
            End If
 
        End If
 
    Next Objet
 
    Set Combo = Me.OLEObjects("CBFormat1").Object
 
    Combo.Clear
 
    For I = 1 To 10
        Combo.AddItem "Elément n° " & I
    Next
 
End Sub

Et dans le module de classe (nommé par défaut "Classe1") c'est là que tu va adapter ce que tu désire faire sur changement de valeur dans les combobox :

Code:

1
2
3
4
5
6
7
8
9
10
11
 
Public WithEvents GroupeCombo As MSForms.ComboBox
 
 
Private Sub GroupeCombo_Change()
 
    'adapter ici. Certaines propriétés ne sont pas proposées par l'intellisense mais on peut
    'malgré tout y faire référence comme par exemple la propriété "Name"
    MsgBox "Le nom du ComboBox est : " & GroupeCombo.Name & vbCrLf & "Sa valeur est : " & GroupeCombo.Text
 
End Sub

25/09/2015, 15h07
jpclabaux

Wow! Génial!
C'est parfait, merci beaucoup.
Je vais garder ce code précieusement car ça va m'aider dans d'autres projets.

Bonne journée,
Jean