Condition If qui fonctionne mais pas Else

Version imprimable

Bonjour à tous, j'ai un problème probablement encore tout bête mais je ne trouve pas la solution.
Dans une fonction DeleteFiles() j'ai une boucle For Each qui boucle sur chaques fichiers d'un répertoire. Les fichiers sont supprimés et vient ensuite un test if else qui doit vérifier si les fichiers sont bien supprimés et écrire les résultat dans un fichier texte.
Si le fichier n'a pas été supprimé "if fso.FileExists(fichier)", ça écrit bien "Echec de supression du fichier..." mais par contre le Else (qui devrait écrire "Fichier supprimé avec succès...") n'est semble t'il pas pris en compte donc ça n'écrit rien du tout. Je ne comprend pas pourquoi.
Voici un bout du code:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 Dim FolderName, TEMP, MyFile Set WshShell = WScript.CreateObject("WScript.Shell" ) Set fso = WScript.CreateObject("Scripting.FileSystemObject" ) Set MyFile = fso.CreateTextFile("rapport.txt" , True) WINDIR = WshShell.ExpandEnvironmentStrings("%WinDir%" ) DRIVE = WshShell.ExpandEnvironmentStrings("%SystemDrive%" ) TEMP = WshShell.ExpandEnvironmentStrings("%TEMP%" ) FolderName = TEMP if fso.FolderExists(FolderName) then DeleteFiles(FolderName) end if MyFile.Close msgbox("Suppression terminée!") Function DeleteFiles(FolderName) On Error Resume Next Dim ObjFolder Dim ObjFiles Dim ObjFile Set ObjFolder = fso.GetFolder(FolderName) Set ObjFiles = ObjFolder.Files For Each ObjFile In ObjFiles set fichier = ObjFile fichier.Delete if fso.FileExists(fichier) then MyFile.WriteLine("[Echec de suppression du fichier]--- " & fichier) Else MyFile.WriteLine("[Fichier supprimé avec succès]--- " & fichier) end if Next End Function

25/11/2014, 11h10
hackoofr

:salut:
Si tu enlèves cette instruction qui se trouve au début de la fonction DeleteFiles

Code:

On Error Resume Next

ça vous donne quoi comme résultat ?
25/11/2014, 12h53
Christophe.G

Il y a surement de ça, seulement quand je la retire j'ai une erreur une fois fichier.Delete quand un fichier est en cours d'utilisation et ne peut être supprimé. mais le problème doit bien venir de la je pense.
y a t'il moyen d'ignorer cette erreur quand un fichier est utilisé pour pouvoir supprimer l'instruction On Error Resume Next ?
28/11/2014, 12h01
Miistik

Bonjour,

As-tu essayé via le File Scripting Object (ta variable fso) ?

Code:

fso.DeleteFile cheminFichier, True

Il y a peut-être un moyen de contourner le problème : c'est en essayant d'ouvrir le fichier (peut importe en lecture ou en écriture) puis intercepter l'erreur et choisir l'action à entreprendre en conséquence :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Function DeleteFiles(FolderName)   
    Dim ObjFolder
    Dim ObjFiles
    Dim ObjFile   
    Set ObjFolder = fso.GetFolder(FolderName)   
    Set ObjFiles = ObjFolder.Files
    For Each ObjFile In ObjFiles 
           On Error Resume Next
           'On tente d'ouvrir le fichier
           set fich=fso.OpenTextFile(objFile.Path, 1, False)
           If Err.Number = 0 Then
               Fich.Close
               MyFile.WriteLine("[Fichier supprimé avec succès]--- " & ObjFile) 
               ObjFile.Delete true
           Else
               MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile)
           End If
    Next
End Function

Citation:

Envoyé par l_autodidacte

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Function DeleteFiles(FolderName)   
    Dim ObjFolder
    Dim ObjFiles
    Dim ObjFile   
    Set ObjFolder = fso.GetFolder(FolderName)   
    Set ObjFiles = ObjFolder.Files
    For Each ObjFile In ObjFiles 
           On Error Resume Next
           'On tente d'ouvrir le fichier
           set fich=fso.OpenTextFile(objFile.Path, 1, False)
           If Err.Number = 0 Then
               Fich.Close
               MyFile.WriteLine("[Fichier supprimé avec succès]--- " & ObjFile) 
               ObjFile.Delete true
           Else
               MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile)
           End If
    Next
End Function

:salut:
J'ai fait un petit test de votre méthode et j'ai essayé de sorte qu'il m'ouvre le fichier en écriture, alors j'ai constaté quand il s'agit d'un exécutable qui est en cours d'exécution, il ne le supprime pas ce qui très normale, alors quand il s'agit d'un fichier texte ou bien image ou bien vidéo, il le supprime même quand il est ouvert ?? :koi:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Option Explicit
Dim FolderName,fso,MyFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set MyFile = fso.CreateTextFile("rapport.txt",True)
FolderName = "E:\Test\HackooDossier"
 
Call DeleteFiles(FolderName)
'**************************************************************************************
Function DeleteFiles(FolderName)   
    Dim ObjFolder,ObjFiles,ObjFile,Fich  
    Set ObjFolder = fso.GetFolder(FolderName)   
    Set ObjFiles = ObjFolder.Files
    For Each ObjFile In ObjFiles 
           On Error Resume Next
           'On tente d'ouvrir le fichier en écriture
           set Fich=fso.OpenTextFile(objFile.Path,2,True)
           If Err.Number = 0 Then
               Fich.Close
               MyFile.WriteLine("[Fichier supprimé avec succès]--- " & ObjFile) 
               ObjFile.Delete True
           Else
               MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile)
           End If
    Next
End Function
'**************************************************************************************

29/11/2014, 13h36
l_autodidacte

Je ne sais pas si le fichier en sortie(rapport.txt) contient bien les informations attendues ou non.

Mais il ne faut pas perdre de vue la question : Pourquoi le script écrit le résultat dans le fichier rapport.txt si le fichier n'est pas supprimé mais pas dans l'autre cas ?

D'autre part, il y a certains types de fichiers(texte, entre autres) qui peuvent être supprimés même quand ils sont ouverts par Wordpad ou Notepad par exemple.
29/11/2014, 14h04
hackoofr

Citation:

Envoyé par l_autodidacte

Je ne sais pas si le fichier en sortie(rapport.txt) contient bien les informations attendues ou non.

Mais il ne faut pas perdre de vue la question : Pourquoi le script écrit le résultat dans le fichier rapport.txt si le fichier n'est pas supprimé mais pas dans l'autre cas ?

D'autre part, il y a certains types de fichiers(texte, entre autres) qui peuvent être supprimés même quand ils sont ouverts par Wordpad ou Notepad par exemple.

:salut:
Je crois que le script répond bien aux informations attendues :king: :plusser:
01/12/2014, 17h54
Christophe.G

nickel, c'est impeccable comme ça, j'obtiens le résultat souhaité. Merci à tous.
01/12/2014, 18h44
Christophe.G

J'ai parlé trop vite.
La ça indique bien si le fichier est supprimé ou s'il ne l'est pas, mais pour certains fichiers qui n'ont pas pus être supprimés, ça marque quand même fichier supprimé (alors que non).
Mais juste pour quelques fichiers, et pas forcément pour les exécutables, c'est le cas aussi pour un fichier texte et un sans extension. Mais il y a du mieux déjà.
01/12/2014, 20h21
ProgElecT

Salut

Citation:

Envoyé par Christophe.G

....mais pour certains fichiers qui n'ont pas pus être supprimés, ça marque quand même fichier supprimé (alors que non).

En définitif, quel code Function DeleteFiles(FolderName) utilises tu ?
02/12/2014, 08h34
l_autodidacte

Il me semble que Function DeleteFiles(FolderName) devrait être renommée en Sub DeleteFiles(FolderName) car une fonction doit retourner un résultat et pas une procédure Sub.

Je viens d'essayer avec Sub DeleteFiles(FolderName), j'obtiens le même résultat (ça s'affiche dans les deux cas, supprimé ou pas) avec le même problème pour certains fichiers qui sont notés comme étant supprimé avec succès alors que non.
Voici le code:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
FolderName = TEMP
if fso.FolderExists(FolderName) then
	DeleteFiles(FolderName)
end if
 
MyFile.Close
msgbox("Suppression terminée!")
 
Sub DeleteFiles(FolderName)   
    Dim ObjFolder
    Dim ObjFiles
    Dim ObjFile   
    Set ObjFolder = fso.GetFolder(FolderName)   
    Set ObjFiles = ObjFolder.Files
    For Each ObjFile In ObjFiles 
           On Error Resume Next
           set fich=fso.OpenTextFile(objFile.Path, 1, False)
           If Err.Number = 0 Then
               Fich.Close
               MyFile.WriteLine("[Fichier supprimé avec succès]--- " & ObjFile) 
               ObjFile.Delete true
           Else
               MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile)
           End If
    Next
End Sub

Salut

La partie de ton code qui ne peut pas t'assurer d'une bonne gestion
Code:

1 2 3 4 5 6 7 8 9 10 11 For Each ObjFile In ObjFiles On Error Resume Next set fich=fso.OpenTextFile(objFile.Path, 1, False) If Err.Number = 0 Then Fich.Close MyFile.WriteLine("[Fichier supprimé avec succès]--- " & ObjFile) ObjFile.Delete true Else MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile) End If Next
Ligne 3 tu vérifies si tu peux ouvrir le fichier,
ligne 4 tu considères que puisque tu a pus l'ouvrir tu vas pouvoir le supprimer,
ligne 5 tu le fermes,
ligne 6 tu déclares déjà que le fichier est supprimer (l'erreur est ici)
ligne 7 du lance la commande de suppression ?? Ok, mais si le système te le refuse (le on error est toujours valide/actif), .... ben ton fichier LOG te trompe car du l'as écris juste avant la commande de suppression.

Au minimum, ton code devrait ressembler à
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 For Each ObjFile In ObjFiles On Error Resume Next set fich=fso.OpenTextFile(objFile.Path, 1, False) If Err.Number = 0 Then ' le fichier est ouvrable Fich.Close ObjFile.Delete true If Err.Number = 0 Then ' le fichier a bien été supprimer MyFile.WriteLine("[Fichier supprimé avec succès]--- " & ObjFile) Else ' il y a refus de suppression du fichier Err.Clear MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile) End If Else ' le fichier n'a pas put être ouvert Err.Clear MyFile.WriteLine("[Echec de suppression du fichier]--- " & ObjFile) End If Next
Bien qu'utilisés par un .exe, par exemple, certains fichiers sont consultables mais non modifiables à plus forte raison non autorisés en suppression.
D'autres par statut propre au fichier (stratégie de sécurité) ont les mêmes contraintes.

04/12/2014, 00h55
Christophe.G

La ça me refait la même chose qu'avec mon code au départ, serte plus d'erreur ça met bien échec de suppression pour ce qui ne peut être supprimé, mais de nouveau ça n'inscrit pas ceux qui sont supprimés avec succès.

Salut

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Option Explicit
Dim FsO, MyFile
Dim FolderName, TEMP
 
'Set WshShell = WScript.CreateObject("WScript.Shell")
Set FsO = WScript.CreateObject("Scripting.FileSystemObject")
Set MyFile = FsO.CreateTextFile("C:\Dossier memo\rapport.txt", True)
 
FolderName = "C:\Dossier de test"
If FsO.FolderExists(FolderName) Then
    DeleteFiles (FolderName)
End If
MyFile.Close
Set MyFile = Nothing
Set FsO = Nothing
 
MsgBox ("Suppression terminée!")
 
Sub DeleteFiles(NameFolder)
 
    Dim ObjFolder, ObjFiles, ObjFile, Fich
    Dim NameFichier
 
    Set ObjFolder = FsO.GetFolder(NameFolder)
    Set ObjFiles = ObjFolder.Files
 
    For Each ObjFile In ObjFiles
        NameFichier = ObjFile.Name
        On Error Resume Next
        Set Fich = FsO.OpenTextFile(ObjFile.Path, 1, False)
        If Err.Number = 0 Then
            ' le fichier est ouvrable
            Fich.Close
            ObjFile.Delete True
            If Err.Number = 0 Then
                ' le fichier a bien été supprimer
                MyFile.WriteLine ("[Fichier supprimé avec succès]--- " & NameFichier)
                Else
                ' il y a refus de suppression du fichier
                Err.Clear
                MyFile.WriteLine ("[Echec de suppression du fichier]--- " & NameFichier)
            End If
            Else
            ' le fichier n'a pas put être ouvert
            Err.Clear
            MyFile.WriteLine ("[Echec de suppression du fichier]--- " & NameFichier)
        End If
    Next
    Set ObjFile = Nothing
    Set ObjFiles = Nothing
    Set ObjFolder = Nothing
End Sub

Code vérifié, l'erreur étant MyFile.WriteLine ("[Fichier supprimé avec succès]--- " & ObjFile), ObjFile et remplacé par le contenu de la variable NameFichier

05/12/2014, 01h15
Christophe.G

Bien vu, merci beaucoup, ça fonctionne nickel.