Inversion des caractères d'une chaîne

Version imprimable

Bonjour !

J'ai un problème avec cette procédure :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
program inverser;
begin
 
type
Tab=string;
 
Procedure Inverser (Var t : Tab; p, n : Integer);
Var aux : char;
Begin
If p < n Then
Begin
aux := t[p];
t[p] := t[n];
t[n] := aux;
Inverser (t, p + 1, n - 1);
 End;
 End;
End;
end.

Pourriez-vous m'aider ?

06/12/2014, 20h08
AdmChiMay
Oui, bonjour moi aussi.

Je pense que les gens qui liront ton post auront au moins deux problèmes en commun avec moi :
- Quel est ton problème, en clair in the text ?
- Il faudrait proposer un code lisible : d'abord la balise code (le # en haut à droite lors de l'édition), et ensuite indenter correctement ton code.
D'ailleurs, si tu avais indenté ton code, je subodore qu'il y aurait au moins un problème de visible. Mais peut-être que ce n'est pas celui qui t'as motivé à poster, allons savoir.
06/12/2014, 21h09
Roland Chastain

Citation:

Envoyé par nadirmabed

J'ai un problème avec cette procédure

Commençons par le début. Pourrais-tu nous expliquer ce que tu veux faire ?
06/12/2014, 21h25
nadirmabed

Je veux exécuter cette procédure, pour inverser un vecteur ou une chaîne de caractère. Free Pascal me marque beaucoup d'erreurs.
06/12/2014, 21h39
nadirmabed

1 pièce(s) jointe(s)

Pièce jointe 163207

Pour rendre ton programme compilable, il n'y a pas grand chose à changer :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
program inverser;
 
//begin
 
type
  Tab = string;
 
procedure Inverser (var t: Tab; p, n: Integer);
var
  aux: char;
begin
  If p < n Then
  begin
    aux := t[p];
    t[p] := t[n];
    t[n] := aux;
    Inverser (t, p + 1, n - 1);
  end;
end;
 
//end;
 
begin
end.

07/12/2014, 04h40
Roland Chastain
La déclaration du type Tab me semble inutile : autant utiliser directement le type string.

D'autre part, si ce que tu veux faire, c'est de renverser toute la chaîne, tu peux le faire plus simplement, par exemple de la façon suivante :
Code:

1 2 3 4 5 6 7 8 9 10 11 var aux: string; i: integer; begin aux := ''; for i := Length(t) downto 1 do aux := aux + t[i]; t := aux; end;
07/12/2014, 19h20
nadirmabed

Comment l'écrire en algorithme ?
07/12/2014, 19h31
nadirmabed

1 pièce(s) jointe(s)

Pièce jointe 163263

Quel est le type de la variable t ?
07/12/2014, 19h59
Roland Chastain

Le code que j'ai posté n'est pas un programme complet. C'est une autre version de ta procédure Inverser().
07/12/2014, 20h32
nadirmabed

Pourrais-tu l'écrire complètement ?

Citation:

Envoyé par nadirmabed

Pourrais-tu l'écrire complètement ?

Voici le programme complet :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
program Inversion;
 
procedure Inverser(var s: string);
var
  aux: string;
  i: integer;
begin
  aux := '';
 
  for i := Length(s) downto 1 do
    aux := aux + s[i];
 
  s := aux;
end;
 
var
  s1: string;
 
begin
  s1 := 'bonjour'; // ou ReadLn(s1);
  Inverser(s1);
  WriteLn(s1);
  ReadLn;
end.

08/12/2014, 13h54
e-ric

Citation:

Envoyé par nadirmabed

Pourrais-tu l'écrire complètement ?

Un petit effort personnel ne serait pas malvenu. Roland a déjà donné bien des précisions.
10/12/2014, 07h20
nadirmabed

Citation:

Envoyé par e-ric

Un petit effort personnel ne serait pas malvenu. Roland a déjà donné bien des précisions.

je suis un deputant
dèsole et merci a tous

Voici 3 autres méthodes pour inverser une chaîne. Toutes ne sont pas vraiment efficaces.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
 
program Inversion;
 
procedure InverserRecursif(var S: String);
 
  procedure InverserCaracteres(var S: String; Gauche, Droit: Integer);
  var
    C : Char;
  begin
    if Droit > Gauche then
    begin
      C := S[Gauche];
      S[Gauche] := S[Droit];
      S[Droit]:=C;
      InverserCaracteres(S, Gauche + 1, Droit - 1);
    end;
  end;
 
begin
  InverserCaracteres(S, 1, Length(S));
end;
 
procedure InverserEnPlace(var S: String);
var
  I, J, Len: Integer;
  Tmp : Char;
begin
  Len := Length(S);
 
  for I := 1 to  Len div 2 do
  begin
    J := Len - I + 1;
    Tmp := S[I];
    S[I] := S[J];
    S[J] := Tmp;
  end;
end;
 
procedure InverserAuHasard(var S: String);
var
  Aux : String;
  Len : Integer;
 
  function EstInverse : Boolean;
  var
    I : Integer;
  begin
    EstInverse := true;
    for I := 1 to Len do
      if Aux[I] <> S[Len - I + 1] then
      begin
        EstInverse := false;
        Break;
      end;
  end;
 
  procedure Echange(I, J : Integer);
  var
    C : Char;
  begin
    C := Aux[I];
    Aux[I] := Aux[J];
    Aux[J] := C;
  end;
 
begin
  Len := Length(S);
  if Len > 1 then
  begin
    Aux := S;
 
    while not EstInverse do
      Echange(Random(Len) + 1, Random(Len) + 1);
 
    S := Aux;
  end;
end;
 
var
  S1: String;
begin
  Randomize;
 
  S1 := 'abcdefghij'; 
  InverserEnPlace(S1);
  WriteLn('InverserEnPlace =>', S1);
 
  InverserRecursif(S1);
  WriteLn('InverserRecursif =>', S1);
 
  InverserAuHasard(S1);
  WriteLn('InverserAuHasard =>', S1);
end.

27/01/2015, 12h14
nadirmabed

merci beaucoup