aide programmation VBA

Version imprimable

01/06/2015, 12h39
schumi22

1 pièce(s) jointe(s)

aide programmation VBA

bonjour à tous,

je suis un très gros novice en programmation quelle qu'elle soit ^^
j'ai besoin pour un futur projet d'avoir un classeur pour le suivie kilométrique de pièces.
je travail sur EXCEL 2013
j'ai reussi à créer un formulaire afin d'ajouter de nouvelles pièces à mon classeur ( merci Youtube ^^ )
j'ai également une mise en forme conventionnelle pour le remplissage des fonds de mes lignes en fonction de certains paramètres.

voici un imprim écran du classeur :

Pièce jointe 179373

je souhaite maintenant, lorsque mes pièces seront toutes ajoutées, avoir un autre USERFORM qui me permettra d'en selectionner plusieurs comme la liste du tri.
puis incrementer la cellule temps de roulage et temps de banc aux pièces selectionnées.

je ne sais pas si c'est très bien expliqué...

si quelqu'un pouvait me filer une petit coup de main car je ne trouve rien sur you tube ou autre

merci d'avance
cordialement
SCHUMI22
01/06/2015, 13h09
Gado2600

Bonjour,

Citation:

je ne trouve rien sur you tube ou autre

As-tu essayé sur www.developpez.net ? :)

Blague à part, ce qu'il te faut c'est, une zone de liste (à ne pas confondre avec une liste déroulante comme tu utilises dans ton exemple) dans ton Userform avec comme paramètre multiselection.
En utilisant comme mot clé "rowsource", tu devrais trouver 2-3 trucs pour l'alimenter (pour que ton code soit plus efficace et rapide, je te conseille d'ajouter dans cette liste, le numéro de la ligne de tes données).

En parcourant chacun de tes items sélectionnés dans ta liste, tu pourras appliquer ton incrémentation.

Je pense qu'avec ces mots-clés et ton début d'expérience en VBA, cela devrait te permettre d'y voir plus clair. :)

Cordialement,

un coup de pouce

Un bou de code pour t'aider : ca permet de le mettre dans une liste box et sa te liste ce que tu met en range ;) je m'en suis servis une fois , je ne suis pas du tout callé en userform donc je ne vais pas pouvoir t'aider plus mais bon ca pourra probablement t'aider dans ton userform :)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 'liste entreprise 1 Private Sub CompanyName1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer) Dim trouve As String, I As Integer Worksheets("Feuil1").Select trouve = CompanyName1 With CompanyName1 .Clear For I = 1 To 59 If Range("b" & I) Like trouve & "*" Then .AddItem Range("B" & I) .List(.ListCount - 1, 1) = Range("C" & I) .List(.ListCount - 1, 2) = Range("D" & I) End If Next I .ListIndex = 0 End With End Sub

01/06/2015, 23h59
schumi22

1 pièce(s) jointe(s)

merci pour vos réponse :)

en revanche cela ne m'aide pas beaucoup ... je suis réellement novice les gars, pour la plus part des propos je n'ai rien compris :)

la zone de liste me permettra t elle de faire une selection de ce type ?

Pièce jointe 179441

car je souhaite choisir sur quelles pièces j'éffectue l'incrémentation ( une incrémentation d'une valeur que je choisirai dans ce USERFORM )
02/06/2015, 00h26
tamtam64

Sinon tu peux utiliser l'enregistreur de macro peut etre? et la tu utilise un tableau croisé dynamique non?

Bonjour,

Pose sur ta Form une liste de choix (ListBox) et un bouton (CommandButton), colle le code ci-dessous et teste et adapte à tes besoins. La liste te permet une sélection multiple avec case à cocher et le bouton incrémente de 1 à chaque clic la valeur des cellules de la colonne D :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
Private Sub UserForm_Initialize()
 
    Dim Plage As Range
    Dim I As Integer
 
    With ActiveSheet
 
        'sur la feuille active en colonne A à partir de la 14 ème ligne
        Set Plage = .Range(.Cells(14, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    With ListBox1
 
        '3 colonnes
        .ColumnCount = 3
        .ColumnWidths = "100;100;100"
        .ListStyle = fmListStyleOption
        .MultiSelect = fmMultiSelectMulti
 
        'rempli la liste
        For I = 1 To 10
 
            .AddItem Plage(I).Value
            .Column(1, I - 1) = Plage(I).Offset(, 1).Value
            .Column(2, I - 1) = Plage(I).Offset(, 2).Value
 
        Next I
 
    End With
 
End Sub
 
Private Sub CommandButton1_Click()
 
    Dim I As Integer
 
    With Me.ListBox1
 
        For I = 0 To .ListCount - 1
 
            If .Selected(I) = True Then
 
                With ActiveSheet.Range("D" & I + 14)
 
                    .Value = .Value + 1
 
                End With
 
            End If
 
        Next I
    End With
 
End Sub

Hervé.

02/06/2015, 09h12
schumi22

2 pièce(s) jointe(s)

merci Theze !

c'est ce genre de chose que je recherche.

voici aujourd'hui ce que ça donne :

ajout de pièce :

Pièce jointe 179471

ajout temps de banc :

Pièce jointe 179473

et de meme pour ajout temps de roulage

est il possible de faciliter le choix de pièces dans la liste pour les ajouts de temps ? ( par exemple des sous catégories comme si on avait un tri ou alors effectuer le tri dans mon tableau avant de lancer l'ajout de temps ? )
car là si je dois parcourir 1000 pièces une par une ça risque d'étre long ^^

Bonjour,

Si j'ai bien compris, tu souhaites faire un tri sélectif dans ta plage avant d'incrémenté ?
Tu ajoutes un TextBox et tu colle tout le code ci-dessous dans le module de la Form. Une recherche est faite sur la plage (ici de façon simple par une moulinette) et les mots commençant par les lettres entrées sont chargés. Il est nécessaire dans ce cas d'utiliser un tableau niveau module car il faut garder en mémoire les numéros de ligne où sont trouvés les mots :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
 
Dim Tbl() As Integer
 
Private Sub TextBox1_Change()
 
    Dim Plage As Range
    Dim I As Integer
    Dim J As Integer
 
    With ActiveSheet
 
        'sur la feuille active en colonne A à partir de la 14 ème ligne
        Set Plage = .Range(.Cells(14, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    'par défaut, vide la liste si une lettre n'est pas trouvée
    ListBox1.Clear
 
    For I = 1 To Plage.Count
 
        'recherche la correspondance et rempli la liste
        If Left(Plage(I), Len(TextBox1.Text)) = TextBox1.Text Then
 
            J = J + 1
            ReDim Preserve Tbl(1 To J)
 
            Tbl(J) = I
 
            With ListBox1
 
                .AddItem Plage(I).Value
                .Column(1, J - 1) = Plage(I).Offset(, 1).Value
                .Column(2, J - 1) = Plage(I).Offset(, 2).Value
 
            End With
 
        End If
 
    Next I
 
End Sub
 
Private Sub UserForm_Initialize()
 
    Dim Plage As Range
    Dim I As Integer
 
    With ActiveSheet
 
        'sur la feuille active en colonne A à partir de la 14 ème ligne
        Set Plage = .Range(.Cells(14, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    With ListBox1
 
        '3colonnes
        .ColumnCount = 3
        .ColumnWidths = "100;100;100"
        .ListStyle = fmListStyleOption
        .MultiSelect = fmMultiSelectMulti
 
        'rempli la liste
        For I = 1 To Plage.Count
 
            .AddItem Plage(I).Value
            .Column(1, I - 1) = Plage(I).Offset(, 1).Value
            .Column(2, I - 1) = Plage(I).Offset(, 2).Value
 
        Next I
 
    End With
 
End Sub
 
Private Sub CommandButton1_Click()
 
    Dim I As Integer
 
    With Me.ListBox1
 
        For I = 0 To .ListCount - 1
 
            If .Selected(I) = True Then
 
                With ActiveSheet.Range("D" & Tbl(I + 1) + 13)
 
                    .Value = .Value + 1
 
                End With
 
            End If
 
        Next I
 
    End With
 
End Sub

Hervé.

merci pour ton code,

Malheureusement ça m'aide pas beaucoup, car il est possible que j'ai des pièces de plusieurs départements à incrementer.
J'aurais preféré si c'est possible, faire ma préselection ( par exemple par département et pièces fonctionnelles ) avec mon tri pui lancer ma macro qui ajoute le temps de roulage.

N'est il pas possible de dire à la macro d'afficher dans la LISTBOX seulement les pièces aparentes dans le tableau ( c'est a dire les pièces que j'aurais moi même triées avant )

merci en tout cas, sans toi je suis incapable de faire tout ça !!!!

je te joint le code que j'ai pour la partie ajout de temps :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
Private Sub UserForm_Initialize()
 
    Dim Plage As Range
    Dim I As Integer
    Dim DerLigne As Integer
 
 
    With ActiveSheet
 
        'sur la feuille active en colonne A à partir de la 14 ème ligne
        Set Plage = .Range(.Cells(14, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    With ListBox1
 
        '3 colonnes
        .ColumnCount = 3
        .ColumnWidths = "70;90;100"
        .ListStyle = fmListStyleOption
        .MultiSelect = fmMultiSelectMulti
 
        'rempli la liste
        For I = 1 To 32000
 
            .AddItem Plage(I).Value
            .Column(1, I - 1) = Plage(I).Offset(, 1).Value
            .Column(2, I - 1) = Plage(I).Offset(, 2).Value
 
        Next I
 
    End With
 
End Sub
 
Private Sub CommandButton2_Click()
 
    Dim I As Integer
 
    With Me.ListBox1
 
        For I = 0 To .ListCount - 1
 
            If .Selected(I) = True Then
 
                With ActiveSheet.Range("d" & I + 14)
 
                    .Value = .Value + TextBox1.Value
 
 
                End With
 
            End If
 
        Next I
    End With
 Unload UserForm2
End Sub
 
' ferme le USERFORM au clique sur QUITTER
Private Sub CommandButton3_Click()
 
    UserForm2.Hide
    Unload UserForm2
 
End Sub
 
 
'empeche d'écrire des lettres dans la textbox uniquement des chiffre
 
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
   If InStr("0123456789", Chr(KeyAscii)) = 0 Then KeyAscii = 0: Beep
End Sub

Re,

En admettant que le tri est fait, quand tu lance la Form, les lignes visibles sont chargées dans la liste. L'utilisation du tableau est nécessaire pour mémoriser le numéro de ligne afin d'incrémenter les bonnes :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
 
Dim Tbl() As Integer
 
Private Sub UserForm_Initialize()
 
    Dim Plage As Range
    Dim I As Integer
    Dim J As Integer
 
    With ActiveSheet
 
        'sur la feuille active en colonne A à partir de la 14 ème ligne
        Set Plage = .Range(.Cells(14, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    With ListBox1
 
       '3colonnes
       .ColumnCount = 3
       .ColumnWidths = "100;100;100"
       .ListStyle = fmListStyleOption
       .MultiSelect = fmMultiSelectMulti
 
       'rempli la liste
       For I = 1 To Plage.Count
 
           'recherche la correspondance et rempli la liste
           If Plage(I).EntireRow.Hidden = False Then
 
               J = J + 1
               ReDim Preserve Tbl(1 To J)
 
               Tbl(J) = I
 
               With ListBox1
 
                   .AddItem Plage(I).Value
                   .Column(1, J - 1) = Plage(I).Offset(, 1).Value
                   .Column(2, J - 1) = Plage(I).Offset(, 2).Value
 
               End With
 
           End If
 
       Next I
 
    End With
 
End Sub
 
Private Sub CommandButton1_Click()
 
    Dim I As Integer
 
    With Me.ListBox1
 
        For I = 0 To .ListCount - 1
 
            If .Selected(I) = True Then
 
                With ActiveSheet.Range("D" & Tbl(I + 1) + 13)
 
                    .Value = .Value + CInt(TextBox1.Text)
 
                End With
 
            End If
 
        Next I
 
    End With
 
End Sub

Hervé.

03/06/2015, 16h33
Gado2600

Bonjour,

Ne serait-il pas plus judicieux de stocker les numéros de lignes en question directement dans la zone de liste chargée ?
Il est possible de "masquer" des colonnes en mettant une taille de 0 dans cette même colonne.
Beaucoup plus simple à gérer d'un point de vue personnel.

Cordialement,
03/06/2015, 22h40
schumi22

alors là franchement merci pour tout !!!!! c'est génial :)

( bon pour le message de Gado2600; je dirais probable ^^ car je ne comprend reelement rien à ce qu'on fait ....)

peut être une dernière amélioration à apporter au système si c'est possible,

le tri étant effectué sur mon tableur, puis après avoir lancé la macro d'ajout de temps, n'est il pas possible d'avoir une case en haut de la listbox avec " selectionner tout " ?

en tout cas merci pour tout c'est vraiment top de savoir programmer comme ça ... je pense savoir ( enfin tu as toujours compris pour le moment ^^ ) expliquer ce dont j'ai besoin mais je ne sais pas programmer ... bien dommage.

Bonjour,

Tu pose une case à cocher (CheckBox) sur ta Form et tu ajoute ce code dans le module de la Form :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Private Sub CheckBox1_Click()
 
    Dim I As Integer
 
    With ListBox1
 
        For I = 0 To .ListCount - 1
 
            .Selected(I) = CheckBox1.Value
 
        Next I
 
    End With
 
End Sub

Hervé.

07/06/2015, 22h07
schumi22

1 pièce(s) jointe(s)

Merci Hervé,

Ca avance plutot bien pour ma part. Je te joints le fichier excel.
Si tu as du temps jettes y un oeuil et dit moi si tu vois des choses qui te parraissent suspectes.

et si tu as des ameliorations à me proposer je suis preneur :)

pour tout mot de passe qu'on te demande c'est : "afs" en minuscule