Supprimer des lignes avec vba

Version imprimable

08/01/2015, 03h13
sigma17

Supprimer des lignes avec vba

bonsoir la communauté,bonne année 2015
je voudrais savoir comment je peux supprimer des lignes d'une feuille de calcul excel 2007 à partir du code vba.en effet j'ai un tableau de 5 colonnes et environ un millier de ligne.mon objectif est de supprimer les lignes n'ayant pas de données dans toutes les colonnes et cela à partir de vba:roll:
merci d'avance pour votre aide.
Cordialement.

Bonjour,

Une solution possible avec ce code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub SupprimerLesLignes()
 
Dim LigneDeTitre As Long
Dim DerniereLigne As Long
Dim I As Long
 
    With ActiveSheet
         LigneDeTitre = 1
         DerniereLigne = .UsedRange.Rows.Count ' S'il n'y a pas de lignes totalement vides
        ' DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row ' Sinon, si la première colonne est toujours remplie
         For I = DerniereLigne To LigneDeTitre + 1 Step -1
             If WorksheetFunction.CountA(Range(.Cells(I, 1), .Cells(I, 5))) < 5 Then .Cells(I, 1).EntireRow.Delete
         Next I
    End With
 
End Sub

Cordialement.

10/01/2015, 19h34
sigma17

salut,
merci bien :plusser:Eric KERGRESSE pour ton coup de main, le code marche à merveille juste qu'il manquait un tout petit "end if" pour que se soit parfait.vous me sortez une belle épine du pied :P.
Cordialement
10/01/2015, 20h06
Qwazerty

Salut

Citation:

'il manquait un tout petit "end if"

Juste par curiosité, où as-tu ajouté ce petit "end if" ?:weird:

++
Qwaz

Bonsoir le fil, bonsoir le forum,

Pareil Qwazerty !...

Une autre proposition plus rapide si il y a beaucoup de lignes :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Macro1()
Dim O As Object 'déclare la variable O (Onglet)
Dim TC As Variant 'déclare la variable TC (Tableau de Cellules)
Dim I As Integer 'déclare la variable I (Incrément)
Dim J As Integer 'déclare la variable J (incrément)
Dim LS As Range 'déclare la variable LS (LigneS)
Dim TEST As Boolean 'déclare la variable TEST
 
Set O = Sheets("Feuil1") 'définit l'onglet O (à adapter)
TC = O.UsedRange 'définit le tableau de cellules TC
Set LS = Range("A1") 'initialise la plage LS
For I = 2 To UBound(TC, 1) 'boucle 1 : sur toutes les lignes du tableau TC (en partant de la seconde)
    For J = 1 To UBound(TC, 2) 'boucle 2 : sur toutes les colonnes du tableau TC
        'condition : si la valeur du tableau TC en ligne I, colonne J n'est pas vide, définit la variable
        'TEST comme [Vrai] et sort de la boucle 2
        If TC(I, J) <> "" Then TEST = True: Exit For
    Next J 'prochaine colonne de la boucle 2
    'si TEST est [faux] redéfinit la plage LS (si Ls ne contient qu'une seule cellule, LS devient la ligne I,
    'sinon la ligne I s'ajoute à LS)
    If TEST = False Then Set LS = IIf(LS.Cells.Count = 1, Rows(I), Application.Union(LS, Rows(I)))
    TEST = False 'définit la variable TEST comme [faux]
Next I 'prochaine ligne de la boucle 1
LS.Delete 'efface la plage LS
End Sub

11/01/2015, 08h07
Qwazerty
Salut

En terme de rapidité d'exécution, il est très fortement conseillé lors de ce type de traitement qui peuvent être assez long, de désactiver la mise à jour de l'écran en utilisant
Code:

1 2 3 4 5 6 7 8 9 10 11 '... Application .ScreenUpdating = false 'La boucle qui modifie le tableau Excel '.... Application .ScreenUpdating = True '...
C'est non négligeable comme gain de temps.
Par contre un inconvénient, si le code plante et que vous choisissez d'arrêter l'exécution de celui-ci, penser à déplacer le curseur d'exécution (Flèche jaune qui pointe la ligne de code qui va être exécuté) sur la ligne ScreenUpdating = True et exécuté la avec la touche F8, sinon la mise à jour ne se fera plus dans Excel... et c'est pénible.
Au global pour éviter ça, il faut faire une gestion d'erreur et activé le ScreenUpdating avant de quitter la macro.

++
Qwaz
11/01/2015, 11h32
Thautheme

Bonjour le fil, bonjour le forum,

Tout à fait d'accord avec toi Qwazerty. Je ne l'ai pas mis dans le code que j'ai proposé car seule la dernière ligne : LS.Delete agit réellement sur le SreenUpdating. Et comme elle efface toutes les lignes en une seule fois ce n'était plus nécessaire...
Il est aussi conseillé, si le fichier contient de nombreuses formules, de mettre le calcul en manuel en début de macro (Application.Calculation = xlCalculationManual) puis de le remettre au automatique en fin de celle-ci (Application.Calculation=xlCalculationAutomatic) pour gagner du temps.
12/01/2015, 15h31
Invité

Citation:

Envoyé par sigma17

le code marche à merveille juste qu'il manquait un tout petit "end if" pour que se soit parfait.

Bonjour Sigma17,

Code:

If WorksheetFunction.CountA(Range(.Cells(I, 1), .Cells(I, 5))) < 5 Then .Cells(I, 1).EntireRow.Delete

Sachez que lorsque Then est suivi d'un code sur la même ligne, le End If est implicite, comme c'est le cas ici.

Si bien sûr

Code:

.Cells(I, 1).EntireRow.Delete

est mis à la ligne après Then, il vous faut ajouter ce End If en dessous de cette ligne.

C'est ce qu'ont voulu vous indiquer aussi Qwazerty et Thautheme.

Cordialement.