Déplacer des fichiers dans des sous dossier selon leur extension

Version imprimable

Bonjour;
je souhaite déplacer les fichiers de mon flash disque dans des sous dossiers appropriés selon leurs extensions, avec l'outil VBSEdit
Voilà donc ce que j'ai fais :

déclarer l'objet fso, et la collection
Créer un objet folder qui pointe vers la racine du disque amovible
créer les sous dossiers (images , textes, vidéos)
créer une collection files de la propriété de folder ( et col = files.folder)
En suite je dois parcourir la collection et pour chaque fichier le déplacer dans son sous dossier approprié :
Code:

1 2 3 4 5 6 7 8 For each file in files.folder If (fso.getextensionname (file.path)) = " txt" "docx" Then file.move ; [destination] End If If (fso.getextensionname (file.path)) = "jpg" "png" Then file.move ; [destination] End If Next
Est-ce le code cité est le bon code ? Je vous prie de me communiquer le bon code ! :oops:

Salut, bienvenue sur DVP

Pas loin, le code.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Dim DossierSource, QuelExtention, DestinationTxtDocs, DestinationJpgPng
Dim fso, Files, file
 
DossierSource = "C:\DossierSource"
DestinationTxtDocs = DossierSource & "\DossierPourTxtOuDocs\"
DestinationJpgPng = DossierSource & "\DossierPourJpgOuPng\"
 
Set fso = CreateObject("Scripting.FileSystemObject")
Set Files = fso.GetFolder("C:\DossierSource")
 
If Not fso.FolderExists(DestinationTxtDocs) Then
    fso.CreateFolder (DestinationTxtDocs)
End If
If Not fso.FolderExists(DestinationJpgPng) Then
    fso.CreateFolder (DestinationJpgPng)
End If
 
For Each file In Files.Files
    QuelExtention = LCase(fso.GetExtensionName(file.Path))
    Select Case QuelExtention
        Case "txt", "docx"
            file.Move DestinationTxtDocs & file.Name
        Case "jpg", "png"
            file.Move DestinationJpgPng & file.Name
    End Select
Next
Set fso = Nothing
Set Files = Nothing

ATTENTION de bien paramétrer les lignes 4, 5 et 6 avec tes propres paramètres.

voilà le bon code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
Set fso=createobject("Scripting.FileSystemObject")
 
x=inputbox("Veuillez entré le nom d'un lecteur : " )
 
fso.createfolder(x&":\VBS")
fso.createfolder(x&":\VBS\Musique")
fso.createfolder(x&":\VBS\Videos")
fso.createfolder(x&":\VBS\Script")
fso.createfolder(x&":\VBS\Images")
fso.createfolder(x&":\VBS\Documents")
fso.createfolder(x&":\VBS\Archives")
fso.createfolder(x&":\VBS\PDF")
fso.createfolder(x&":\VBS\Programmes")
fso.createfolder(x&":\VBS\Autres Fichiers")
 
Set lect=fso.GetFolder(x&":\")
 
Set col=lect.Files
 
for each F in col
 
Ext=fso.GetExtensionName(f.name)
 
if ext="vbs" then
F.Move (x&":\VBS\Script\")
else
 
     if ext="mp3" or ext="wma" or ext="dat" or ext="cda" then 
     F.Move (x&":\VBS\Musique\")
     else  
 
           if ext="exe" or ext="com" then 
           F.Move (x&":\VBS\Programmes\")
           else
 
                  if ext="jpg" or ext="jpeg" or ext="gif" or ext="bmp" then 
                  F.move (x&":\VBS\Images\")
                  else
 
                          if ext="avi" or ext="mpg" or ext="mpeg" or ext="mp4" or ext="flv" then
                          F.move (x&":\VBS\Videos\")
                          else
 
                                 if ext="txt" or ext="doc" or ext="docx" or ext="ps" or ext="xls" or ext="xlsx" or ext="ppt" or ext="pptx" then
                                 F.Move (x&":\VBS\Documents\")
                                 else
 
                                         if ext="rar" or ext="zip" then 
                                         F.Move (x&":\VBS\Archives\")
                                         else
 
                                                 if ext="pdf" then 
                                                 F.Move (x&":\VBS\PDF\")
                                                 else
 
 
 
 
                                               F.Move (x&":\VBS\Autres Fichiers\")
 
     end if
 
           end if
 
                  end if
 
                          end if
 
                                 end if
 
                                         end if
 
                                                    end if
 
                                                                end if

Il y a quelque chose que je n'ai pas saisi : Où devrait-on déplacer les fichiers ? Est-ce vers la même unité vers une autre ?

D'autre part, un code indenté permet de bien comprendre, or ici on voit un code indenté à l'envers avec un grand nombre de conditions imbriquées; chose qui rend ledit code très peu clair.

A mon humble avis, le choix de ProgElecT(SALUT) pour Select Case est bien judicieux dans ce cas de figure;

Voici une modification du même code avec recherche auto du lecteur USB :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Option Explicit
Dim fso, x, col, lect, F,  drv, Ext
 
Set fso=createobject("Scripting.FileSystemObject")
 
  For Each drv In fso.Drives
      If drv.DriveType = 1  Then 
           If drv.IsReady Then
                Set x = fso.GetDrive(drv)
                x = drv.DriveLetter
                Exit For
            Else 
                x=inputbox("Veuillez entrer la lettre d'un lecteur : " )
                If x = "" Or Len(x) > 1 Then
                 MsgBox "Veuillez réessayer en donnant une unité de lecteur valide"
                 WScript.Quit 
                End If
            End If
        End If
    Next
On Error Resume Next    ' Juste pour ne pas avoir l'erreur : le fichier(dossier) existe déjà
                        ' si on exécute le code une 2ème fois
fso.CreateFolder(x & ":\VBS")
fso.CreateFolder(x & ":\VBS\Musique")
fso.CreateFolder(x & ":\VBS\Videos")
fso.CreateFolder(x & ":\VBS\Script")
fso.CreateFolder(x & ":\VBS\Images")
fso.CreateFolder(x & ":\VBS\Documents")
fso.CreateFolder(x & ":\VBS\Archives")
fso.CreateFolder(x & ":\VBS\PDF")
fso.CreateFolder(x & ":\VBS\Programmes")
fso.CreateFolder(x & ":\VBS\Autres Fichiers")
 
Set lect=fso.GetFolder(x & ":\")
 
Set col=lect.Files
 
for each F in col
    Ext=fso.GetExtensionName(f.name)
     Select Case LCase(Ext)
         Case "vbs" : F.Move (x & ":\VBS\Script\")
         Case "mp3", "wma", "dat", "cda" :  F.Move (x & ":\VBS\Musique\")
         Case "exe", "com" : F.Move (x & ":\VBS\Programmes\")
         Case "jpg", "jpeg", "gif", "bmp" : F.move (x & ":\VBS\Images\")
         Case "avi", "mpg", "mpeg", "mp4", "flv" : F.move (x & ":\VBS\Videos\")
         Case "txt", "doc", "docx", "ps", "xls","xlsx", "ppt", "pptx" : F.Move (x & ":\VBS\Documents\")
         Case "rar", "zip" : F.Move (x & ":\VBS\Archives\")
         Case "pdf" : F.Move (x & ":\VBS\PDF\")
         Case Else : F.Move (x & ":\VBS\Autres Fichiers\")
     End Select
Next