Changer les valeurs de textbox à chaque incrément d'une boucle while

Version imprimable

Voir 40 message(s) de cette discussion en une page

1 pièce(s) jointe(s)

Changer les valeurs de textbox à chaque incrément d'une boucle while

Bonjour à tous,
j'ai débuté il y a peu la programmation sur VBA pour excel.
J'ai développé un petit programme, mais pas très intuitif pour des utilisateurs lambda...
Je voudrais donc habiller ce programme avec des userforms contenant des Textbox, labels...

Pour le moment je souhaite créer une macro où l'on rentre des valeurs dans des textbox et ces valeurs seraient reportées dans les cellules d'une ligne i
Les valeurs de ces textbox sont amenées à changer à chaque ligne et le principe est de créer une boucle (ici While) pour saisir les valeurs des textbox de chaque ligne.

Pour faire simple dans ma macro, pour une ligne i : la textbox 3 dois enregistrer la valeur la cellule (i,B) et la textbox 4 celle de la cellule (i,C)Pièce jointe 171843
Et je voudrais pouvoir saisir pour chaque ligne de nouvelles valeurs à enregistrer dans ma feuille excel.

Voici mon script actuel (ci-dessous), mais le problème est que je ne peux pas saisir à chaque étape les valeurs des textbox 3 et 4. (J'ai aussi essayer avec des Me.controls... mais je n'arrive pas à le faire fonctionner...)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Private Sub valider_Click() Dim i As Long i = 2 While ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value <> "" TextBox3.Text = "" TextBox4.Text = "" If ThisWorkbook.Sheets("Geniteurs").Range("E" & i).Value > 0 Then TextBox1.Text = ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value TextBox2.Text = ThisWorkbook.Sheets("Geniteurs").Range("D" & i).Value Label5.Caption = ThisWorkbook.Sheets("Geniteurs").Range("E" & i).Value ThisWorkbook.Sheets("Geniteurs").Range("B" & i).Value = TextBox3.Text (je n'arrive pas à prendre le contrôle à ces deux étapes) ThisWorkbook.Sheets("Geniteurs").Range("C" & i).Value = TextBox4.Text End If i = i + 1 Wend End Sub
Je vous remercie infiniment pour votre aide en espérant que cela est possible

Bonjour,
si tu veux ajouter plusieurs chose dans ta textbox avec une boucle, il faut faire comme ceci
Code:

1 2 TextBox1.Text = TextBox1.Text & ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value TextBox2.Text = TextBox2.Text & ThisWorkbook.Sheets("Geniteurs").Range("D" & i).Value

17/03/2015, 10h11
cclleemmeenntt

Bonjour Gnaim,

Merci beaucoup pour ton aide. J'ai essayé ces codes mais ça ne marche pas. Je me suis sûrement mal exprimé pour décrire ce que je voulais.
A chaque valeur de i dans ma boucle, je souhaite pouvoir entrer de nouvelles valeurs dans les textbox 3 et 4, pour que ces valeurs soient enregistrées dans les cases correspondantes (i, B) et (i,C) de ma feuille excel.
Je pense que le problème principal est que je n'arrive pas à reprendre le contrôle à chaque étape de ma boucle pour rentrer les nouvelles valeurs des textbox. Si j'applique ma formule, je ne peut rentrer qu'une valeur pour chacune des textbox 3 et 4 (en fin de boucle), et ces valeurs seront appliquées à toutes les lignes précédentes.

je ne sais pas si cela est faisable, mais j'espère que toi ou quelqu'un d'autre pourra m'aider. En tout cas merci encore ;);)
17/03/2015, 11h00
Nico Chg

Bonjour,

C'est le principe même de la boucle !

En gros, tu veux pouvoir changer les valeurs de tes textbox, et les enregistrer dynamiquement à chaque changement ?

Penche toi sur les événements, et plus particulièrement sur valider_change().
17/03/2015, 11h12
cclleemmeenntt

Bonjour Nico Chg,

Oui c'est exactement ça!!:D:D
J'ai essayé dans cette boucle en remplaçant les textbox par des inputbox pour tester et ça fonctionnait comme je le voulais. Le problème est que je veux utiliser un userform pour rendre l'interface accueillante et sympa et les inputbox rendent ça très moche...

Sinon concernant ta réponse je trouve tt un tas d'évènements (Click, Enter, Exit...) mais pas Change....

Dsl je suis un peu nul en VBA ;) Mais merci beaucoup pour ta réponse
17/03/2015, 11h20
Nico Chg

1 pièce(s) jointe(s)

On est d'accord, tu boss sur un Userform, contenant au moins une textbox ? (nommée à tout hasard TextBox1)

Et bien, cette TextBox possède un événement "Change" : Pièce jointe 171936

Il faudra mettre ton code dans cet événement, et il va s’exécuter à chaque changement de valeur de la textbox.

Désolé je bloque encore...

Grâce à ton aide je pense qu'on y est presque:):), tu pourrais juste me donner un coup de main pour que ça marche? Voilà mon script ci-dessous
En tout cas merci énormément :
Script 1 : (j'ai mis en public sub pour que la valeur de i soit transmise aux autres sub)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Public Sub valider_Click()
Dim i As Long
i = 2
While ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value <> ""
    TextBox3.Text = ""
    TextBox4.Text = ""
    If ThisWorkbook.Sheets("Geniteurs").Range("E" & i).Value > 0 Then
    TextBox1.Text = ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value
    TextBox2.Text = ThisWorkbook.Sheets("Geniteurs").Range("D" & i).Value
    Label5.Caption = ThisWorkbook.Sheets("Geniteurs").Range("E" & i).Value
    TextBox3_Change
    TextBox4_Change
    End If
i = i + 1
Wend
End Sub
 
Script 2 : (ça bloque ici)
Private Sub TextBox3_Change()
ThisWorkbook.Sheets("Geniteurs").Range("B" & i).Value = TextBox3.Text
End Sub
 
Script 3 : (je pense qu'on aura le même problème qu'avec le script 2)
Private Sub TextBox4_Change()
ThisWorkbook.Sheets("Geniteurs").Range("C" & i).Value = TextBox4.Text
End Sub

Merci encore!!!:D:D:D

A mettre dans le module de ton userform

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Explicit
 
Dim i As Long
 
Private Sub UserForm_Initialize()
 
TROUVE i
End Sub
 
Private Sub valider_Click()
 
With ThisWorkbook.Sheets("Geniteurs")
    .Range("B" & i).Value = TextBox3.Text
    .Range("C" & i).Value = TextBox4.Text
End With
TROUVE i
End Sub
 
Private Sub TROUVE(ByRef i As Long)
 
If i = 0 Then i = 1
With ThisWorkbook.Sheets("Geniteurs")
    Do While .Range("A" & i).Value <> ""
        i = i + 1
        If .Range("E" & i).Value > 0 Then
            TextBox1.Text = .Range("A" & i).Value
            TextBox2.Text = .Range("D" & i).Value
            Label5.Caption = .Range("E" & i).Value
            TextBox3.Text = .Range("B" & i).Value
            TextBox4.Text = .Range("C" & i).Value
            Exit Do
        End If
    Loop
    If .Range("A" & i).Value = "" Then Unload Me
End With
End Sub

Citation:

Envoyé par cclleemmeenntt

(j'ai mis en public sub pour que la valeur de i soit transmise aux autres sub)

Ce n'est que partiellement juste (enfait, c'est faux). Si tu passe une procédure en "public", il n'y a que la procédure qui est visible depuis les autres modules. Les variables restent liée à la procédure, tu n'y a pas accès ailleurs. Avec ce genre de procédé, tu peux simplement appeler ta procédure depuis un autre projet, puisqu'elle est Public. C'est a priori pour ça que ton code bloque, la variable "i" n'est pas définis.

Pour le vérifier, il suffit simplement de lire le message d'erreur. i n'étant pas définis, il va prendre la valeur 0, ou null ou Empty, ou ce que tu veux quand tu vas l'utiliser, et dans ton cas, tu va te retrouver à écrire dans la range ("B0"), et je te laisse trouver cette cellule dans Excel ...
Citation:
Envoyé par cclleemmeenntt
'Script 1 : (j'ai mis en public sub pour que la valeur de i soit transmise aux autres sub)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 Public Sub valider_Click() Dim i As Long i = 2 While ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value <> "" TextBox3.Text = "" TextBox4.Text = "" If ThisWorkbook.Sheets("Geniteurs").Range("E" & i).Value > 0 Then TextBox1.Text = ThisWorkbook.Sheets("Geniteurs").Range("A" & i).Value TextBox2.Text = ThisWorkbook.Sheets("Geniteurs").Range("D" & i).Value Label5.Caption = ThisWorkbook.Sheets("Geniteurs").Range("E" & i).Value TextBox3_Change TextBox4_Change End If i = i + 1 Wend End Sub 'Script 2 : (ça bloque ici) Private Sub TextBox3_Change() ThisWorkbook.Sheets("Geniteurs").Range("B" & i).Value = TextBox3.Text End Sub 'Script 3 : (je pense qu'on aura le même problème qu'avec le script 2) Private Sub TextBox4_Change() ThisWorkbook.Sheets("Geniteurs").Range("C" & i).Value = TextBox4.Text End Sub
Merci encore!!!:D:D:D
Ensuite, Pourquoi faire une boucle While ? Les événements vont exécuter les macro à chaque fois que la valeur de ta Textbox change, ta boucle While ne sert plus à grand chose, non ?

Ce que tu veux, c'est à chaque valeur dans ta Textbox, tu veux aller écrire la valeur dans une cellule, une ligne en dessous, si possible ? Pas besoin de boucle While, juste de connaître la dernière cellule remplie pour pouvoir écrire en dessous ?

Un peu d'aide :
Code:

1 2 Dim lastLine as single lastLine = Worksheets("MaFeuille").Columns(2).Find("*", , , , xlByColumns, xlPrevious).Row
Avec ce code, tu peux récupérer la ligne de la dernière cellule remplie de la colonne 2 (B) de la feuille "MaFeuille".

EDIT : à 2-3min près de mercatog, effectivement, c'est plus malin comme ça, je voyais poindre le problème avec l'event change de la tbx ...

17/03/2015, 14h08
cclleemmeenntt

Merci Mercatog ça marche super!!!!! C'est exactement ce que je voulais comme genre de userForm!!!!:):D :) :D :) :D
En tout cas quand je vois ce que tu as fait je me dis que j'ai vraiment un petit niveau et encore beaucoup à apprendre!!! Mais en tout cas merci c'est vraiment génial!!!! je vais me pencher sur ce script pour mieux comprendre:D

Pour répondre à Nico, en fait j'étais parti sur une boucle while car même si je ne l'ai pas expliqué je voulais balayé l'ensemble des lignes tout en évitant certaine que je ne voulais pas remplir... Je pense que ce n'était peut être pas la meilleure des solutions, mais étant donné mon peu d'expérience en VBA je pensais vraiment que ça pouvait marcher. 8O
En tout cas vraiment un grand merci à tous les deux pour le temps que vous m'avez consacré!!!

(J'aimerais bien vous rendre la pareil mais vous êtes franchement plus balèzes que moi!! :D :D )
17/03/2015, 15h16
cclleemmeenntt
Je ne voudrais pas abuser mais j'ai juste une autre petite question concernant ce programme pour Mercatog?

Je voudrais ajouter un autre command button "précédent", dans le cas d'une erreur de manipulation.
J'aimerais que ce bouton renvoie au dernier élément afficher. Voici mon ébauche de script (qui ne marche pas bien sûr...)
Code:

1 2 3 4 5 6 7 8 9 Private Sub precedent_click() i = i - 1 With ThisWorkbook.Sheets("Geniteurs") While Range("E" & i).Value > 0 i = i - 1 Wend End With TROUVE i End Sub
Merci encore énormément pour votre aide

Edit

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
 
Dim i As Long
 
Private Sub UserForm_Initialize()
 
i = 1
TROUVE i
End Sub
 
Private Sub valider_Click()
 
With ThisWorkbook.Sheets("Geniteurs")
    .Range("B" & i).Value = TextBox3.Text
    .Range("C" & i).Value = TextBox4.Text
End With
TROUVE i
End Sub
 
Private Sub Precedent_Click()
 
TROUVE i, True
End Sub
 
Private Sub TROUVE(ByRef Deb As Long, Optional Prced As Boolean)
Dim Pas As Integer
Dim N As Long
 
With ThisWorkbook.Sheets("Geniteurs")
    N = .Cells(.Rows.Count, 1).End(xlUp).Row
    Pas = IIf(Prced, -1, 1)
    Do While i <= N And i >= 1
        i = i + Pas
        If .Range("E" & i).Value > 0 Then
            TextBox1.Text = .Range("A" & i).Value
            TextBox2.Text = .Range("D" & i).Value
            Label5.Caption = .Range("E" & i).Value
            TextBox3 = .Range("B" & i).Value
            TextBox4.Text = .Range("C" & i).Value
            Exit Do
        End If
    Loop
    If i > N Or i < 2 Then Unload Me
End With
End Sub

17/03/2015, 16h19
cclleemmeenntt

Trop bien!!!! :):):):)
Merci beaucoup Mercatog!!! ça marche super bien!!!

Tu es franchement trop fort!! :D:D
17/03/2015, 16h37
mercatog

Le code initial a été édité, je ne sais pas si tu en a tenu compte
17/03/2015, 16h46
cclleemmeenntt

Oui j'ai vu qu'il y avait un petit décalage mais j'ai modifié dans mon script et ça marche nickel!! :D (enfin si c'est ce que tu voulais me signaler)

Merci beaucoup pour ton aide (même si je ne comprend pas ton script entièrement), car je pense que j'aurais beaucoup galéré et sûrement pas réussi sinon ;)

A force de mijoter, on ne se rend plus compte des bêtises. le paramètre Deb de la sub TROUVE n'a plus aucun sens

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
 
Dim i As Long
 
Private Sub UserForm_Initialize()
 
i = 1
TROUVE
End Sub
 
Private Sub valider_Click()
 
With ThisWorkbook.Sheets("Geniteurs")
    .Range("B" & i).Value = TextBox3.Text
    .Range("C" & i).Value = TextBox4.Text
End With
TROUVE
End Sub
 
Private Sub Precedent_Click()
 
TROUVE True
End Sub
 
Private Sub TROUVE(Optional Prced As Boolean)
Dim Pas As Integer
Dim N As Long
 
With ThisWorkbook.Sheets("Geniteurs")
    N = .Cells(.Rows.Count, 1).End(xlUp).Row
    Pas = IIf(Prced, -1, 1)
    Do While i <= N And i >= 1
        i = i + Pas
        If .Range("E" & i).Value > 0 Then
            TextBox1.Text = .Range("A" & i).Value
            TextBox2.Text = .Range("D" & i).Value
            Label5.Caption = .Range("E" & i).Value
            TextBox3 = .Range("B" & i).Value
            TextBox4.Text = .Range("C" & i).Value
            Exit Do
        End If
    Loop
    If i > N Or i < 2 Then Unload Me
End With
End Sub

18/03/2015, 08h47
cclleemmeenntt

Merci Mercatog!!

Je modifie cela!! Mais ça marchait déjà très bien avant :lol:
J'ai juste une question sur le script : Prced dans la sub Trouve, réfère à la sub Precedent_Click? Car je ne comprend pas tout dans la macro Trouve...

En tout cas merci beaucoup pour ton aide et le temps que tu me conssacres, ça m'aide grandement :D
18/03/2015, 10h53
mercatog

La procédure TROUVE cherche la ligne où la cellule de la colonne E est >0

La procédure à un seul paramètre optionnel Prced qui est booléen (cf. dernier code)

Si cet argument est omis ou FALSE, la recherche se fait de haut en bas (Pas = 1)

Si cet argument est à TRUE, la recherche se fait de bas en haut (Pas =-1)

Bonjour Mercatog,

Je reviens vers toi car im reste une petite question concernant mes userform...
Dans un autre userform je cherche à afficher un tableau (colonne A à F, jusqu'à la dernière ligne non vide) dans un onglet dont j'ai sélectionné le nom via un combobox.

Quand j'exécute le code j'obtiens une erreur "d'exécution 9 : l'indice n'appartient pas à la sélection"... Je suis quasi certain qu'il s'agit d'une très grossière erreur mais je sèche un peu.

Voici mon code
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 Option Explicit Dim k As String Private Sub combobox1_click() Dim k As String k = ComboBox1.Value a = ThisWorkbook.Sheets("k").Range("a1", _ ActiveSheet.Range("a1").End(xlDown).End(xlToRight)).Select Me.ListBox1.Visible = True Me.ListBox1.List = a 'MsgBox (k) End Sub Private Sub ComboBox1_DropButtonClick() ComboBox1.Clear Dim i As Long For i = 4 To Sheets.Count ComboBox1.AddItem Sheets(i).Name Next i End Sub
Merci encore infiniment pour ton aide!!! Bonne journée

20/03/2015, 10h49
mercatog

si k est un string
sheets(k) et non sheets("k")

ps. je préfère

Code:

Thisworkbook.worksheets(k)

Malgré que toute worksheet est une sheet et non inversement

Voir 40 message(s) de cette discussion en une page