VBA - Gestion des Sauts de Page

Version imprimable

11/02/2015, 11h40
BibiLellow

VBA - Gestion des Sauts de Page
Bonjour tout le monde,

Je développe en VBA sous Excel un bout de programme qui met un forme un fichier .XLS, pas besoin de rentrer dans les détails.

Une fois mis en forme, je dois le sauver en .PDF.

Pour que le fichier PDF soit "beau", je dois gérer les sauts de page, et pour cela je dois tester un a un tous les sauts de page automatique (pour voir si il ne se situe pas dans une cellule fusionnée mais ce n'est pas important).

Pour cela, je scrute tous les sauts de page de la manière suivante :
Code:

1 2 3 4 Dim HPB As HPageBreak For Each HPB In ActiveSheet.HPageBreaks 'Traitement Next HPB
Ce code marche très bien lorsque que j'ai qu'un seul saut de page à gérer, mais lorsque que j'en ai plusieurs, j'obtiens l'erreur "L'indice n'appartient pas à la sélection" à la ligne For Each HPB In ActiveSheet.HPageBreaks.

Quelqu'un a une idée de comment scruter tous les sauts de page ?

J'ai également essayer de les scruter manuellement, du genre :
Code:

1 2 Set HPB1 = ActiveSheet.HPageBreaks(1) Set HPB2 = ActiveSheet.HPageBreaks(2)
Mais encore une fois, le premier fonctionne très bien, mais le deuxième... même erreur.

Help :(
11/02/2015, 22h18
clementmarcotte

En tout cas, quand je regarde dans l'aide de VBA pour Excel 2010, je constate très rapidement que PageBreak est une propriété de l'objet Range et absolument pas une propriété de l'objet Worksheet. :aie:

En principe, cela devrait réveiller quelqu'un.

Et puis Excel 2010 peut enregistrer directement au format pdf.

Sinon, toujours dans l'aide VBA, c'est soit ExportAsFixedFormat, ou saveas. Cela devrait marcher avec un des deux.

P.S. Je ne me suis pas donné la peine de répondre sur les deux forums, et je ne le ferai pas non plus.

Bonjour BibiLellow

Déplacer les sauts de pages en fonction de cellules fusionnées.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Sub SautDePageCellulesFusionnees()
 'par Docmarti 2014/05/13
 
    Dim PremiereLigneDeLaPageSuivante As Object
 
    Dim f As Worksheet
 
    Dim ProchainNumeroPageBreak As Long
 
    Dim Ligne As Long
 
    Set f = ThisWorkbook.ActiveSheet
 
    ActiveWindow.View = xlPageBreakPreview
 
    f.ResetAllPageBreaks
 
    ProchainNumeroPageBreak = 1
 
    While ProchainNumeroPageBreak <= f.HPageBreaks.Count
 
        Set PremiereLigneDeLaPageSuivante = f.HPageBreaks(ProchainNumeroPageBreak).Location
 
        Ligne = PremiereLigneDeLaPageSuivante.Row
 
        If f.Cells(Ligne, 1).Value = "" And f.Cells(Ligne, 1).MergeCells = True Then
 
            While f.Cells(Ligne, 1).Value = ""
 
                Ligne = Ligne - 1
 
            Wend
 
            Set f.HPageBreaks(ProchainNumeroPageBreak).Location = f.Cells(Ligne, 1)
 
        End If
 
        ProchainNumeroPageBreak = ProchainNumeroPageBreak + 1
 
    Wend
 
End Sub

12/02/2015, 09h47
BibiLellow

PARFAIT ! J'ai eu besoin de juste faire une ou 2 petites modif pour adapter à mon code et c'est exactement ce dont j'avais besoin.

Tu me sauves la vie à 2 jours de la fin de mon stage ;)

Merci beaucoup,

Cordialement