Réunir le contenu de plusieurs onglets dans une même feuille

Version imprimable

29/10/2014, 15h31
musicalegria

1 pièce(s) jointe(s)

Réunir le contenu de plusieurs onglets dans une même feuille

Bonjour à tous et à toutes,

J'ai réussi à faire pas mal de choses avec mon fichier Excel qui me sert au boulot, mais je bloque sur une chose.
Voici le fichier pour mieux suivre la conversation : Pièce jointe 160126
Les onglets "Budget" et "Récap" ne bougent pas. (Ainsi que les onglets masqués).
Toutefois, sur la base de l'onglet "Modèle", je créé de nouveaux onglets "Modèle 2" etc... En tout, il y a aura une trentaine d'onglets identiques basés sur l'onglet "Modèle".
Le récapitulatif budgétaire simple de ces onglets créés au fur et à mesure est répertorié dans l'onglet "BUDGET". Ca, pas de problème.

Or, dans l'onglet "RECAP" j'aimerais avoir, sur cette unique feuille "RECAP", l'affichage des données comprises entre A8-AA8 à A167-AA167 de chaque onglet "Modèle" à la suite.
Donc on aurait les lignes de 8 à 167 de l'onglet "Modèle", puis les lignes de 8 à 167 de l'onglet "Modèle 2" et ainsi de suite...

J'ai regardé un peu les macros et j'ai vu que des choses étaient possibles, mais je ne sais pas s'il est possible d'avoir une macro générique qui s'adapterait à la création de nouveaux onglets modèles ?

Si on peut aussi pousser le vice à n'avoir le récap que des lignes de 10 à 29, 34 à 53, 58 à 77, 82 à 101, 106 à 110, 115 à 119, 124 à 128, 133 à 166 de chaque onglet dans l'onglet "RECAP", c'est encore mieux.

Si jamais quelqu'un a une idée pour moi, elle est le bienvenue.
Merci de votre aide !

1 pièce(s) jointe(s)

Bonjour MusicAlegria, bonjour le forum,

En pièce jointe le fichier avec juste l'onglet RECAP tel qu'il doit être pour que le code fonctionne. Remplace cet onglet dans ton fichier originale et clique sur le bouton MAJ... pour mettre à jour les données de tous les onglets Modèle...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub CommandButton1_Click() 'bouton mise a jour
Dim O As Object 'déclare la variable O (Onglets)
Dim PL As Range 'déclare la variable PL (PLage)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)
 
Application.ScreenUpdating = False 'masque les rafraîchissements d'écran
Rows("3:" & Application.Rows.Count).Delete 'efface les anciennes données
For Each O In Sheets 'boucle sur tous les onglets du classeur
    Select Case Left(O.Name, 6) 'agit en fontion des 6 premiers caratères du nom de l'onglet
        Case "Modèle" 'cas "Modèle"
            'définit la plage PL
            Set PL = Application.Union(O.Range("A10:AA29"), O.Range("A34:AA53"), O.Range("A58:AA77"), O.Range("A82:AA101"), O.Range("A106:AA110"), O.Range("A115:AA119"), _
                O.Range("A124:AA128"), O.Range("A133:AA166"))
            'définit la cellule de destination DEST
            Set DEST = Sheets("RECAP").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0)
            PL.Copy DEST 'copie la plage PL dans DEST
    End Select 'fin de l'action en fonction des 6 premiers caractères du nom de l'onglet
Next O 'prochain onglet de la boucle
Application.ScreenUpdating = True 'affiche les rafraîchissements d'écran
End Sub

Sinon, MusicAlegria, c'est quoi le prochain concert que tu organises ?

30/10/2014, 16h05
musicalegria

Bonjour Thautème,

J'ai réussi (tant bien que mal) à copier la commande et le bouton dans mon fichier...Puis, quand j'ai cliqué sur MAJ, c'était magique !
MERCI, c'est à priori LA piste à suivre !

Toutefois :
- Quand je rajoute un onglet, ça ne s'ajoute pas à la suite du récap (même en recliquant sur MAJ)
- Quand je renomme l'onglet, ça ne marche plus... (Or, je compte nommer mes onglets DATE/VILLE)

Je me dis donc :
1) Sois, il faut que je copie autre chose que la commande avec le bouton, et dans ce cas, c'est une incompétence de ma part de ne pas savoir copier un onglet vers un autre classeur.
2) Pour l'histoire du nom, je me dis que si je créé une occurence du type "A- DATE/VILLE", je peux jouer sur la fonction qui "agit en fontion des 6 premiers caratères du nom de l'onglet" sur l'occurrence "A-"
3) Pour le fait que ça ne reproduit pas les autres onglets, là je ne vois pas où ça intervient dans le code. Peut-être peux-tu à nouveau m'éclairer ?

Le prochain concert c'est dans 3h à Villepinte, autour des Antilles, mélange tambour Ka (Sonny Troupé) et hip-hop (Casey) ! Ca va donner !

Merci encore.
A bientôt.
30/10/2014, 16h49
Thautheme
Bonjour MusicAlegria, bonjour le forum,

Dans ton premier post tu dis que les nouveaux onglets s'appellent Modèle2, Modèle3, etc... Le code passe les onglets un par un et ne récupère les données que des onglets commençant par Modèle avec les lignes :
Code:

1 2 Select Case Left(O.Name, 6) Case "Modèle"
Si tes nouveaux onglets ne commencent plus par "Modèle", évidemment ça ne fonctionne plus !

Si tu veux utiliser A- alors modifie le code :
Code:

1 2 Select Case Left(O.Name, 2) Case "A-"

Bonjour Thautème,

Ok c'est bien ce que j'avais compris pour le nom. J'ai fait la modification. Merci.
Mais donc, je me suis mal exprimée la première fois, mais même sans changer le nom de l'onglet, quand j'ajoutais un onglet, dans le récap n'apparaissait pas le récap des autres onglets.
Donc, là j'ai bien mon code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub CommandButton1_Click() 'bouton mise a jour
Dim O As Object 'déclare la variable O (Onglets)
Dim PL As Range 'déclare la variable PL (PLage)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)
 
Application.ScreenUpdating = False 'masque les rafraîchissements d'écran
Rows("3:" & Application.Rows.Count).Delete 'efface les anciennes données
For Each O In Sheets 'boucle sur tous les onglets du classeur
    Select Case Left(O.Name, 2) 'agit en fontion des 2 premiers caratères du nom de l'onglet
        Case "A-" 'cas "Modèle"
            'définit la plage PL
            Set PL = Application.Union(O.Range("A10:AA29"), O.Range("A34:AA53"), O.Range("A58:AA77"), O.Range("A82:AA101"), O.Range("A106:AA110"), O.Range("A115:AA119"), _
                O.Range("A124:AA128"), O.Range("A133:AA166"))
            'définit la cellule de destination DEST
            Set DEST = Sheets("RECAP").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0)
            PL.Copy DEST 'copie la plage PL dans DEST
    End Select 'fin de l'action en fonction des 6 premiers caractères du nom de l'onglet
Next O 'prochain onglet de la boucle
Application.ScreenUpdating = True 'affiche les rafraîchissements d'écran
End Sub
 
Mais quand j'ajoute un deuxième onglet, ça ne se rajoute pas à la suite.
J'imagine que c'est dans cette ligne là qu'il faut modifier quelque chose ?
    Set DEST = Sheets("RECAP").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0)

Merci !
Bonne journée !

31/10/2014, 18h34
Thautheme

Bonsoir MusicAlegria, bonsoir le forum,

En fait, ça ne se fait pas automatiquement ! Il te faut cliquer sur le bouton MAJ pour que les données du nouvel onglet soit récupérées.
On pourrait le faire automatiquement en mettant le code dans le composant ThisWorkbook dans la procédure NewSheet. Mais j'ai pensé que tu allais d'abord remplir ce nouvel onglet et une fois les données éditées, là, tu récupèrerais dans RECAP ces données. C'est pour cette raison que j'ai préféré le bouton qui commence par tout supprimer dans l'onglet RECAP et refait la boucle sur tous les onglets pour récupérer un par un.
J'ai pensé que de cette manière tu aurais toujours les données à jour en appuyant sur le bouton MAJ qui, comble de l'ironie, signifie Mise A Jour. Comme quoi il n'y a pas de hasard...
Mais si tu préfères de l'automatique à la création d'un nouvel onglet, pas de problème, je te recode tout ça en écoutant de la música alegria do Brasil...
03/11/2014, 11h08
musicalegria

Bonjour Thautème,

Non ça ne me dérange pas que ce ne soit pas automatisé.
Mais justement, même en recliquant sur le bouton MAJ, ça ne prend pas en compte les nouveaux onglets !
Donc, j'ai que le récap' du premier onglet.
Je ne sais pas pourquoi ça ne fonctionne pas...
03/11/2014, 11h45
Thautheme

Bonjour MusicAlegria, bonjour le forum,

Je viens de comprendre (il était temps...) ! En fait ça marche mais ça recopie toujours au même endroit à cause de la ligne :

Code:

Set DEST = Sheets("RECAP").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0)

Remplace cette ligne par :

Code:

Set DEST = Sheets("RECAP").Cells(Sheets("RECAP").UsedRange.SpecialCells(xlCellTypeLastCell).Row + 1, 1)
03/11/2014, 12h33
musicalegria

Thautème,

Yes !!! Ca fonctionne !!
Merci infiniment, c'est super ! J'ai essayé de chercher la réponse par moi-même, mais je n'aurais jamais trouvé en fait...

Saurais-tu répondre à cette dernière question :
J'ai essayé de faire un filtre par couleur sur le RECAP (pour afficher quand j'en aurais besoin, toutes les lignes rouges, puis toutes les lignes jaunes etc), mais "Filtre par couleur" apparait en grisé donc non utilisable...Est-ce que c'est à cause du format du fichier excel (qui prend en charge les macros), que ça ne fonctionne pas ?

Merci, merci, en tout cas, c'est génial !!
(Ca donne envie de danser sur la musica do Brasil dont tu parlais :))

Bonsoir MusicAlegria, bonsoir le forum,

Ces deux macro événementielles à placer dans le composant RECAP. L'une réagit au double-clic, l'autre au clic du bouton-droit. Les deux ont une action limitée à la première colonne (colonne A). Donc si tu double-cliques dans une cellule de la colonne A, seules resteront affichées les lignes de la même couleur que la cellule double-cliquée.
Pour afficher à nouveau toutes les lignes un clic-du bouton-droit sur n'importe quelle cellule de la colonne A.
Le code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim COUL As Variant 'déclare la variable COUL (COULeur)
Dim TC As Variant 'déclare la variable TC (Tableau de Cellules)
Dim PL As Range 'déclare la variable PL (PLage)
 
Application.ScreenUpdating = False 'masque les rafraîchiessements d'écran
Set PL = Range("A1") 'définit la plage PL (initialisation)
If Target.Column <> 1 Then Exit Sub 'si le double-clic a lieu ailleurs que dans la colonne A'sort de la procédure
Cancel = True 'annule le mode [Édition] lié au double-clic
COUL = Target.Interior.Color 'définit la couleur COUL
TC = Range("A1:A" & Sheets("RECAP").UsedRange.SpecialCells(xlCellTypeLastCell).Row) 'définit le tableau de variables TC
For I = 3 To UBound(TC, 1) 'boucles sur toutes les lignes du tableau TC (en partant de la ligne 3)
    If Cells(I, 1).Interior.Color <> COUL Then 'condition : si la cellule n'a pas la même couleur que COUL
        'définit la plage PL (si PL n'a qu'une seule cellule, la ligne i, sinon, l'union de PL et la ligne I
        Set PL = IIf(PL.Cells.Count = 1, Rows(I), Application.Union(PL, Rows(I)))
    End If 'fin de la condition
Next I 'prochaine ligne de la boucle
PL.EntireRow.Hidden = True 'masque la plage PL
Application.ScreenUpdating = True 'affiche les rafraîchiessements d'écran
End Sub

Code:

1
2
3
4
5
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Target.Column <> 1 Then Exit Sub 'si le double-clic a lieu ailleurs que dans la colonne A'sort de la procédure
Cancel = True 'annule le [menu contextuel] lié au clic du bouton-droit
Rows.Hidden = False 'affiche toutes les lignes
End Sub

Bora dançar ?

10/11/2014, 10h44
musicalegria

Bonjour Thautème,

Désolée, j'ai eu une semaine très chargée !! The festival's on !!

Je viens de regarder ton post, mais là, tu m'as perdue.
J'ai essayer de créer une macro en mettant le code que tu me donnes, mais ça ne fonctionne pas...car je ne vois pas comment enregistrer la macro !!

Bon je crois qu'il va falloir que je prennes des cours de macros........

Merci en tout cas, dès que j'ai un moment, je m'y repenche sérieusement !!

A++
Bonne journée,
12/11/2014, 13h40
Thautheme

Bonjour MusicAlegria

Voici la procédure à suivre :
• Copie le code que je t'ai proposé
• Sélectionne l'onglet dans lequel tu veux qu'il agisse
• Clique avec le bouton droit dans le nom de cet onglet (en bas)
• Choisis l'option Visualiser le code
• Tu te retrouves dans VBE (Visual Basic Editor)
• La où le curseur clignote, colle de code copié
• Idem pour le second code
• [ALT] + [F11] pour fermer VBE
• Enregistre ton fichier

Dès lors, le filtrage par couleurs devrait se faire au double-clic dans une cellule de la colonne A et le ré affichage de toutes les couleurs au clic du bouton droit dans une cellule de la colonne A de l'onglet en question...
12/11/2014, 15h00
musicalegria

Bonjour Thautème,

Ah génial !
Non seulement c'est parfait, mais en + ça m'a permis de comprendre (enfin!) le fonctionnement de l'enregistrement des macros. Car au début, je pensais qu'il fallait en créer une à chaque fois, mais finalement, mettre ça à la suite, ça fonctionne !
Un grand grand merci c'est vraiment chouette !

Maintenant, il faut venir sur les concerts, à Pantin (salle jacques brel) ce samedi, j'offre des verres facilement :) surtout quand -comme dans ce cas précis- je ne sais comment retourner l'appareil au service rendu !!

Merci beaucoup !
Bonne journée,
Anne-Laure
12/11/2014, 15h38
Thautheme

Bonjour Anne-Laure, bonjour le forum,

Content que ça fonctionne.
Sinon de Sète à Paris le chemin est un peu long... Mais qui sait ? un jour peut-être... En tous cas merci pour l'invitation.

Bonne journée à toi aussi.
15/12/2014, 15h33
musicalegria

1 pièce(s) jointe(s)

Erreur de manip ?

Bonjour Thauthème,

je ne sais pas ce que j'ai fais et je ne trouve pas mon erreur...: le bouton commande ne fonctionne plus !

Voici le fichier
Pièce jointe 163913

Peux-tu éclairer mon ignorance ?

Merci beaucoup,
27/05/2016, 16h49
musicalegria

1 pièce(s) jointe(s)

Suite macros fichier excel

Bonjour,

Grâce à l'aide de Thautème, j'ai pu développer un super tableau de travail que voici.
J'aimerais ajouter une modernité c'est que dans l'onglet LISTING et HBGT, la boucle faite sur les onglets n'affiche que les lignes où il y a du contenu quand je fais la MAJ.
J'ai regardé sur des forums et je vois bien que c'est possible, mais comme je ne sais pas coder, je ne sais pas comment écrire une boucle à l'intérieur de celle déjà créée.
Sachant qu'il y a toujours du contenu texte dans la première colonne si une ligne a du contenu. Donc la première colonne peut être la référence de la boucle.
Quelqu'un pour m'aider ?

Merci infiniment.
Anne Laure