Probleme de macro entre excel 2007 et 2010

Version imprimable

Bonjour,

J'ai une macro qui fonctionnait bien sous excel 2007 et je suis passé en excel 2010 et depuis les images que j’insérai via un chemin ne s'affiche plus du moment ou je supprime ou je renomme le dossier d'image en question. Pourriez vous regardez se qui cloche et me donner une solution merci.

Voici le code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Sub InsertionImages()
 
Dim Repertoire As String
Dim Extension As String
Dim Fichier As String
 
 
'Saisie du nom du répertoire
Repertoire = InputBox("Chemin complet du répertoire (\ à la fin)", "Répertoire", "D:\test\")
If Repertoire = "" Then Exit Sub
 
'Saisie du type d'extension
Extension = InputBox("Type de fichier (sans le point, ex : jpg, png, bmp)", "Type de fichier", "jpg")
If Extension = "" Then Exit Sub
'Récupération du premier fichier du répertoire
Fichier = Dir(Repertoire & "*" & Extension, vbDirectory)
 
L = -3
c = 4
 
Do While Fichier <> ""
i = i + 1
'Insertion de l'image
L = L + 5
'Verification 3 photos
If L = 17 Then
c = c + 13
L = 2
 
 
 
End If
ActiveSheet.Pictures.Insert(Repertoire & Fichier).Select
 
'Selection.Name = monimage & L
Selection.Name = Fichier
Selection.ShapeRange.LockAspectRatio = msoFalse
'With ActiveSheet.Shapes(monimage & L)
With ActiveSheet.Shapes(Fichier)
 
.Top = Cells(c, L).Top
.Left = Cells(c, L).Left
.Height = Range(Cells(c, L), Cells(c + 11, L)).Height
 
.Width = Range(Cells(c, L), Cells(c, L + 4)).Width
 
End With
 
Range("L18").Select
 
Fichier = Dir
Loop
 
End Sub

09/11/2014, 18h44
SfJ5Rpw8

Bonsoir,

je ne comprends pas ce morceau de phrase :

Citation:

Envoyé par romain.l88

...depuis les images que j’insérai via un chemin ne s'affiche plus du moment ou je supprime ou je renomme le dossier d'image en question....

les images ne s'affiche plus "jamais" en 2010 ?.
09/11/2014, 18h57
romain.l88

Bonsoir,

Si si elle s'affiche car la macro fonctionne mais lorsque je ferme le fichier excel et que je supprime ou renomme le dossier ou sont les images , et bien lorsque je rouvre se fichier exel les photo ont disparu et un message me dit :" impossible d'afficher l'image liée. Le fichier a peut être été déplacer, renommé ou supprimer.Vérifiez que la liaison pointe vers le fichier et l’emplacement correct."
Alors que je n'ai jamais eu se problème sous excel 2007
09/11/2014, 19h55
Stef999

Bonsoir,

Ah oui ... même avec l'enregistreur de macro ça le fait, l'image est liée ...

Il faudrait jeter un oeil à Shapes.AddPicture(Filename, LinkToFile, SaveWithDocument, Left, Top, Width, Height) qui permet de spécifier de sauvegarder l'image avec le fichier.

Stéphane
10/11/2014, 17h04
romain.l88

Bonjour,

Stephan pourrait tu m'expliquer car je ne m'y connais pas vraiment en VBA
10/11/2014, 17h46
pgz
Bonjour à tous
Citation:
Envoyé par romain.l88

Voici le code

Code:

1 2 3 4 5 6 7 8 Sub InsertionImages() ... ActiveSheet.Pictures.Insert(Repertoire & Fichier).Select ... End Sub
Il y aurait une collection Pictures dans les propriétés de l'objet Worksheet ou de l'objet Chart ? Quelqu'un peut m'éclairer ?

Cordialement,

PGZ
10/11/2014, 21h43
clementmarcotte

Bonjour,

Citation:

Envoyé par pgz

Bonjour à tous

Il y aurait une collection Pictures dans les propriétés de l'objet Worksheet ou de l'objet Chart ? Quelqu'un peut m'éclairer ?

Cordialement,

PGZ

Je ne pense pas. Et même s'il y en avait une, j'ai bien l'impression que la ligne serait quand même rejetée.

Code:

ActiveSheet.Pictures.Insert(Repertoire & Fichier).Select

Sauf horreur de ma part, VBA n'accepte pas deux méthodes sur la même ligne.
11/11/2014, 12h25
Stef999

Bonjour,

Avec l'enregistreur de macro c'est pourtant bien cette ligne qui est enregistrée, et qui fonctionne.

Code:

ActiveSheet.Pictures.Insert(...).Select

Mais qui insère une image liée. Ca date de Excel 5 et c'est ce que nombre d'ancien sites sur vba indiquent comme technique pour insérer des images.

avec

Code:

ActiveSheet.Shapes.AddPicture Filename:="C:\xxxx.jpg", SaveWithDocument:=msoTrue, linktofile:=msoFalse, Left:=100, Top:=50, Width:=200, Height:=100

On a une image non liée.

Stephane
11/11/2014, 19h15
pgz

Bonsoir

Citation:

Envoyé par Stef999

Avec l'enregistreur de macro c'est pourtant bien cette ligne qui est enregistrée, et qui fonctionne.

Code:

ActiveSheet.Pictures.Insert(...).Select

Mais qui insère une image liée. Ca date de Excel 5 et c'est ce que nombre d'ancien sites sur vba indiquent comme technique pour insérer des images.

OK.

Citation:

Envoyé par Stef999

avec

Code:

ActiveSheet.Shapes.AddPicture Filename:="C:\xxxx.jpg", SaveWithDocument:=msoTrue, linktofile:=msoFalse, Left:=100, Top:=50, Width:=200, Height:=100

On a une image non liée.

Cela m'est plus familier et devrait répondre à la question initiale.

Merci Stephane.

PGZ
17/11/2014, 20h39
romain.l88

Bonsoir,

je voudrais savoir si je peut prendre cette ligne de code et quelle ligne je peut remplacer dans mon code d'origine.

Bonne soirée et merci beaucoup

Citation:

Envoyé par pgz

Bonjour à tous

Il y aurait une collection Pictures dans les propriétés de l'objet Worksheet ou de l'objet Chart ? Quelqu'un peut m'éclairer ?

Cordialement,

PGZ

Bonsoir, je pense que oui.... par hasard
Voir post http://www.developpez.net/forums/d14...s-feuille-2-a/
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Sub TestRemovePic() Dim Pics As Pictures, Pic As Picture Dim PicDelLog As String ' Toute la collection Set Pics = ActiveSheet.Pictures If Pics.Count > 0 Then 'Pour chaque élément de la collection For Each Pic In Pics
Bonne soirée

19/11/2014, 10h57
romain.l88

Citation:

Envoyé par pgz

Bonsoir

OK.

Cela m'est plus familier et devrait répondre à la question initiale.

Merci Stephane.

PGZ

Bonjour,

Serait-il possible de me mettre la ligne de code pour que cela fonctionne car je ne vois pas ou je doit insérer cette ligne

Bonsoir,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Sub InsertionImages()
 
Dim Repertoire As String
Dim Extension As String
Dim Fichier As String
 
 
'Saisie du nom du répertoire
Repertoire = InputBox("Chemin complet du répertoire (\ à la fin)", "Répertoire", "D:\test\")
If Repertoire = "" Then Exit Sub
 
'Saisie du type d'extension
Extension = InputBox("Type de fichier (sans le point, ex : jpg, png, bmp)", "Type de fichier", "jpg")
If Extension = "" Then Exit Sub
'Récupération du premier fichier du répertoire
Fichier = Dir(Repertoire & "*." & Extension, vbDirectory)
 
L = -3
c = 4
 
Do While Fichier <> ""
i = i + 1
'Insertion de l'image
L = L + 5
'Verification 3 photos
If L = 17 Then
c = c + 13
L = 2
End If
 
ActiveSheet.Shapes.AddPicture Filename:=Repertoire & Fichier, SaveWithDocument:=msoTrue, linktofile:=msoFalse, Left:=Cells(c, L).Left, Top:=Cells(c, L).Top, Width:=Range(Cells(c, L), Cells(c, L + 4)).Width, Height:=Range(Cells(c, L), Cells(c + 11, L)).Height
 
Range("L18").Select
 
Fichier = Dir
Loop
 
End Sub

Stéphane

20/11/2014, 00h18
romain.l88

Bonsoir,

C'est génial ça marche super bien merci beaucoup vous êtes au top.

Bonne continuation