Decoupage fichier XML

Version imprimable

Bonjour,

Je post ici car j'ai un problème pour "découper" un fichier xml. Suite à un autre post sur ce forum il m'a été conseillé d'utiliser "xsltproc" et cela fonctionne :) Je souhaiterais juste apporter une modification et je solicite donc votre aide.

fichier.xml :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
<Message xmlns="http://www.URL.com/sous/lien">    
  <Identification>        
    <TypeMessage>ORDERS</TypeMessage>        
    <Version>1.0</Version>
    <FonctionMessage/>    
  </Identification> 
  <Commande>  
  <CommandeDLR>        
    <TypeDocument>1</TypeDocument>
    </CommandeDLR>
  </Commande>
</Message>

fichier.xsl :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:ns="http://www.URL.com/sous/lien" exclude-result-prefixes="ns">
 
   <xsl:output omit-xml-declaration="yes" />
 
   <xsl:template match="/ns:Message">
      <xsl:apply-templates select="ns:Commande"/>
   </xsl:template>
 
   <xsl:template match="ns:*">
      <xsl:element name="{local-name()}">
         <xsl:apply-templates select="node() | @*"/>
      </xsl:element>
   </xsl:template>
 
   <xsl:template match="node() | @*">
      <xsl:copy>
         <xsl:apply-templates select="node() | @*"/>
      </xsl:copy>
   </xsl:template>
 
</xsl:stylesheet>

Résultat :

Code:

1
2
3
4
5
<Commande>
  <CommandeDLR>
    <TypeDocument>1</TypeDocument>
    </CommandeDLR>
  </Commande>

Ce que je souhaiterais c'est afficher la même chose mais sans la balise "Commande". Savez-vous svp ce qu'il faut modifier dans le fichier.xsl pour arriver à ce résultat?

Merci d'avance.

Je viens de régler tout seul mon problème :mouarf:

Il fallait ajouter :
Code:

1 2 3 <xsl:template match="ns:Commande"> <xsl:apply-templates select="ns:CommandeDLR" /> </xsl:template>

Ouaip, même système que pour enlever la balise <Message>.

Autre possibilité, un peu plus directe :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:ns="http://www.URL.com/sous/lien" exclude-result-prefixes="ns">
 
   <xsl:output omit-xml-declaration="yes" />
 
   <xsl:template match="/">
      <!-- Le match racine, sélectionne directement les éléments à aller chercher dans le document -->
      <xsl:apply-templates select="/ns:Message/ns:Commande/*"/>
   </xsl:template>
 
   <xsl:template match="*">
      <xsl:element name="{local-name()}">
         <xsl:apply-templates select="node() | @*"/>
      </xsl:element>
   </xsl:template>
 
   <!-- le précédent template s'occupe des éléments. Celui-ci n'a donc besoin de s'occuper que des attributs et des textes, qui n'ont pas d'enfant. On peut simplifier. --> 
   <xsl:template match="node() | @*">
      <xsl:copy/>
   </xsl:template>
 
</xsl:stylesheet>