blocage sur une instruction For Next et Exit For

Version imprimable

Bonjour,

Je n'arrive pas à voir quel est le soucis dans mon code mais le programme ne passe qu'une seule fois dans le for et je ne sais pas pourquoi il ne continue pas tous les Lignes de 7 à 30, sachant qu'il est sencé s'arreter à 28....

Voyez vous quel est le pb?

merci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Sub testcopiedonneeestcdW2()
'
'
Dim PremiereLigne As Integer
Dim DerniereLigne As Integer
Dim Ligne As Integer
 
PremiereLigne = 7
DerniereLigne = 7
 
Sheets("TCD_W2").Select
 
Var = Range("A18").Value
MsgBox ("test=" & Var)
 
 
    For Ligne = PremiereLigne To 30
 
MsgBox ("Ligne=" & Ligne)
 
        If Cells(Ligne, 1).Value = "Total général" Then DerniereLigne = Ligne - 1
 
           Exit For
 
    Next Ligne
 
MsgBox ("PremiereLigne =" & PremiereLigne)
MsgBox ("DerniereLigne =" & DerniereLigne)
 
Range(Cells(PremiereLigne, 1), Cells(DerniereLigne, 2)).Select
 
Selection.Copy
 
Sheets("INDEX").Select
 
Range(I8).Select
 
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
 
 
End Sub

03/05/2015, 18h38
Marc-L

Bonjour, bonjour !

A quoi peut bien servir la ligne n°23 à part de sortir de la boucle dès la première ligne ?‼

Vérifier en mode pas pas via la touche F8 ou en plaçant un point d'arrêt …

Consulter dans l'aide VBA le bloc d'instructions If … Then … End If …

SI j'ai bien compris le besoin, environ cinq lignes de code sont nécessaires !

_____________________________________________________________________________________________________
Je suis Charlie - Je suis Bardo

Le but est de sortir du traitement For lorsque la cellule traitée contient "Total général"et de déterminer la ligne qui est juste au dessus de "Total général".

Dans mon code initial j'avais End If après le Exit For mais cela bugger sur le End If....
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 Dim PremiereLigne As Integer Dim DerniereLigne As Integer Dim Ligne As Integer PremiereLigne = 7 DerniereLigne = 7 Sheets("TCD_W2").Select For Ligne = PremiereLigne To 30 MsgBox ("Ligne=" & Ligne) If Cells(Ligne, 1).Value = "Total général" Then DerniereLigne = Ligne - 1 Exit For End If Next Ligne

heu

ton instructruction apres "then" est mal placée
soit tu fait ca

Code:

1
2
3
4
5
6
7
 For Ligne = PremiereLigne To 30
 msgBox ("Ligne=" & Ligne)
         If Cells(Ligne, 1).Value = "Total général" Then 
         DerniereLigne = Ligne - 1
            Exit For
      end if  
Next Ligne

soit tu fait ca

Code:

1
2
3
4
5
For Ligne = PremiereLigne To 30
 MsgBox ("Ligne=" & Ligne)
         If Cells(Ligne, 1).Value = "Total général" Then DerniereLigne = Ligne - 1: Exit For
  
 Next Ligne

Bonjour,

Et en faisant une recherche de la valeur avec Find ? A voir :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub testcopiedonneeestcdW2()
 
    Dim Cel As Range
    Dim PremiereLigne As Integer
    Dim DerniereLigne As Integer
 
    PremiereLigne = 7
    DerniereLigne = 7
 
    With Sheets("TCD_W2")
 
        Set Cel = .Range("A7:A30").Find("Total général", , xlValues, xlWhole)
 
        If Not Cel Is Nothing Then DerniereLigne = Cel.Row - 1
        '"DerniereLigne + 1" car on commence à la ligne 8
        Sheets("INDEX").Range(Sheets("INDEX").Cells(8, 9), Sheets("INDEX").Cells(DerniereLigne + 1, 10)).Value = .Range(.Cells(PremiereLigne, 1), .Cells(DerniereLigne, 2)).Value
 
    End With
 
End Sub

Hervé.

Merci Patrick, effectivement je positionnais mal mon code, et ta deuxième option est plus simple je trouve.

Par contre These, ton code m'interesse mais je ne comprends pas bien les lignes avec un point d'interrogation, pourrais tu m'expliquer ?
Code:

1 2 3 4 5 6 7 8 9 With Sheets("TCD_W2") Set Cel = .Range("A7:A30").Find("Total général", , xlValues, xlWhole) '? If Not Cel Is Nothing Then DerniereLigne = Cel.Row - 1 '? '"DerniereLigne + 1" car on commence à la ligne 8 Sheets("INDEX").Range(Sheets("INDEX").Cells(8, 9), Sheets("INDEX").Cells(DerniereLigne + 1, 10)).Value = .Range(.Cells(PremiereLigne, 1), .Cells(DerniereLigne, 2)).Value End With

05/05/2015, 07h14
Theze
Bonjour,
Code:

1 2 Set Cel = .Range("A7:A30").Find("Total général", , xlValues, xlWhole)
Une recherche de la valeur "Total général" est effectuée sur la plage A7:A30 à l'aide de la méthode "Find" avec correspondance exacte (xlWhole) comme c'est une fonction native, elle est compilée et donc plus rapide qu'une boucle.
Code:

1 2 If Not Cel Is Nothing Then DerniereLigne = Cel.Row - 1
"Find" retourne un objet "Range", ici une cellule, (d'où la présente de l'instruction "Set" --> Set Cel =...) dès la première valeur trouvée. Dans mon code, l'objet Range retourné est affecté à la variable "Cel" mais il faut contrôler si un Range est bien retourné avant de vouloir s'en servir car si elle n'a rien trouvée, elle ne peut rien retourner et si on utilise la variable sans avoir contrôlé son initialisation, plantage !
Dans la suite de ton code, tu utilise la variable "DerniereLigne" pour la récup. des valeurs donc, j'utilise la propriété "Row" pour connaitre la ligne où est située "Total général" et je soustrais 1 à ce numéro de ligne pour ne pas la prendre en compte.

J'espère avoir été clair dans mes explications sinon, reviens pour plus de précisions.

Hervé.
05/05/2015, 08h00
valérieF

Merci Hervé, c'est plus clair.

Mais c'est surtout le "If Not Cel Is Nothing" que je ne comprends pas bien....

Et quand tu dis :

Citation:

l'objet Range retourné est affecté à la variable "Cel" mais il faut contrôler si un Range est bien retourné avant de vouloir s'en servir car si elle n'a rien trouvée, elle ne peut rien retourner et si on utilise la variable sans avoir contrôlé son initialisation, plantage !

Cela veut dire que si aucune valeur n'est trouvé ca plante mais si j'affecte une valeur à Cel en amont ca ne plantera pas non?

merci pour ton aide
Valérie

Re,

Citation:

Cela veut dire que si aucune valeur n'est trouvé ca plante mais si j'affecte une valeur à Cel en amont ca ne plantera pas non?

Non, puisque tu fais un contrôle sur la variable :
Code:

1 2 If Not Cel Is Nothing Then
peut se traduire "Si Cel n'est Pas Rien Alors"
et comme l'instruction :
Code:

1 2 DerniereLigne = Cel.Row - 1
est à la suite de Then, le compilateur sait qu'il faut interpréter cette instruction si "Not Cel Is Nothing" = Vrai
l'instruction "If Not Cel Is Nothing Then" est égale à :
Code:

1 2 If Not Cel Is Nothing = True Then
que tu peux contrôler avec :
Code:

1 2 MsgBox Not Cel Is Nothing
si la variable a été initialisé car une valeur a été trouvée, le message sera "Vrai" sinon, "Faux"

Hervé.

Re,

Si tu enlève Not, tu as le résultat inverse :
Code:

1 2 MsgBox Cel Is Nothing
et dans ce cas, ton code serait alors :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 Sub testcopiedonneeestcdW2() Dim Cel As Range Dim PremiereLigne As Integer Dim DerniereLigne As Integer PremiereLigne = 7 DerniereLigne = 7 With Sheets("TCD_W2") Set Cel = .Range("A7:A30").Find("Total général", , xlValues, xlWhole) If Cel Is Nothing Then 'si pas initialisée.. 'dans ce cas, ne rien faire ! Else 'sinon, si initialisée... DerniereLigne = Cel.Row - 1 '"DerniereLigne + 1" car on commence à la ligne 8 Sheets("INDEX").Range(Sheets("INDEX").Cells(8, 9), Sheets("INDEX").Cells(DerniereLigne + 1, 10)).Value = .Range(.Cells(PremiereLigne, 1), .Cells(DerniereLigne, 2)).Value End If End With End Sub
Hervé.

15/05/2015, 16h54
valérieF

merci pour tes explications Hervé