Transporter une formule Excel dans Access

Version imprimable

13/09/2015, 22h07
celthi

1 pièce(s) jointe(s)

Transporter une formule Excel dans Access

bonjour au forum,

Débutant en Access, j'aimerais tranporter une formule d'un fichier Excel pour calculer un temps de carence pour un nouvelle mission d'intérimaire. J'arrive a faire une requete avec une partie du calcul mais la formule doit prendre uniquement les jours de travail (workday) et une function IF.
Je pense qu'il faut passer par du VBA ou SQL mais là cela dépasse mes competences.
Je joint le fichier Excel, la formule finale est en AC.

Merci pour toute l'aide que vous pourriez m'apporter.

Cordialement.Pièce jointe 187797

Bonjour,

Pour autant que la règle est

- si la durée du dernier contrat est supérieure à 14 jrs, alors durée divisé par 2 et forcer à l'unité supérieure
- sinon, retourner vide,

voici une fonction équivalente en Access
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Option Compare Database Option Explicit Public Function carence(DureeDernContrat As Long) As String If DureeDernContrat > 14 Then carence = CInt((DureeDernContrat / 2) + 0.5) Else carence = "" End If End Function
http://claudeleloup.developpez.com/&99/L3579.jpg

14/09/2015, 21h34
celthi

Bonsoir au Forum et à Claude

Je vais tenter cela demain,

Merci pour ce tuyau.
J'ai toujours un problème car la règle doit impliquer une durée du contrat sans compter les W.E (les jours fériés comptes) et je n'arrive pas à faire ce calcul en access.
J'ai l'expérience qu'avec Access 2007 je ne suis pas arrivé à faire deux champs calculé dans une même requête, d'où mon idée de passer par le VBA ou SQL.

Cordialement
14/09/2015, 21h53
ClaudeLELOUP

Pour les jours ouvrés, regarde ici : http://claudeleloup.developpez.com/t...plic-ploc/#LIV
17/09/2015, 00h13
celthi

Bonjour Claude et au forum,

Concernant la formule, elle dit
Si la durée du dernier contrat est <14, divisé la durée par 2, sinon divisé par 3.

J'ai réussi à faire la table des jours ouvrés, j'ai mis la function dans un module, comment faire maintenant pour mettre tout cela en pratique.

Dans mon formulaire, j'ai les chants "début de contrat" et "fin de contrat", "durée du "contrat", "carence" et "date de reprise possible".

est-ce que je dois creer un bouton charger de faire les calcules en VBA.

Cdt.
17/09/2015, 05h25
ClaudeLELOUP

Bonjour,

Si tu veux, je te proposerai un exemple. Poste une version Access2000 de ta db (avec des données anonymes, mais représentatives) pour que je puisse tester.

Citation:

Si la durée du dernier contrat est <14, divisé la durée par 2, sinon divisé par 3.

Dans l'exemple que tu donnais 15/2 = 8 jrs
Que doit donner 16/3 ? 5 ou 6 jrs ?
17/09/2015, 11h10
celthi

1 pièce(s) jointe(s)

Pièce jointe 188156Bonjour Claude,

Merci pour ton aide.
Je n'ai pas pu enregistrer sous Access 2000. Je joins une base demo sans données confidentielles au format 2007

Concernant la carence >14, il faut forcer à l'entier supérieur.

Merci encore

Cdt,
Pièce jointe 188155
17/09/2015, 11h11
celthi

Il s'agit du formulaire F_Mission
17/09/2015, 11h33
madefemere

1 pièce(s) jointe(s)

Bonjour celthi et Claude ;),

Ci-joint la base en version 2000. C'est tout ce que je peux faire.

@ celthi : il fallait supprimer le champ image personnel qui était définit comme étant pièce jointe. Access 2000 ne les gère pas.

Cordialement
17/09/2015, 11h45
celthi

Merci madefemere
Je ne comprenais pas pourquoi.

Est-il possible de passer par un evenement afterupdate du champs "date de fin de la dernière mission" pour utiliser la function et faire les calcules. J'ai encore beaucoup de mal avec VBA ou bien existe t'il un moyen plus efficient et plus propre

Merci

Cdt.
17/09/2015, 11h55
ClaudeLELOUP

Merci Mandresy,

Je regarde après le repas !

1 pièce(s) jointe(s)

Voici

http://claudeleloup.developpez.com/&99/L3619.jpg

N.B. Dans la table T_Mission, j’ai modifié le type de « Durée_dernière_mission » : date => long.

Dans l’événement « Après mise à jour » du contrôle « Date_Fin_derniere_mission », ce code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Date_Fin_derniere_mission_AfterUpdate()
  'Vérifier que les dates sont cohérentes
  If Me.Date_Fin_derniere_mission - Nz(Me.Date_Début_derniere_mission, #1/1/2100#) < 0 Then
      MsgBox "les 2 dates sont incohérentes"
      Exit Sub
  End If
  'Calcul de la durée de la dernière mission
  Me.Durée_dernière_mission = NbreJOuvDeA(Me.Date_Début_derniere_mission, Me.Date_Fin_derniere_mission)
  'Calcul de la carence
  If Me.Durée_dernière_mission > 14 Then
      Me.Carence = Int((Me.Durée_dernière_mission / 3) + 0.67)
    Else
      Me.Carence = Int((Me.Durée_dernière_mission / 2) + 0.5)
  End If
End Sub

18/09/2015, 11h10
celthi

Bonjour Claude,
Merci beaucoup, cela fonctionne.

Il reste le champs "Date de reprise mini" à coder.
J'ai pensé à mettre un évenement après mise à jour du champs Carence.
Je veux récupérer la date du champs "Date fin dernière mission" et y ajouter la carence en tenant compte uniquement des jours ouvrés. Je me demande comment repassé par les données de la table des jours ouvrés, ou bien existe t'il une fonction ?

Cdt,
18/09/2015, 11h14
celthi

Désolé,
Je viens de consulter ton article et j'ai un début de réponse, reste à réussir à l'adapter à mon cas.
Cdt,
18/09/2015, 15h57
celthi

Bonjour Claude,

Un grand merci : ça fonctionne, j'ai récupéré la fonction dans ton article et c'est tout bon.
Juste un point de finiolage. La fonction renvoi 12:00:00 AM si la date de fin de contrat n'est pas dans la tables des jours ouvrés, y aurait-il un moyen d'avancer cette date d'un ou deux jours en cas d'erreur ?

Cdt

1 pièce(s) jointe(s)

Bonjour,

Si je te comprends bien :

la date de reprise mini = le lendemain de la date de fin + nbre de jours de carence,
mais si la date de fin renseignée n’est pas ouvrable, alors il faut considérer la veille ouvrable de la fin renseignée.
Ajoute cette fonction dans module2
(N.B. Je viens de corriger une erreur dans le plic-ploc.)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Function Echeance(DateDebut As Date, NbreJrs As Integer) As Date
 'Renvoie la date ouvrable qui vient après le nombre de jours (qui peut être négatif)
 'DateDebut sous la forme anglo-saxonne
 'Si cette DateDebut n'existe pas dans la table, la fonction renvoie 00:00:00
 
  Dim rst As Recordset
  Set rst = CurrentDb.OpenRecordset("SELECT JoursOuvres FROM tJoursOuvres ORDER BY JoursOuvres;")
  Do While Not rst.EOF
    If rst("JoursOuvres") = DateDebut Then
        rst.Move NbreJrs
        Echeance = rst("JoursOuvres")
        Exit Function
      Else
        rst.MoveNext
    End If
  Loop
End Function

Et l’événement Après mise à jour de Date fin de dernière mission devient :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Date_Fin_derniere_mission_AfterUpdate()
  Dim dFinReelle As Date
  'Vérifier que les dates sont cohérentes
  If Nz(Me.Date_Fin_derniere_mission, #1/1/1900#) - Nz(Me.Date_Début_derniere_mission, #1/1/2100#) < 0 Then
      MsgBox "les 2 dates sont incohérentes"
      Exit Sub
  End If
  'Calcul de la durée de la dernière mission
  Me.Durée_dernière_mission = NbreJOuvDeA(Me.Date_Début_derniere_mission, Me.Date_Fin_derniere_mission)
  'Calcul de la carence
  If Me.Durée_dernière_mission > 14 Then
      Me.Carence = Int((Me.Durée_dernière_mission / 3) + 0.67)
    Else
      Me.Carence = Int((Me.Durée_dernière_mission / 2) + 0.5)
  End If
  'Calcul de la date de reprise mini
  'Trouver la date de fin réelle (si la date fin non ouvrable ==> sa veille ouvrable)
  dFinReelle = DMax("JoursOuvres", "tJoursOuvres", "JoursOuvres<=#" & Format(Me.Date_Fin_derniere_mission, "mm/dd/yyyy") & "#")
  Me.Date_de_reprise_mini = Echeance(dFinReelle, Me.Carence + 1)
End Sub

http://claudeleloup.developpez.com/&99/L3639.jpg

http://claudeleloup.developpez.com/&99/L3640.jpg

22/09/2015, 23h02
celthi

Bonsoir au Forum, Bonsoir Claude.

Après avoir fait ces modifs, tout fonctionne à merveille.
Merci pour ton aide sur ce point. Mon projet avance à grands pas, j'aurais certainement au moins une autre question, mais j'ouvrirai une autre discussion si je ne trouve pas de réponses.

Mon probleme est résolu.

Cdt.