Saisies Userform

Version imprimable

26/03/2015, 08h44
pidres

1 pièce(s) jointe(s)

Saisies Userform

Bonjour,

Questions qui me bloquent : si j'ajoute une colonne avant la 1er(A)et si j'ajoute des colonnes en plus (jaune), les critères demandés de mon userform ne fonctionnent plus !
Comment modifier la plage et modifier la sélection des cellules ?

Merci pour votre aide.
26/03/2015, 09h17
Philippe Tulliez

Bonjour,
Difficile de t'aider si tu n'affiches pas le code que tu utilises pour définir la plage de données à l'ouverture du formulaire.
26/03/2015, 09h39
pidres

Bonjour Philippe,

Je ne peux pas vous répondre, je débute sur vba; en lisant des tutoriels, des réponses à des questions sur des forums,
j'essai d'adapter les formules à ma problématique.
Je bloque moi aussi pour comprendre comment augmenter la plage ?

Merci pour votre aide.

Bonjour,

Une solution possible dans le fichier joint.

J'ai mis un titre à la colonne des dates et j'ai modifié le CommandButton1 de la façon suivante (et accessoirement j'ai déplacé votre texte qui était sous la colonne des dates) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Private Sub CommandButton1_Click()
 
Dim Plage As Range
Dim Cel As Range
 
Dim PlageTitre As Range
Dim CelluleTitre As Range
 
Dim DerniereColonne As Long
Dim ColDate As Long
Dim ColAgent As Long
 
 
    With Worksheets("Feuil1")
         DerniereColonne = .Cells(1, .Columns.Count).End(xlToLeft).Column
         Set PlageTitre = .Range(.Cells(1, 1), .Cells(1, DerniereColonne))
 
 
        ' Recherche des colonnes
        '-----------------------
        ColDate = 0
        ColAgent = 0
        For Each CelluleTitre In PlageTitre
            If CelluleTitre = "Dates" Then ColDate = CelluleTitre.Column
            If ComboBox2.Text = CelluleTitre Then ColAgent = CelluleTitre.Column
        Next CelluleTitre
 
 
        ' Mise à jour du tableau
        '-----------------------
        If ColDate > 0 And ColAgent > 0 Then
           Set Plage = .Range(.Cells(3, ColDate), .Cells(.Rows.Count, ColDate).End(xlUp))
           For Each Cel In Plage
                If CDate(Cel.Value) = CDate(ComboBox3.Text) Then
                    Cel.Offset(0, ColAgent - ColDate) = ComboBox1.Text
                    Cel.Offset(0, ColAgent - ColDate + 1) = TextBox1.Text
                    Exit For
                End If
            Next Cel
           Set Plage = Nothing
        End If
        Set PlageTitre = Nothing
 
    End With
 
 
End Sub

Cordialement.

26/03/2015, 10h31
pidres

Bonjour Eric,

Ta solution est parfaite.
Il me reste à essayer de bien comprendre ta procédure.

Merci pour ton aide.
26/03/2015, 10h49
Invité

Citation:

Envoyé par pidres

Il me reste à essayer de bien comprendre ta procédure.

Attention aux homonymies dans les titres.

Voir également ma contribution : Repérer des colonnes dans un onglet.

Cordialement.