Problème de sauvegarde Word et Pdf depuis macro excel

Version imprimable

Bonjour,

Je débute dans le VBA et je coince depuis un petit bout de temps sur la fin de ma macro :
J'ai un document word de référence dans lequel j'intègre les données d'une feuille excel via les signets.
Je souhaite conserver le document word original et enregistrer la version modifiée séparément (en word et en pdf).
Les titres de ces nouveaux fichiers sont identiques entre eux et j'aimerais intégrer dedans des informations issues des cellules de l'excel.

Mais j'ai un message d'erreur vide au moment de l'enregistrement. Je n'ai pas réussi à faire une sauvegarde en pdf simple malgré les différents posts du forum.
Pouvez-vous m'aider ? (certaines explications dans mon code sont très simplistes et s'adressent à des utilisateurs sans expérience si des modifications devaient être apportées). Merci !

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub creationcertifdestru()
    Dim WordApp As Word.Application
    Dim WordDoc As Word.Document
    Dim A As String, B As String
    Dim i As Byte
 
    A = ActiveWorkbook.Path & "\Certif Destruction vierge avec signature - copie" 'mettre le nom exact du fichier vierge, ce fichier doit être placé dans le même répertoire que le fichier excel où la macro est présente
    B = ActiveWorkbook.Path & "\certificat de destruction - " & Range("G2").Value & " " & Range("D2").Value & " - " & Range("E2").Value & " - " & Range("F2").Value & ".doc" 'permet d'écrire le titre du certificat de destruction créé par la macro
 
        Set WordApp = CreateObject("word.application")    'ouvre une session Word
        Set WordDoc = WordApp.Documents.Open(A)  'ouvre le document Word vierge pour réaliser les modifications
        WordApp.Visible = False    'Word est affiché pendant l'opération, pour le masquer il faut écrire FALSE
 
        For i = 1 To 9 'on fait ici une boucle pour mettre dans les repères de word le contenu des cellules du fichier excel
            'les signets du document Word sont nommés Signet1 , Signet2 , Signet3...
            WordDoc.Bookmarks("Signet" & i).Range.Text = Cells(2, i)
        Next i 'la boucle s'arrête au bout de 9 tours
 
        WordDoc.Bookmarks("signet10").Range.Text = Format(Now, "dd/mm/yyyy") 'la date du jour est écrite dans le signet 10
 
 
        WordApp.Visible = False
        WordDoc.SaveAs2 B 'sauvegarde le fichier dans un nouveau word, dont l'emplacement et le nom sont indiqués au début du programme (B)
        WordDoc.Close 'ferme le document word
        WordApp.Quit 'ferme la session Word
        'WordDoc.Close True ' en sauvegardant les données
End Sub

13/11/2014, 20h51
clementmarcotte

Bonjour,

Il te manque la constante du format de sauvegarde sans ton saveas2. Si tu veux enregistrer en Word et en PDF, tu dois utiliser saveas2 deux fois et modifier la constante en conséquence.

Clique sur saveas2 et appuie sur :f1:

Mets un espion sur B et un point d'arrêt sur

Code:

WordDoc.Close

et vérifie la valeur de B dans la fenêtre espion
13/11/2014, 22h33
kiki29

Salut, et une fois de plus un mélange entre Early binding et Late binding : Early ou Late Binding

Bonjour et merci pour vos réponses.

Je me suis rendu compte que mon code initial marchait parfaitement, mais en rajoutant les données dans le titre ça bloquait à cause d'un anti-slash dans une cellule (caractère interdit dans les titres de documents).

Et en cherchant dans les recoins de l'aide F1 j'ai trouvé la constante pdf! Merci clementmarcote !

En revanche kiki29 je ne comprends pas où j'ai merdé dans le binding... (désolé c'est la première fois que je fais du VBA et j'ai grillé la théorie pour mettre en pratique sans avoir fait mes armes). J'avais mis le B trop tôt? ou dans la définition de mes variables j'aurais pu être plus précis?

le nouveau code!

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sub creationcertifdestru()
    Dim WordApp As Word.Application
    Dim WordDoc As Word.Document
    Dim A As String, B As String
    Dim i As Byte
 
    A = ActiveWorkbook.Path & "\Certificat de destruction" 'mettre le nom exact du fichier vierge, ce fichier doit être placé dans le même répertoire que le fichier excel où la macro est présente
 
        Set WordApp = CreateObject("word.application")    'ouvre une session Word
        Set WordDoc = WordApp.Documents.Open(A)  'ouvre le document Word vierge pour réaliser les modifications
        WordApp.Visible = False    'Word est affiché pendant l'opération, pour le masquer il faut écrire FALSE
 
        For i = 1 To 9 'on fait ici une boucle pour mettre dans les repères de word le contenu des cellules du fichier excel
            'les signets du document Word sont nommés Signet1 , Signet2 , Signet3...
            WordDoc.Bookmarks("Signet" & i).Range.Text = Cells(2, i)
        Next i 'la boucle s'arrête au bout de 9 tours
 
        WordDoc.Bookmarks("signet10").Range.Text = Format(Now, "dd/mm/yyyy") 'la date du jour est écrite dans le signet 10
        B = A & " - " & Range("G2").Value & " " & Range("D2").Value & " - " & Range("E2").Value & " - " & Range("F2").Value 'permet d'écrire le titre du certificat de destruction créé par la macro
 
        WordApp.Visible = False
        WordDoc.SaveAs2 B, wdFormatDocument 'sauvegarde le fichier dans un nouveau word, dont l'emplacement et le nom sont indiqués au début du programme (B)
        WordDoc.SaveAs2 B, wdFormatPDF 'sauvegarde le fichier en format pdf
        WordDoc.Close 'ferme le document word
        WordApp.Quit 'ferme la session Word
        'WordDoc.Close True ' en sauvegardant les données
End Sub

14/11/2014, 09h41
kiki29

Salut, cela saute aux yeux si tu as lu et assimilé ce qui est dit dans le lien donné plus haut.
14/11/2014, 10h08
Cllem_501

Désolé mais moi ça ne me parait pas si évident, je le répète je suis nouveau dans la prog quelle quelle soit.
J'ai pris des bouts de codes à droite à gauche donc reproduit les erreurs de ces personnes.
Je suppose après deuxième lecture du lien que tu reproches à ce code d'utiliser des variables WordDoc et Wordapp comme raccourcis ?
Sinon je suis perdu.

Bonjour,
On parle d'Early Binding (ou Liaison anticipée) lorsque la variable objet est déclarée dans un type objet précis.

Code:

Dim bkm as Word.BookMark 'Je veux un objet BookMark de la bibliothèque Word

On parle de Late Binding (Laison tardive) lorsque la variable objet est déclarée en tant qu'Object.
Code:

1 2 3 Dim oApp as Object 'Je veux un objet set oDApp = CreateObject("Word.Application") 'Créer une nouvelle instance de la classe Application de Word 'Et pointer la variable oAPP vers cet objet
Code:

1 2 Dim WordApp As Word.Application 'cette déclaration implique un référencement dans ton projet! Set WordApp = CreateObject("word.application") 'alors que cette écriture sous entent que tu ne la déclare pas dans le références!
Early Binding
Code:

1 2 3 Dim WordApp As New Word.Application Dim WordApp2 As Word.Application set WordApp2 =new Word.Application
Late Binding
Code:

1 2 Dim WordApp As Object Set WordApp = CreateObject("word.application")
moi je préfère la formulation Late Binding car elle prend en compte l'application installé sur la machine de l'utilisateur et pas celle du développeur (Word 2003,2010....)!

en revanche tu peux utiliser ta formulation pour le développement pour garde la saisie intuitive et ne pas oublier de supprimer Word de tes références et de renommer As Word.Application en As Object à la livraison.

si tu panache et que la référence pointe sur Word 2010 et que c'est Word 2013 sur la machine de l'utilisateur Erreur!

14/11/2014, 14h03
Cllem_501

Merci d'avoir pris le temps de détailler ta réponse rdurupt.
En effet Kiki29 ça pique les yeux dans mon code initial....je corrige de ce pas!

Merci pour vos explication à tous. Je vais maintenant étoffer la macro en faisant une boucle pour prendre en compte plusieurs ligne dans mon fichier excel.

Problème résolu et macro plus propre, merci à tous!