Remplacer espaces par underscores dans noms de fichiers

Version imprimable

19/03/2015, 11h29
Ysae68

Remplacer espaces par underscores dans noms de fichiers

Bonjour à tous,

J'ai environ 500 documents PDF avec des noms à rallonge pour lesquels il faut que je remplace tous les espaces par des underscores. Comme je n'ai aucune envie de faire ça manuellement, j'ai cherché une solution pour pouvoir m'épargner cette tâche, et ai trouvé ceci.

Le problème, c'est que ça ne marche pas, et comme je ne connais malheureusement rien à ces scripts, je ne vois pas ce qui bloque :oops: Pour info, j'ai essayé en testant sur d'autres fichiers (histoire de pas faire de bêtise sur les importants). J'ai créé un dossier test, avec dedans deux fichiers PDF "Test 1" et "Test 2", j'y ai placé le fichier batch nommé "Batch test", et tout ce qui se passe lorsque je l'exécute, c'est que le fichier batch passe de "Batch test" à "Batchtest".

J'ai donc grand besoin d'aide, parce que le renommage de docs manuellement un par un... enfin vous voyez quoi :roll:

Merci beaucoup d'avance :D

Bonjour,

essaye ça en remplaçant "<chemin_d'accès>" par le chemin d'accès du répertoire a traiter.
Code:

1 2 3 4 5 6 7 8 9 10 @echo off setlocal enabledelayedexpansion for /r "<chemin_d'accès>" %%a in (*.pdf) do ( set "path=%%~a" set "path=!path: =_!" copy /v "%%~a" "!path!" del /q "%%~a" ) pause

Désolée, ça ne marche pas non plus :oops: Ca me retourne une erreur "Le chemin d'accès spécifié est introuvable. 0 fichier(s) copié(s)", écrite deux fois vu qu'il y a deux fichiers PDF dans le dossier de test (j'ai testé, avec quatre fichier l'erreur est retournée quatre fois).

Est ce que je me trompe dans la syntaxe pour écrire le chemin d'accès ?
Code:

1 2 3 4 5 6 7 8 9 10 @echo off setlocal enabledelayedexpansion for /r "C:\Users\Moi\Documents\Dossier test" %%a in (*.pdf) do ( set "path=%%~a" set "path=!path: =_!" copy /v "%%~a" "!path!" del /q "%%~a" ) pause
EDIT : j'ai oublié de préciser qu'avec le lancement du batch, les deux fichiers PDF disparaissent du dossier ! Heureusement que c'était du test :mouarf:

:salut:
Une autre solution en Vbscript mais pas encore complète, juste affichage du résultat avec msgbox donc à essayer avec un dossier test :mouarf:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
Dim fso,MonDossier,File,MyNewFile
Set fso = CreateObject("Scripting.FileSystemObject")
MonDossier = Parcourir_Dossier()
Set MonDossier = fso.GetFolder(MonDossier)
For each File in MonDossier.Files
    Msgbox File
    MyNewFile = Replace(File," ","_")
    Msgbox MyNewFile
Next
'*********************************************************************************************
Function Parcourir_Dossier()
    Dim objShell,objFolder,Message
    Message = "Veuillez sélectionner un dossier pour renommer ses fichiers avec underscrore"
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0,Message,1,"c:\Programs")
    If objFolder Is Nothing Then
        Wscript.Quit
    End If
    Parcourir_Dossier = objFolder.self.path
end Function
'*********************************************************************************************

:salut:
Voici la solution complète en Vbscript :king: :plusser:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
Dim fso,ws,MonDossier,File,MyNewFile
set ws = CreateObject("wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
MonDossier = Parcourir_Dossier()
Set MonDossier = fso.GetFolder(MonDossier)
For each File in MonDossier.Files
    MyNewFile = Replace(File," ","_")
    MyNewFile = GetNameFile(MyNewFile)
    Call RenameMyFile(File,MyNewFile)
Next
MsgBox "L'oprération est finie !",VbInformation,"L'oprération est finie !"
ws.run "explorer.exe "& DblQuote(MonDossier)
'*********************************************************************************************
Function Parcourir_Dossier()
    Dim objShell,objFolder,Message
    Message = "Veuillez sélectionner un dossier pour renommer ses fichiers avec underscrore"
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0,Message,1,"c:\Programs")
    If objFolder Is Nothing Then
        Wscript.Quit
    End If
    Parcourir_Dossier = objFolder.self.path
end Function
'*********************************************************************************************
Function GetNameFile(sFile)
    Dim  Tab
    Tab = Split(sFile,"\")
    GetNameFile = Tab(UBound(Tab))
End Function
'*********************************************************************************************
Sub RenameMyFile(File1,File2)
    Dim Ws,Command,Execution
    Set Ws = CreateObject("WScript.Shell")
    Command = "Cmd /c Rename "& DblQuote(File1) &" "& DblQuote(File2) &""
    Execution = Ws.Run(Command,0,False)
End Sub
'*********************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'*********************************************************************************************

Non tu ne t'es pas trompé dans le chemin d'accès, j'avais pas pris en compte le faite qu'il pouvait y avoir des espaces dans ton chemin d'accès. Tu doit avoir un dossier "C:\Users\Moi\Documents\Dossier_test" qui a dût être créé, pense à le supprimer.
Code:

1 2 3 4 5 6 7 8 9 10 @echo off setlocal enabledelayedexpansion for /r "C:\Users\Moi\Documents\Dossier test" %%a in (*.pdf) do ( set "path=%%~nxa" set "path=!path: =_!" copy /v "%%~a" "%%~dpa!path!" del /q "%%~a" ) pause
@hackoofr: petit gourmand :mouarf:

19/03/2015, 14h16
Ysae68

Merci beaucoup à tous les deux pour votre aide... mais ça ne va toujours pas :? Désolée en plus je ne fais pas avancer les choses, c'est quasiment la première fois que j'utilise des batch et vbscript :oops: On peut dire que je découvre leur existence justement parce que je cherchais à éviter un travail long et répétitif.

Pour la solution de hackoofr : j'ai bien une fenêtre qui s'ouvre et me demande de sélectionner un dossier. Je prends le dossier de test, mais alors j'ai juste une autre fenêtre qui s'ouvre avec le chemin d'accès du premier document affiché et un bouton "OK". Je clique, re-fenêtre avec le chemin d'accès, je re-clique, fenêtre avec le chemin d'accès du deuxième doc... :roll:

Pour la solution de InitSreen : le PDF "Test 1" a disparu du dossier de test, mais "Test 2" s'est bien transformé en "Test_2".

En espérant que vous aurez encore la patience de vous pencher sur mon problème... :D

Essaye comme ça, peut être ...
Code:

1 2 3 4 5 6 7 8 9 @echo off setlocal enabledelayedexpansion for /r "C:\Users\Moi\Documents\Dossier test" %%a in (*.pdf) do ( set "path=%%~nxa" set "path=!path: =_!" move /y "%%~a" "%%~dpa!path!" ) pause
ça devrait marcher, problème d'écriture décalé avec la commande copy

19/03/2015, 14h33
Ysae68

Ca marche !!! Un grand merci soulagé, j'avais vraiment pas envie de faire ça document par document :D

Merci à tous les deux d'avoir pris le temps de chercher la solution :)
19/03/2015, 14h35
InitSreen

Met le post en résolut alors. Et de rien c'est un plaisir de faire du script ...
19/03/2015, 14h38
Ysae68

C'est fait :ccool:

Citation:

Envoyé par Ysae68

Pour la solution de hackoofr : j'ai bien une fenêtre qui s'ouvre et me demande de sélectionner un dossier. Je prends le dossier de test, mais alors j'ai juste une autre fenêtre qui s'ouvre avec le chemin d'accès du premier document affiché et un bouton "OK". Je clique, re-fenêtre avec le chemin d'accès, je re-clique, fenêtre avec le chemin d'accès du deuxième doc... :roll:

Parce que tu as cliqué plusieurs fois sur le script, voici une petite mise à jour, pour lancer une seule instance du script, en attendant d'ajouter une barre d'attente :king:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Option Explicit
If AppPrevInstance() Then 
    MsgBox "Attention ! Il ya déjà une instance lancé !" & VbCrLF &_
    CommandLineLike(WScript.ScriptName),VbExclamation,"Attention ! Il ya déjà une instance lancé !"    
    WScript.Quit   
Else 
Dim fso,ws,MonDossier,File,MyNewFile
set ws = CreateObject("wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
MonDossier = Parcourir_Dossier()
Set MonDossier = fso.GetFolder(MonDossier)
For each File in MonDossier.Files
    MyNewFile = Replace(File," ","_")
    MyNewFile = GetNameFile(MyNewFile)
    Call RenameMyFile(File,MyNewFile)
Next
MsgBox "L'oprération est finie !",VbInformation,"L'oprération est finie !"
ws.run "explorer.exe "& DblQuote(MonDossier)
End If
'*********************************************************************************************
Function Parcourir_Dossier()
    Dim objShell,objFolder,Message
    Message = "Veuillez sélectionner un dossier pour renommer ses fichiers avec underscrore"
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0,Message,1,"c:\Programs")
    If objFolder Is Nothing Then
        Wscript.Quit
    End If
    Parcourir_Dossier = objFolder.self.path
end Function
'*********************************************************************************************
Function GetNameFile(sFile)
    Dim  Tab
    Tab = Split(sFile,"\")
    GetNameFile = Tab(UBound(Tab))
End Function
'*********************************************************************************************
Sub RenameMyFile(File1,File2)
    Dim Ws,Command,Execution
    Set Ws = CreateObject("WScript.Shell")
    Command = "Cmd /c Rename "& DblQuote(File1) &" "& DblQuote(File2) &""
    Execution = Ws.Run(Command,0,False)
End Sub
'*********************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'*********************************************************************************************
Function AppPrevInstance()   
    With GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")   
        With .ExecQuery("SELECT * FROM Win32_Process WHERE CommandLine LIKE " & CommandLineLike(WScript.ScriptFullName) & _
            " AND CommandLine LIKE '%WScript%' OR CommandLine LIKE '%cscript%'")   
            AppPrevInstance = (.Count > 1)   
        End With   
    End With   
End Function    
'*********************************************************************************************
Function CommandLineLike(ProcessPath)   
    ProcessPath = Replace(ProcessPath, "\", "\\")   
    CommandLineLike = "'%" & ProcessPath & "%'"   
End Function
'*********************************************************************************************

19/03/2015, 14h54
Ysae68

Ah non, négatif : j'ai fait un clic droit dessus, puis "Ouvrir", donc je n'ai pas pu lancer le script plusieurs fois. Mais peu importe, j'ai également essayé avec ta dernière mise à jour, et ça marche impec', merci ! :D
28/08/2017, 16h56
PaulPlatt

BatchRenameFiles.org

essayer l'outil BatchRenameFiles