Validation Formulaire avec choix cellule

Version imprimable

28/05/2015, 18h28
jfk15

1 pièce(s) jointe(s)

Validation Formulaire avec choix cellule

Bonjour,

Je suis novice en Vba et je souhaiterais confier à votre expertise mon souci.

J'ai créé un userform que vous pourrez trouver en pièce jointe.
Ce userform contient des :
- boutons d'option répartis dans des cadres;
- un bouton de commande RAZ (macro déjà allouée)
- un bouton valider (je n'arrive pas à faire la macro)
- une zone de texte prévue pour saisir une cellule excel de la feuille active pour que les infos aillent dans cette cellule.

Je souhaite donc pouvoir cocher des boutons d'option, valider le userform et que les informations aillent dans la cellule choisie. Ces informations devront s'écrire les unes derrière les autres dans la même cellule.

Un grand merci à toutes les personnes qui pourront se pencher sur ce problème.

Bonjour, j'ai une proposition qui fonctionne normalement :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Private Sub CommandButton2_Click()
 
'Vérifie préalablement si la textbox est remplie MAIS PAS SI LA CELLULE EXISTE
 
If TextBox1.Text = "" Then
    MsgBox "Remplissez d'abord l'adresse de la cellule à remplir"
    TextBox1.SetFocus
    Exit Sub 'on ferme la macro pour éviter de lire le reste
End If
 
'on déclare les variables
Dim ctrl As Control
Dim Message As String
Dim NbChoix As Integer
Dim NbFrame As Integer
 
For Each ctrl In Me.Controls 'on scanne tous les contrôles du formulaire
    Select Case TypeName(ctrl) 'on regarde leur type
        Case "OptionButton" 'on s'arrête sur les OptionButtons
            If ctrl.Value = True Then 'uniquement sur ceux dont la valeur est true
                NbChoix = NbChoix + 1 'on incrémente le compteur d'OptionButtons
                Message = Message & ctrl.Parent.Caption & " : " & ctrl.Caption & " / " 'On remplit la variable Message qu'on écrira à la fin
            End If
        Case "Frame" 'On s'arrête également sur les Frames
            NbFrame = NbFrame + 1 'on incrémente leur compteur
    End Select
Next ctrl
 
On Error GoTo Erreur
If NbFrame = NbChoix + 1 Then '+ 1 car tu as UNE frame qui ne contient pas d'optionbutton
    Range(TextBox1.Text).Value = Message 'si on a bien le même nombre de frames que de choix, alors on écrit le message dans la cellule
Else
    MsgBox "Impossible de procéder car " & NbFrame - NbChoix - 1 & " points ne sont pas remplis." 'sinon, on écrit un message d'erreur
End If
 
Exit Sub 'si tout se passe bien, on quitte la macro
 
Erreur:  'Sinon, la macro enverra le code directement ici
MsgBox "Il y a eu une erreur, il est probable que la cellule spécifiée n'existe pas, veuillez vérifier l'adresse ou contacter l'administrateur"
TextBox1.SetFocus
 
End Sub

Pour info, pour que tu puisses comprendre le code, j'ai placé des commentaires.

Par contre, je pense que tu ne devrais pas utiliser une textbox mais plutôt une RefEdit qui te permet de spécifier manuellement la cellule en la sélectionnant dans le tableau... Ou mieux : de l'imposer par la macro.

Quentin

PS : si tu veux remplacer les "/" par des retours à la ligne, utilise vbNewLine comme ceci :

Code:

Message = Message & ctrl.Parent.Caption & " : " & ctrl.Caption & vbNewLine 'comme ça, ça écrira et insérera un retour à la ligne à chaque nouvelle info

Les infos seront par ailleurs : le texte associé au parent de l'optionbutton activé (le nom de la frame dans lequel il se trouve) : le texte associé à l'optionbutton (+ retour à la ligne)

En espérant que ce soit clair :D

Quentin

28/05/2015, 20h11
jfk15

Tout d'abord merci beaucoup Quentin !

j'ai essayé de rédiger la macro mais j'étais à 10 000 de trouver cela.
Cela fonctionne parfaitement mais je ne voudrais pas que :
- le nom de la frame apparaisse
- les : après le nom de la frame non plus
- les / entre les appréciations non plus
- et que ce ne soit pas obligatoire de choisir une option dans toutes les frames (on peut en choisir une ou deux si on le souhaite mais pas obligatoirement toutes)

Encore merci beaucoup pour ta justesse et ta rapidité.
Au plaisir de te lire.

Rebonsoir,

Je n'ai pas vérifié mais logiquement ça devrait fonctionner ! Vu que l'on se fout du nombre de frames et tout, j'ai tout supprimé ce qui concernait les frames et le compte des optionbuttons cochés.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub CommandButton2_Click()
 
'Vérifie préalablement si la textbox est remplie MAIS PAS SI LA CELLULE EXISTE
 
If TextBox1.Text = "" Then
    MsgBox "Remplissez d'abord l'adresse de la cellule à remplir"
    TextBox1.SetFocus
    Exit Sub 'on ferme la macro pour éviter de lire le reste
End If
 
'on déclare les variables
Dim ctrl As Control
Dim Message As String
 
For Each ctrl In Me.Controls 'on scanne tous les contrôles du formulaire
    If TypeName(ctrl) = "OptionButton" 'on s'arrête sur les contrôles dont le type est "OptionButton" uniquement
            If ctrl.Value = True Then 'Plus précisément sur ceux dont la valeur est True 
                Message = Message & ctrl.Caption & " " 'On remplit la variable Message qu'on écrira à la fin, entre 2 valeurs il y aura un espace (libre à toi de changer)
            End If
    End If
Next ctrl
 
On Error GoTo Erreur
Range(TextBox1.Text).Value = Message 'On écrit dans la cellule choisie le message formé par les optionbuttons
 
Exit Sub 'si tout se passe bien, on quitte la macro
 
Erreur:  'Sinon, la macro enverra le code directement ici
MsgBox "Il y a eu une erreur, il est probable que la cellule spécifiée n'existe pas, veuillez vérifier l'adresse ou contacter l'administrateur"
TextBox1.SetFocus
 
End Sub

Tu pourrais sinon garder le même code que précédemment et t'arranger pour qu'au lieu de mettre un message d'erreur disant que toutes les frames ne sont pas remplies et quitter, alors tu précises "attention, tous les champs ne sont pas remplis, continuer ? " et si c'est non, alors tu quittes.

Quentin

C'est incroyable mais je crois que suis arrivé à résoudre cela.
Merci beaucoup à ceux qui se sont penchés sur mon souci.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub CommandButton2_Click()
 
'Vérifie préalablement si la textbox est remplie MAIS PAS SI LA CELLULE EXISTE
 
If TextBox1.Text = "" Then
    MsgBox "Remplissez d'abord l'adresse de la cellule à remplir"
    TextBox1.SetFocus
    Exit Sub 'on ferme la macro pour éviter de lire le reste
End If
 
'on déclare les variables
Dim ctrl As Control
Dim Message As String
Dim NbChoix As Integer
Dim NbFrame As Integer
 
For Each ctrl In Me.Controls 'on scanne tous les contrôles du formulaire
    Select Case TypeName(ctrl) 'on regarde leur type
        Case "OptionButton" 'on s'arrête sur les OptionButtons
            If ctrl.Value = True Then 'uniquement sur ceux dont la valeur est true
                NbChoix = NbChoix + 1 'on incrémente le compteur d'OptionButtons
                Message = Message & ctrl.Caption & "  "  'On remplit la variable Message qu'on écrira à la fin
            End If
        Case "Frame" 'On s'arrête également sur les Frames
            NbFrame = NbFrame + 1 'on incrémente leur compteur
    End Select
Next ctrl
     Range(TextBox1.Text).Value = Message 'si on a bien le même nombre de frames que de choix, alors on écrit le message dans la cellule
 
Exit Sub 'si tout se passe bien, on quitte la macro
 
Erreur:  'Sinon, la macro enverra le code directement ici
MsgBox "Il y a eu une erreur, il est probable que la cellule spécifiée n'existe pas, veuillez vérifier l'adresse ou contacter l'administrateur"
TextBox1.SetFocus
 
End Sub

28/05/2015, 23h05
Invité

Bonsoir,
remplace le textbox1 par un refedite et tu pourras selectionner la celulle avec la sourie dans la feuille de calcul EXCEL!

Bonjour,
le code ci dessous fonctionne parfaitement pour mon besoin. J'ai toutefois l'impression qu'il écrit les appréciations dans l'ordre où elles ont été créées dans mon userform. Je préfèrerais qu'elles apparaissent dans l'ordre où elles sont cliquées. Est ce que vous avez une idée de ce qu'il faut modifier dans ce code.
Merci.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub CommandButton2_Click()
 
'Vérifie préalablement si la textbox est remplie MAIS PAS SI LA CELLULE EXISTE
 
If TextBox1.Text = "" Then
    MsgBox "Remplissez d'abord l'adresse de la cellule à remplir"
    TextBox1.SetFocus
    Exit Sub 'on ferme la macro pour éviter de lire le reste
End If
 
'on déclare les variables
Dim ctrl As Control
Dim Message As String
Dim NbChoix As Integer
Dim NbFrame As Integer
 
For Each ctrl In Me.Controls 'on scanne tous les contrôles du formulaire
    Select Case TypeName(ctrl) 'on regarde leur type
        Case "OptionButton" 'on s'arrête sur les OptionButtons
            If ctrl.Value = True Then 'uniquement sur ceux dont la valeur est true
                NbChoix = NbChoix + 1 'on incrémente le compteur d'OptionButtons
                Message = Message & ctrl.Caption & "  "  'On remplit la variable Message qu'on écrira à la fin
            End If
        Case "Frame" 'On s'arrête également sur les Frames
            NbFrame = NbFrame + 1 'on incrémente leur compteur
    End Select
Next ctrl
 
     On Error GoTo Erreur
Range(TextBox1.Text).Value = Message 'On écrit dans la cellule choisie le message formé par les optionbuttons
 
Exit Sub 'si tout se passe bien, on quitte la macro
 
Erreur:  'Sinon, la macro enverra le code directement ici
MsgBox "Il y a eu une erreur, il est probable que la cellule spécifiée n'existe pas, veuillez vérifier l'adresse ou contacter l'administrateur"
TextBox1.SetFocus
 
End Sub

Bonjour,

Citation:

Je préfèrerais qu'elles apparaissent dans l'ordre où elles sont cliquées. Est ce que vous avez une idée de ce qu'il faut modifier dans ce code.

Dans ce cas, ceci devient un peu plus complexe car il faut connaître l'ordre de clic et pour ça, il faut intercepter l'évènement "Click" de chaque bouton d'option.
Vu le nombre de bouton d'option, il est préférable d'utiliser un module de classe qui permet un évènement commun à tous les boutons.
Donc, ajouter au projet un module de classe nommé Classe1 (nom donné par défaut) puis coller le code ci-dessous dans le module :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 Public WithEvents GroupeOpt As MSForms.OptionButton Private Sub GroupeOpt_Click() If GroupeOpt.Value = True Then K = K + 1 ReDim Preserve Tbl(1 To K) Tbl(K) = GroupeOpt.Caption End If End Sub
Ensuite, coller le code ci-dessous dans le module de la Form et tout en haut après "Option Explicit" (pour la variable principalement) :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 Dim Opt() As New Classe1 Private Sub UserForm_Initialize() Dim Ctrl As Control Dim I As Integer For Each Ctrl In Me.Controls If TypeName(Ctrl) = "OptionButton" Then I = I + 1 ReDim Preserve Opt(1 To I) Set Opt(I).GroupeOpt = Ctrl End If Next Ctrl End Sub
Et pour finir, ajouter au projet un module standard afin de déclarer deux variables de portée "Projet" afin qu'elles soient accessibles depuis les modules qui en ont besoin :
Code:

1 2 3 Public Tbl() As String Public K As Integer
Et tu remplace le code du bouton "CommandButton2" par celui qui suit (je suis parti du code donné par Quentin) :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 Private Sub CommandButton2_Click() 'on déclare les variables Dim Ctrl As Control Dim Message As String Dim NbChoix As Integer Dim NbFrame As Integer Dim I As Integer 'Vérifie préalablement si la textbox est remplie MAIS PAS SI LA CELLULE EXISTE If TextBox1.Text = "" Then MsgBox "Remplissez d'abord l'adresse de la cellule à remplir" TextBox1.SetFocus Exit Sub 'on ferme la macro pour éviter de lire le reste End If For I = 1 To UBound(Tbl) Message = Message & Tbl(I) Next I Range(TextBox1.Text).Value = Message 'si on a bien le même nombre de frames que de choix, alors on écrit le message dans la cellule Erase Tbl() K = 0 Exit Sub 'si tout se passe bien, on quitte la macro Erreur: 'Sinon, la macro enverra le code directement ici MsgBox "Il y a eu une erreur, il est probable que la cellule spécifiée n'existe pas, veuillez vérifier l'adresse ou contacter l'administrateur" TextBox1.SetFocus End Sub
Il ne te reste plus qu'à tester.

En ce qui concerne la cellule cible, si tu ne veux pas utiliser le contrôle RefEdit, je te propose une alternative. Tu colle le code ci-dessous dans le module de la feuille de calcul et tu mets la propriété "ShowModal" de la Form à "False" :
Code:

1 2 3 4 5 6 7 8 Private Sub Worksheet_SelectionChange(ByVal Target As Range) On Error Resume Next UserForm1.TextBox1.Text = Target.Address(0, 0) AppActivate ("UserForm1") End Sub
En cliquant dans une cellule de la feuille, son adresse est entrée automatiquement dans le TextBox mais pour ce faire, il ne faut pas qu'elle soit déjà sélectionnée. Bon courage !

Hervé.

Petite précision ! Dans mon code je n'ai pas géré la modification de choix, c'est possible mais le code sera plus complexe.

Hervé.

30/05/2015, 21h34
jfk15

Cela fonctionne parfaitement. C'est vraiment super.

Merci beaucoup pour votre aide et félicitations pour vos connaissances. :)
02/06/2015, 21h38
jfk15

Bonjour,

Je me suis servi de ma feuille excel ce soir et comme un imbécile j'ai saisi l'adresse d'une cellule que j'avais verrouillée comme cible de la macro. Finalement, tant mieux car cela a planté la macro et j'ai pu me rendre compte de ce souci. Comme je ne serai pas le seul à me servir de ce fichier, est il possible d'avoir un message d'alerte qui bloque la macro car elle a vérifié avant si l'adresse de la cellule était une cellule verrouillée ou pas.

Merci.

Bonjour,

Tester la propriété "Locked" :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
Sub Test()
 
    If Range("C5").Locked Then
 
        MsgBox "Vérrouillée !"
 
    Else
 
        MsgBox "Dévérrouillée !"
 
    End If
 
End Sub

Hervé.

03/06/2015, 16h49
jfk15

Bonjour,

Excusez moi car j'ai sûrement dû mal présenter ma question :

Au départ, j'ai créé un userform où je devais cocher des options et je voulais que les options cochées aillent dans une cellule que je renseignais dans l'userform (dans une textbox). Un membre du forum a eu la gentillesse de m'aider et cela fonctionne parfaitement.

Un soir par mégarde, j'ai saisi dans la textbox une cellule verouillée de la feuille qui est protégée. Du coup, cela a fait planter la macro. Dans le fond ce n'est pas hyper grave, j'ai compris le souci et si je me trompe un autre jour ça sera bien fait pour moi. Mais je ne suis pas le seul à utiliser cette feuille.

J'aurais aimé avoir un message d'avertissement qui me dise "tu es une andouille, la cellule que tu as choisie pour destination est verrouillée et ça va faire planter la macro. Essaie une autre cellule !

J'ai été plus clair? que faut il modifier dans le code de theze un peu plus haut?

Merci

Bonjour,

Tu peux (devrais) implanter une gestion d'erreurs digne de ce nom

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub quelque_chose()
    on error goto piègeàerreurs
    la macro 
    exit sub
:piègeàerreurs
    select case err
       case numéro d'erreur pour cellule verrouillée
            Fais quelque chose pour arrêter ou corriger l'erreur
            resume (ou exit sub, ou resume next, ou stop, ou end)
       case autre numéro d'erreur
            Fais quelque chose pour arrêter ou corriger l'erreur
            resume (ou exit sub, ou resume next, ou stop, ou end)
     end select
end sub

Si les numéros d'erreur ne sont pas dans l'aide ou sur MSDN, tu mets un point d'arrêt à quelque part, un espion sur err, tu exécutes au pas-à-pas et tu regardes la valeur de err dans la fenêtre espions.

Bonjour,

Une piste, j'ai intégré un petit gestionnaire d'erreur (pas évolué comme te le propose Clément) mais il permet de gérer si l'adresse est incorrecte et on teste aussi si la cellule est verrouillée. Adapte :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
Private Sub CommandButton2_Click()
 
    'on déclare les variables
    Dim Ctrl As Control
    Dim Cel As Range
    Dim Message As String
    Dim NbChoix As Integer
    Dim NbFrame As Integer
    Dim I As Integer
 
 
    'Vérifie préalablement si la textbox est remplie
    If TextBox1.Text = "" Then
 
        MsgBox "Remplissez d'abord l'adresse de la cellule à remplir"
        TextBox1.SetFocus
        Exit Sub 'on ferme la macro pour éviter de lire le reste
 
    End If
 
    'gère l'erreur d'une adresse non conforme
    On Error Resume Next
    Set Cel = Range(TextBox1.Text)
 
    If Err.Number <> 0 Then
 
        MsgBox "Adresse de cellule invalide !"
        Exit Sub
 
    End If
 
    'annule le gestionnaire
    On Error GoTo 0
 
    'vérifie si la cellule est déverrouillée
    If Range(TextBox1.Text).Locked Then
 
        MsgBox "Attention, la cellule '" & TextBox1.Text & "' est verrouillée," & _
        "il n'est pas possible de lui attribuer une valeur !"
 
        Exit Sub
 
    End If
 
    For I = 1 To UBound(Tbl)
 
        Message = Message & Tbl(I)
 
    Next I
 
    Range(TextBox1.Text).Value = Message 'si on a bien le même nombre de frames que de choix, alors on écrit le message dans la cellule
    Erase Tbl()
    K = 0
 
End Sub

Hervé.

04/06/2015, 08h01
jfk15

Je viens de modifier le code de mon userform et j'ai testé toutes les possibilités d'erreurs et cela fonctionne parfaitement !

Très sincèrement Merci car je passe des heures et des heures et des heures et des ...... sur un projet avec des connaissances vba qui date d'une semaine. J'arrive à me débrouiller la plupart du temps avec l'enregistreur de Macro dans Excel (pratique quand on ne sait pas programmer) ou en cherchant sur google des cas un peu similaires au mien (merci à tout ceux qui comme vous donne des solutions) mais parfois comme là c'est trop compliqué et je manque de connaissances et/ou je ne trouve pas un exemple ailleurs assez proche de mon pb pour l'adapter.

A ce propos auriez vous un lien qui va vers un cours (pour débutant) pour créer un code qui remplisse une cellule par l'intermédiaire d'un userform (comme ici quoi). Un cours qui explique ligne par ligne pour que j'essaie.

Merci à vous.
04/06/2015, 08h36
Invité

Bonjour,

Cours et tutoriels de formation pour apprendre Excel http://excel.developpez.com/cours/
04/06/2015, 22h45
jfk15

Merci :)

je vais essayer d'en apprendre un peu plus.

Bonne soirée.