Lecture les fichier Text

Bonjour,

Je voudrais récupérer la 8eme ligne dans un fichier ListeUser.txt.

Mais impossible à d’afficher la 8eme ligne à partir du code ci-dessous !

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
	Function Lecture()
				dim ScriptFileName,objFSO,FileOut,i,mot,Temp 
                                Temp = "C:\test"
				ScriptFileName = Temp & "\ListeUser.txt"
				Set objFSO = CreateObject("Scripting.FileSystemObject")
				Set InputFile = objFSO.OpenTextFile(ScriptFileName)
				i = 1
				Do Until InputFile.atEndOfStream
                                   i = i + 1
                                   if i = 8 Then
					mot = InputFile.Readline
                                   end if 
				loop
                                Lecture = mot 
				InputFile.close
				if objFSO.FileExists(ScriptFileName) Then objFSO.DeleteFile(ScriptFileName)
	End Function
        Msgbox Lecture()

Pouvez vous corriger mon problème svp !!!

Je vous remercie d'avance !! :hola:

Salut

Il me semble d’ailleurs que tu te trouves dans une boucle infini.

Code:

1
2
3
4
5
6
7
                i = 1
                Do Until InputFile.atEndOfStream
                    i = i + 1
                    If i = 8 Then
                        mot = InputFile.Readline
                    End If
                Loop

En fait tu ne lis que la première ligne.

Citation:

ReadLine, méthode
Lit une ligne entière (jusqu'au caractère de nouvelle ligne mais non compris celui-ci)

Ta variable i à pour valeur 1 avant de rentrer dans la boucle, avant de lire la première ligne tu lui donnes la valeur 2, tu boucles 7 fois se qui incrémente sa valeur à 8, la condition If est donc True , là pour la première fois tu lis la première ligne du fichier Readline, mot contient donc la valeur de la première ligne, tu sors de la condition If ....... End If, et tu continus à boucler en incrémentant i.
Puisque il n'y a pas d'autre condition de sortie de la boucle, tu restes bloqué à l’intérieur.
Ton code pourrait ressembler à

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
    Function Lecture()
                Dim ScriptFileName, InputFile, objFSO, i, mot, Temp
                Temp = "C:\test"
		ScriptFileName = Temp & "\ListeUser.txt"
		Set objFSO = CreateObject("Scripting.FileSystemObject")
                If objFSO.FileExists(ScriptFileName) Then
					ScriptFileName = Temp & "\ListeUser.txt"
					Set InputFile = objFSO.OpenTextFile(ScriptFileName)
					i = 1
					Do Until InputFile.atEndOfStream
						mot = InputFile.Readline
						If i = 8 Then Exit Do
						i = i + 1
					Loop
					Lecture = mot
					InputFile.Close
					Set InputFile = Nothing
					objFSO.DeleteFile (ScriptFileName)
					Else
					Lecture = "Fichier introuvable"
				End If
				Set objFSO = Nothing
    End Function

Il y a plus simple

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Function LectureUneLigne(CheminNomFichier, QuelNumero)
    Const ForReading = 1
    Dim objFSO, InputFile
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    If objFSO.FileExists(CheminNomFichier) Then
        'Ouverture et lecture du fichier
        Set InputFile = objFSO.OpenTextFile(CheminNomFichier, ForReading)
        'recuperation de la ligne voulue
        LectureUneLigne = Split(InputFile.ReadAll, vbNewLine)(QuelNumero - 1)
        InputFile.Close
        Set InputFile = Nothing
        Else
        LectureUneLigne = "Fichier introuvable"
    End If
    Set objFSO = Nothing
End Function
 
MsgBox LectureUneLigne("C:\test\ListeUser.txt", 8)

:salut:
Quelque chose comme ceci :

Code:

1
2
3
4
5
6
7
8
9
10
11
Const ForReading = 1
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("mylogfile.log", ForReading)
 
For i = 1 to 7
    objTextFile.ReadLine
Next
 
strLine = objTextFile.ReadLine
Wscript.Echo strLine
objTextFile.Close

Ahhhh Merci bien !!