méthode find et largeur de colonne ?!

Version imprimable

Bonjour à tous,

J'ai besoin d'aide dans la création de ma première macro:
J'utilise la méthode find dans pour trouver la cellule qui contient une certaine date.
La plage de recherche est la ligne 2:2 de mon tableur. Elle contient dans chaque cellule une date différente (au format date) : A2=18/05/2015 ; B2=19/05/205; ... etc. A noter que le texte est écrit verticalement et non horizentalement.

La chose surprenante est que le résultat de ma recherche avec find dépend de la largeur des colones qui contiennent la date ... !?

Je m'explique:
- Dans le premier cas mes colonnes font 10 de largeur et je trouve bien la cellule qui contient la date voulue
- Ensuite je réduit la largeur des colone à 2.5 et là find ne me retourne rien... et je ne change QUE la largeur des colones, le contenue est identique.

Voici le code que j'utilise:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Sub test() Dim i As Integer Dim weekdate As Date weekdate = "22/05/2015" Sheets("Sheet2").Activate Set R = Range("2:2").Find(What:=weekdate, LookAt:=xlWhole) If Not R Is Nothing Then Sheets("Sheet2").Cells(i + 5, 5) = R.Row Sheets("Sheet2").Cells(i + 5, 6) = R.Column Else Sheets("Sheet2").Cells(i + 5, 5) = "Vide" End If End Sub
Merci d'avance pour votre aide !

27/05/2015, 13h21
eriiic

Bonjour,

Essaie en ajoutant le paramètre LookIn:=xlFormulas.
Avec LookIn:=xlValues .Find recherche dans la propriété .Text de la cellule, donc ce qui est affiché.

eric
27/05/2015, 13h58
wantstofly

En effet ça marche mieux avec LookIn:=xlFormulas

Le souci est que les dates sont obtenues par formule: A2=18/05/2015 ; B2=A2+1 ; ...etc donc si j'utilise "LookIn:=xlFormulas" ça ne marche pas.

Je ne comprends pas en quoi changer la largeur de colone affecte la propriété .Text de la cellule?
27/05/2015, 14h23
Daniel.C

Bonjour,

Personnellement, je n'utilise jamais "Find" quand il s'agit de trouver des dates. Fais une boucle et teste les cellules.
27/05/2015, 15h12
eriiic
Comme sous-entend daniel, .find sur des dates est souvent galère.

Fonctionne avec des dates en formule dans B, même si tu réduis pour n'avoir que des #### à l'affichage :
Code:

1 2 3 Dim c As Range, dat1 As String dat1 = "03/01/2015" Set c = [B:B].Find(CDate(dat1), LookIn:=xlValues)
voire même :
Code:

1 2 3 Dim c As Range, dat1 As String dat1 = "03/01/2015" Set c = [B:B].Find(Int(CDate(dat1)), LookIn:=xlValues)
si des heures sont présentes.

eric

PS: sinon la méthode simple que j'avais trouvé avec un fichier très rétif : mettre la colonne date au format nombre, faire le .find, remettre le format date voulu.

Bonjour.

Find fonctionne très bien avec xlFormulas.
Mais il ne tient pas compte des formules.
Une solution : transformer les formules en constantes dans une plage temporaire et faire la recherche dans cette plage.

Voici pourquoi Find avec xlValues est compliqué pour trouver des dates ou des nombres.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Sub Demo_xlformulas_vs_xlValues()
  Dim c As Range, dat1 As String, dat2 As String
 
  Set cellB2 = Cells(2, "B")
 
    dat1 = "03/01/2015"
 
   'xlFormulas 'Contrainte : la valeur cherchee doit etre de type Date pour trouver une date dans des cellules au format Date,
   'de type Numerique pour trouver un nombre dans des cellules ayant un format Numerique,
   'de type String pour trouver un String dans des cellules au format Texte
 
    cellB2.NumberFormat = "@" 'La cellule est au format Texte
    cellB2.FormulaLocal = dat1
 
    Set c = [B:B].Find(CDate(dat1), LookIn:=xlFormulas, lookat:=xlWhole) 'Non
    Set c = [B:B].Find(dat1, LookIn:=xlFormulas, lookat:=xlWhole) 'Oui
 
    cellB2.NumberFormat = "d/m/yyyy" ' La cellule est au format Date
    cellB2.FormulaLocal = dat1
 
    Set c = [B:B].Find(CDate(dat1), LookIn:=xlFormulas, lookat:=xlWhole) 'Oui
    Set c = [B:B].Find(dat1, LookIn:=xlFormulas, lookat:=xlWhole) 'Non
 
   'xlValues
 
   'xlValues: Contrainte 1 : On doit utiliser AutoFit, sinon la largeur de la cellule doit toujours etre suffisante
 
   'xlValues 'Contrainte 2 : si le format de cellule est "m/d/yyyy",
                           'la valeur cherchee doit etre de type Date
 
    cellB2.NumberFormat = "m/d/yyyy"
    cellB2.FormulaLocal = dat1
    Columns(cellB2.Column).AutoFit
 
    Set c = [B:B].Find(CDate(dat1), LookIn:=xlValues, lookat:=xlWhole) 'Oui
    Set c = [B:B].Find(dat1, LookIn:=xlValues, lookat:=xlWhole) 'Non
    dat2 = cellB2.Text
    Set c = [B:B].Find(dat2, LookIn:=xlValues, lookat:=xlWhole) 'Non
 
  'xlValues 'Contrainte 3 : si le format de cellule n'est pas "m/d/yyyy",
                         'la valeur cherchee doit etre de type String
  ' et le format de la valeur cherchee doit etre identique au format de la cellule
  'c-a-d que la valeur affichee doit etre identique a la valeur cherchee
    cellB2.NumberFormat = "d/m/yyyy"
    cellB2.FormulaLocal = dat1
    Columns(cellB2.Column).AutoFit
 
    dat2 = cellB2.Text
    Set c = [B:B].Find(dat2, LookIn:=xlValues, lookat:=xlWhole) 'Oui pq dat2 = cellB2.Text
    Set c = [B:B].Find(CDate(dat2), LookIn:=xlValues, lookat:=xlWhole) 'Non
 
    Set c = [B:B].Find(dat1, LookIn:=xlValues, lookat:=xlWhole) 'Non. Oui si dat1 = cellB2.Text
    Set c = [B:B].Find(CDate(dat1), LookIn:=xlValues, lookat:=xlWhole) 'Non
 
 
End Sub

27/05/2015, 18h40
Daniel.C

Citation:

Find fonctionne très bien avec xlFormulas.
Mais il ne tient pas compte des formules.

C'est une conception du bon fonctionnement ? :)
27/05/2015, 20h09
Docmarti

Citation:

Envoyé par Daniel.C

C'est une conception du bon fonctionnement ? :)

Effectivement. Find avec xlFormulas est très spécialisé sans l'être trop comme Find avec xlValues qui l'est trop, ou pas assez comme Match qui ne fait pas la différence entre les cellules au format Date et celles au format Nombre.

Ceci dit, chacune des 3 méthodes a son utilité propre :

fIND xlValues effectue sa recherche dans la propriété TEXT,
fIND xlFormulas dans la propriété FORMULA,
ET Match dans la propriété VALUE
28/05/2015, 10h13
wantstofly

Merci à tous pour votre aide. Je comprend mieux les subtilités de find maintenant ;)

Dans mon cas j'ai pas trouvé de façon de faire fonctionner find. J'ai d'un côté une date, de l'autre une formule qui donne une date et je ne souhaite pas changer la taille des colonnes.
Comme dit précédement par Docmarti le plus simple est pour moi de transformer les formules en constantes. Et si j'ai le temps je ferai une boucle à la main sur la plagede recherche pour remplacer find.

Encore merci. A+