Fermeture de la fenêtre avec timer

Bonjour

Je ferme la fenêtre soit en cliquant sur un bouton ou soit en cliquant sur le X
Quand je clique sur le bouton je déclenche un timer pour donner effet de fondu.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
  Private Sub ToolStripButtonexit_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles ToolStripButtonexit.MouseDown
        flagexit = True
        Dim exitlogo As New Panel
        exitlogo.BackgroundImage = My.Resources.exitlogo_fw
        exitlogo.BackgroundImageLayout = ImageLayout.None
        exitlogo.Size = My.Resources.exitlogo_fw.Size
        Me.Controls.Add(exitlogo)
        exitlogo.Location = New Point((ClientSize.Width - exitlogo.Width) \ 2, (ClientSize.Height - exitlogo.Height) \ 2)
        exitlogo.BringToFront()
        Timerclose.Interval = 1
        Timerclose.Start()
    End Sub

Code:

1
2
3
4
5
6
7
8
Private Sub Timerclose_Tick(sender As Object, e As System.EventArgs) Handles Timerclose.Tick
        DirectCast(sender, Timer).Interval = 20
        Me.Opacity -= 0.01
        If Me.Opacity = 0 Then
            DirectCast(sender, Timer).Stop()
            Me.Close()
        End If
    End Sub

c

jusqu'à la pas de problème
maintenant j'essaie de faire la même chose si je clique le X de la fenêtre

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Formpreface_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
        If flagquit And Not flagexit Then
            Dim exitlogo As New Panel
            exitlogo.BackgroundImage = My.Resources.exitlogo_fw
            exitlogo.BackgroundImageLayout = ImageLayout.None
            exitlogo.Size = My.Resources.exitlogo_fw.Size
            Me.Controls.Add(exitlogo)
            exitlogo.Location = New Point((ClientSize.Width - exitlogo.Width) \ 2, (ClientSize.Height - exitlogo.Height) \ 2)
            exitlogo.BringToFront()
            Timerclose.Interval = 1
            Timerclose.Start()
        End If
    End Sub

bien sur le timer n'est pas déclenché donc la fenêtre se ferme :(

Merci

Bonjour,

L'évènement "FormClosed" est exécuté après la fermeture de la fenêtre, c'est donc trop tard
Il faut utiliser l'évènement "FormClosing" qui est exécuté avant la fermeture de la fenêtre.
(et bien sur gérer l'autorisation de la fermeture qui positionnera e.Cancel et déclenchera le timer )
Ex :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
    Dim t As Integer = 3 ' 3 secondes d'attentes
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        Timer1.Interval = 1000
    End Sub
    Private Sub Form1_FormClosing(sender As System.Object, e As System.Windows.Forms.FormClosingEventArgs) Handles MyBase.FormClosing
        Label1.Text = String.Format(" veuillez patienter, fermeture dans {0} seconde(s)", t)
        e.Cancel = Not Timer1.Enabled ' si le timer n'est pas lancé, interdit la fermeture, sinon l'autorise
        Timer1.Enabled = Not Timer1.Enabled ' si le timer n'est pas lancé, le lance, sinon l'arrête
    End Sub
    Private Sub Timer1_Tick(sender As System.Object, e As System.EventArgs) Handles Timer1.Tick
        t -= 1 ' compte à rebours
        Label1.Text = String.Format(" veuillez patienter, fermeture dans {0} seconde(s)", t)
        If t <= 0 Then Close() ' fini
    End Sub
    Private Sub Button2_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click
        Close()
    End Sub

Note : si l'utilisateur est pressé et reclique une 2 ème fois, la fermeture est immédiate. (dans ce cas pour interdire le 2ème clic, il faut passer par un flag qui gérera tout d'entré.)

Merci ;)