Sélectionner une feuille avec variable

Version imprimable

Bonjour,

C'est tout bête mais j'essaie de modifier ma macro pour qu'elle puisse traiter une liste d'onglets et ca bug :

Voici le code :
Code:

1 2 3 4 5 6 7 8 9 Range("G8:G22").Select 'plage de données For Each Cell In Selection numCC = Cell.Value MsgBox (numCC) 'ca me rapporte bien ma donnée qui correspond au nom d'un onglet (exemple : 1421) Sheets(numCC).Select 'ca bug ici .....
Merci de votre aide

Bonjour,

Il vous faut déclarer vos variables.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 Sub EssaiSelect() Dim Cell As Range Dim NumCC As String With ActiveSheet .Range("G8:G22").Select 'plage de données For Each Cell In Selection NumCC = Cell.Value MsgBox (NumCC) 'ca me rapporte bien ma donnée qui correspond au nom d'un onglet (exemple : 1421) Sheets(NumCC).Select 'ca bug plus ici Next Cell End With End Sub
Nb : Il est rarement utile de sélectionner un onglet. Regardez plutôt la façon de travailler avec un Set Sh = Sheets(NumCC) où Sh est déclaré comme Worksheet par exemple.

Cordialement.

Tout juste :-) j'ai tendance à oublier de déclarer mes variables et comme souvent ça fonctionne sans je ne pense pas à ca quand ca bug....
Par contre je n'ai pas bien saisi l'intérêt du Set Sh et comment l'utiliser dans mon cas car j'ai besoin de sélectionner les onglets pour faire ma mise en forme et créer le pdf de chaque onglets par la suite.

Voici la macro :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Sub MEF_et_génération_PDF_pour_reporting_DA()
'
'
 
Application.ScreenUpdating = False
 
    Dim Cell As Range
    Dim NumCC As String
    Dim CheminRep As String
    Dim MoisAnnée As String
 
    Sheets("INDEX").Select
 
    CheminRep = Range("G2").Value
    MoisAnnée = Range("G3").Value
 
    Range("G8:G22").Select 'plage de données des CC
 
    For Each Cell In Selection
    NumCC = Cell.Value
 
 
'MsgBox (NumCC)
 
 
    Sheets(NumCC).Select
 
    Range("B3").Select
    ActiveSheet.Outline.ShowLevels RowLevels:=0, ColumnLevels:=2 'ouvre les regroupements de colonnes
    Columns("Y:AA").EntireColumn.Hidden = True
    ActiveSheet.Outline.ShowLevels RowLevels:=0, ColumnLevels:=1 'ferme les regroupements de colonnes
    Columns("Y:AA").EntireColumn.Hidden = False
    Range("B3").Select
 
    ActiveSheet.Outline.ShowLevels RowLevels:=2 'ouvre les regroupements de lignes
    Rows("77:80").EntireRow.Hidden = True
    ActiveSheet.Outline.ShowLevels RowLevels:=1  'ferme les regroupements de lignes
    Rows("77:80").EntireRow.Hidden = False
    Range("B3").Select
 
    Columns("Z:Z").EntireColumn.AutoFit
    Rows("81:81").EntireRow.AutoFit
 
    Range("B3").Select
 
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=CheminRep & "\" & NumCC & "_" & MoisAnnée & "_Suivi Frais " & ".pdf"
 
    Range("B3").Select
 
    ActiveSheet.Outline.ShowLevels RowLevels:=2 'ré-ouvre les regroupements de lignes
 
    Next
 
    MsgBox ("Les fichiers pdf sont créés dans le répertoire : " & CheminRep)
 
 
 
Application.ScreenUpdating = False
 
End Sub

Bonjour,

Un exemple avec votre code sans utiliser Select. Le temps de traitement est-il plus rapide ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Option Explicit
 
Sub MEF_et_génération_PDF_pour_reporting_DA()
 
Dim CheminRep As String
Dim MoisAnnee As String
 
Dim AireDesOnglets As Range
Dim Cell As Range
 
Dim ShEnCours As Worksheet
 
        Application.ScreenUpdating = False
 
        With Sheets("INDEX")
             CheminRep = .Range("G2").Value
             MoisAnnee = .Range("G3").Value
             Set AireDesOnglets = .Range("G8:G22") 'plage de données des CC
          '  Set AireDesOnglets = .Range("G8:G10") ' Essai sur 3 onglets
        End With
 
        For Each Cell In AireDesOnglets
 
            Set ShEnCours = Sheets(Cell.Value)
 
            With ShEnCours
                 .Outline.ShowLevels RowLevels:=0, ColumnLevels:=2 'ouvre les regroupements de colonnes
                 .Columns("Y:AA").EntireColumn.Hidden = True
                 .Outline.ShowLevels RowLevels:=0, ColumnLevels:=1 'ferme les regroupements de colonnes
                 .Columns("Y:AA").EntireColumn.Hidden = False
                 .Outline.ShowLevels RowLevels:=2 'ouvre les regroupements de lignes
                 .Rows("77:80").EntireRow.Hidden = True
                 .Outline.ShowLevels RowLevels:=1 'ferme les regroupements de lignes
                 .Rows("77:80").EntireRow.Hidden = False
                 .Columns("Z:Z").EntireColumn.AutoFit
                 .Rows("81:81").EntireRow.AutoFit
                 .ExportAsFixedFormat Type:=xlTypePDF, Filename:=CheminRep & "\" & Cell & "_" & MoisAnnee & "_Suivi Frais" & ".pdf"
                 .Outline.ShowLevels RowLevels:=2 'ré-ouvre les regroupements de lignes
           End With
 
           Set ShEnCours = Nothing
 
        Next
 
        Set AireDesOnglets = Nothing
 
        Application.ScreenUpdating = False
 
        MsgBox "Les fichiers pdf sont créés dans le répertoire : " & Chr(10) & Chr(10) & CheminRep, vbInformation
 
End Sub

Nb : Pour plus de lisibilité, utilisez les balises de code (# dans le menu) pour encadrer votre code.

Cordialement.

20/04/2015, 09h19
valérieF

Merci Eric, désolé pour les # je ne savais pas..

J'ai testé ce matin et ca bug à :

Code:

Set ShEnCours = Sheets(Cell.Value)

merci pour ton aide

a+
20/04/2015, 09h40
Invité

Bonjour,

Quel message as-tu ?
As tu bien respecté la syntaxe ?
Les noms dans G8:G22 correspondent-ils tous à des onglets ?

Sinon, mets ta procédure complète en ligne.

Cordialement.

Le message est le suivant :
Erreur d'execution 9
L'indice n'appartient pas à la sélection ....

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Sub MEF_et_génération_PDF_pour_reporting_DA_option_explicit()
 
Dim CheminRep As String
Dim MoisAnnee As String
 
Dim AireDesOnglets As Range
Dim Cell As Range
 
Dim ShEnCours As Worksheet
 
        Application.ScreenUpdating = False
 
        With Sheets("INDEX")
             CheminRep = .Range("G2").Value
             MoisAnnee = .Range("G3").Value
             Set AireDesOnglets = .Range("G8:G22") 'plage de données des CC
          '  Set AireDesOnglets = .Range("G8:G10") ' Essai sur 3 onglets
        End With
 
        For Each Cell In AireDesOnglets
 
            Set ShEnCours = Sheets(Cell.Value)
 
            With ShEnCours
                 .Outline.ShowLevels RowLevels:=0, ColumnLevels:=2 'ouvre les regroupements de colonnes
                 .Columns("Y:AA").EntireColumn.Hidden = True
                 .Outline.ShowLevels RowLevels:=0, ColumnLevels:=1 'ferme les regroupements de colonnes
                 .Columns("Y:AA").EntireColumn.Hidden = False
                 .Outline.ShowLevels RowLevels:=2 'ouvre les regroupements de lignes
                 .Rows("77:80").EntireRow.Hidden = True
                 .Outline.ShowLevels RowLevels:=1 'ferme les regroupements de lignes
                 .Rows("77:80").EntireRow.Hidden = False
                 .Columns("Z:Z").EntireColumn.AutoFit
                 .Rows("81:81").EntireRow.AutoFit
                 .ExportAsFixedFormat Type:=xlTypePDF, Filename:=CheminRep & "\" & Cell & "_" & MoisAnnee & "_Suivi Frais" & ".pdf"
                 .Outline.ShowLevels RowLevels:=2 'ré-ouvre les regroupements de lignes
           End With
 
           Set ShEnCours = Nothing
 
        Next
 
        Set AireDesOnglets = Nothing
 
        Application.ScreenUpdating = False
 
        MsgBox "Les fichiers pdf sont créés dans le répertoire : " & Chr(10) & Chr(10) & CheminRep, vbInformation
 
End Sub

20/04/2015, 11h06
SfJ5Rpw8

Bonjour,

combien as tu de classeur excel ouvert ?

avec ton code :

Code:

Sheets(...

tu oublie de préciser le classeur concerné si ta feuille est dans le classeur contenant ta macro utilise ThisWorkBook ...
20/04/2015, 11h12
Invité

Citation:

Envoyé par valérieF

Le message est le suivant :
Erreur d'execution 9
L'indice n'appartient pas à la sélection ....

Remplace

Code:

Set AireDesOnglets = .Range("G8:G22") 'plage de données des CC

par

Code:

Set AireDesOnglets = Sheets("INDEX").Range("G8:G22") 'plage de données des CC

Cordialement.
20/04/2015, 13h54
valérieF

Non ca ne fonctionne toujours pas...Ca bug toujours au même endroit
Cell prend bien la valeur 1421 mais ne rentre pas dans ShEnCours = Sheets(Cell.Value)

Estce que cela n'aurait pas à voir avec le pb que j'avais initialement dans mon code (moins optimisé) où j'ai dû définir NumCC comme String pour que cela fonctionne. Or dans ce nouveau code Cell est défini en Range....

Je joins un fichier basic avec qqles onglets pour tester si besoin.

a+
20/04/2015, 13h59
SfJ5Rpw8

c'est quoi 1421 ? tu as une feuille nommée 1421 ?
20/04/2015, 14h00
valérieF

désolé je n'arrive pas à joindre mon fichier.... j'ai peut être un pb sur mon poste
20/04/2015, 14h01
SfJ5Rpw8

Citation:

Envoyé par valérieF

désolé je n'arrive pas à joindre mon fichier.... j'ai peut être un pb sur mon poste

pas besoin de fichier réponds plutôt aux questions ;)
20/04/2015, 15h00
Invité

Citation:

Envoyé par valérieF

désolé je n'arrive pas à joindre mon fichier.... j'ai peut être un pb sur mon poste

Non.

1421 n'est pas pris comme une valeur alpha :

Essaye :

Code:

Set ShEnCours = Sheets(Cstr(Cell.Value))

Au cas où cela ne marcherait toujours pas et si les noms d'onglets sont des nombres, mets un ' devant chaque nombre pour les transformer en alpha.

Cordialement
20/04/2015, 22h35
valérieF

bbil, oui 1421 est un nom d'onglet, je ne t'ai pas répondu car je n'avais pas vu ta question :-)

Eric, oui!!! super ca ne bug plus. Par contre je testerai la macro entière au bureau demain car je n'ai pas mon pc de boulot avec moi ce soir... Pour plusieurs raisons je ne souhaite pas modifier les noms d'onglets mais un truc m'intrigue : t'es sur qu'il est possible de mettre un ' en début de nom sur un onglet? Je n'y arrive pas...
Je te donnerai des news demain et si tout fonctionnne je te dirais si le traitement de la macro optimisé est plus rapide que ma macro de novice :-) mais le code Set ... nothing je ne comprends pas bien... faut que je cherche un peu de doc.

a+
21/04/2015, 04h40
kiki29

Salut, également qqch qui fait partie des bases : le CodeName ou là
Cela permet de déplacer les feuilles, de renommer les feuilles sans avoir à retoucher au code VBA ( si ce dernier prend en compte le CodeName )
21/04/2015, 04h41
Invité

Citation:

Envoyé par valérieF

mais un truc m'intrigue : t'es sur qu'il est possible de mettre un ' en début de nom sur un onglet? Je n'y arrive pas...

Voui. Il faut simplement taper l'apostrophe ' (correspondant au chiffre 4 sur la deuxième ligne du clavier) au tout début et taper les chiffres, ou insérer l'apostrophe avant le premier chiffre si ton nombre est déjà écrit.

Citation:

Je te donnerai des news demain et si tout fonctionnne je te dirais si le traitement de la macro optimisé est plus rapide que ma macro de novice :-) mais le code Set ... nothing je ne comprends pas bien... faut que je cherche un peu de doc.

En t'envoyant cette macro, je voulais seulement te montrer que tu pouvais te passer des Select.

Cordialement.
21/04/2015, 22h13
valérieF

La macro fonctionne Eric. Par contre ce n'est pas plus rapide. Je pensais que le temps de traitement serait meilleur.
Et je t'assure que j'ai beau essayer de mettre un ' au début du nom d'un onglet et je n'y arrive pas !!!!!
Merci en tout cas, je vais essayer de faire ma prochaine macro, qui est un peu plus compliquée avec mes déclarations de variable et utilisation des objets.

a+