InputBox et Conditions

Version imprimable

Bonjour à tous,
J'utilise une InputBox dans une macro afin de saisir une date.
Si une date est renseignée,je poursuis ma macro, si elle n'est pas renseignée mais que le bouton Ok est cliqué j'envoi un message via une MsgBox.
Enfin si on clique le bouton Cancel on sort de la macro.
Voici le code réalisé :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Sub Data_Date() Dim x As Variant x = InputBox("Enter Data Date" & Chr(10) & " " & Chr(10) & "Use format dd/mm/yy", "NEW_DATA_DATE", "", vbOKCancel) If x <> "" Then Baseline_Date Else If vbOK And x = "" Then MsgBox "Enter a valid date", , "WARNING" ElseIf vbCancel And x = 0 Then Exit Sub End If End If End Sub
Mon problème vient du fait que lorsque je clique sur Cancel, ma msgBox apparaît tout de même, ce qui est normal car x=0 (espion) mais ma condition

Code:

ElseIf vbCancel And x = 0 Then

ne semble pas être reconnue.
:mur:
Comment puis résoudre ce problème ?
Merci pour vos conseils
Eric

10/09/2014, 16h08
Invité

Bonjour,
quel vbCancel ?

Code:

x = InputBox("Enter Data Date" & Chr(10) & " " & Chr(10) & "Use format dd/mm/yy", "NEW_DATA_DATE", 100, 100, 100)
10/09/2014, 17h20
eric4459

Bonjour rdurupt,
Selon moi ligne 5 où je défini ma MsgBox avec ("mon message","titre de ma fenêtre", "valeur par défaut", type de bouton)
mais je me suis peut-etre trompé là-dessus?

Eric
10/09/2014, 17h43
rob1son76

Salut,

Je ne vois pas quand x peut être égale à Zéro.
essaie sans!!
10/09/2014, 17h55
eric4459

Bonjour Robinson76,
Effectivement cette condition n'est pas correcte mais après avoir corrigé pour

Code:

ElseIf vbCancel And x = "" Then

le problème reste le même : l'appui sur le bouton Cancel provoque l'apparition du message "Enter a valid date" .
Eric
10/09/2014, 20h28
clementmarcotte

Bonjour,

Citation:

Envoyé par eric4459

Bonjour à tous,
x = InputBox("Enter Data Date" & Chr(10) & " " & Chr(10) & "Use format dd/mm/yy", "NEW_DATA_DATE", "", vbOKCancel)
Baseline_Date
MsgBox "Enter a valid date", , "WARNING"
Eric

Être en France et s'effoirer devant l'anglais. Joualvert!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!:aie::aie::aie::aie:
10/09/2014, 22h37
Docmarti

Bonjour Clément.

Citation:

Être en France et s'effoirer devant l'anglais. Joualvert!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!:aie::aie::aie::aie:

Quand on est souverain, on peut tout se permettre.

Bonjour,
Avec la fonction InputBox, il est impossible de distinguer si l'on a cliqué sur le bouton Annul, qui renvoie une chaîne de caractère vide (""), ou si l'on a cliqué sur le bouton OK alors que l'on a rien inséré comme donnée.
En effet dans la procédure qui suit rien ne permet de distinguer les deux cas évoqués plus haut
Code:

1 2 3 Dim myVar As Variant myVar = InputBox("Entrez une donnée") MsgBox ">" & myVar & "<" & Len(myVar)
Toutefois, une astuce consisterait à utiliser la fonction StrPtr.
Cette fonction dont voici l'explication de Microsoft à l'adresse http://support.microsoft.com/kb/199824/fr

Citation:

Dans Visual Basic, les chaînes sont stockées en tant que BSTR. Si vous utilisez la fonction VarPtr sur une variable de type String (chaîne), vous obtiendrez l'adresse du BSTR, qui est un pointeur vers un pointeur de la chaîne. Pour obtenir l'adresse du tampon de chaîne lui-même, vous devez utiliser la fonction StrPtr. Cette fonction renvoie l'adresse du premier caractère de la chaîne. Tenez compte du fait que les chaînes sont stockées en tant que chaînes UNICODE dans Visual Basic.

permet en effet de distinguer la différence entre OK avec chaîne vide, OK avec chaîne remplie et Annul.
En reprenant le code utilisé plus haut et en modifiant la ligne 3 par celle ci-dessous,

Code:

MsgBox StrPtr(myVar)

On peut constater que si l'on a cliqué sur Annul la fonction renvoie 0 dans tout les cas alors que OK renvoie un nombre que la chaîne renvoyée par InputBox soit vide ou pas.
Donc partant de ce constat, on pourrait utiliser cette procédure
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Sub TestInputBox() Dim myVar As Variant myVar = InputBox("Entrez votre données", "Introduction des données") If StrPtr(myVar) = 0 Then MsgBox "Annulation de l'opération" Else If myVar = "" Then MsgBox "Vous n'avez rien saisi" Else MsgBox "Vous avez saisi " & myVar End If End If End Sub
Attention, je n'ai effectué de test que sur la version 2010
A lire Unofficial Documentation for VarPtr, StrPtr, and ObjPtr

1 pièce(s) jointe(s)

bonjour,
si tu dessines ton propre InputBox tu fais ce que tu veux!

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Public Function txt(Titre As String, Etiquette, Optional Default)
Me.Caption = Titre
Me.Label1 = Etiquette
Me.TextBox1 = Default
Me.Show vbModal
On Error Resume Next
txt = Me.Tag
If Err <> 0 Then txt = False
Err.Clear
On Error GoTo 0
End Function
 
Private Sub CommandButton1_Click()
Me.Tag = Me.TextBox1
Me.Hide
End Sub
 
Private Sub CommandButton2_Click()
Me.Tag = False
Me.Hide
End Sub

Code:

1
2
3
4
5
Sub test()
Dim txt
txt = MyInputBox.txt("Test", "Entrez la valeur du text", 100)
MsgBox txt
End Sub

11/09/2014, 12h58
eric4459

Philippe, Robert
Merci pour ces deux approches, celle de Philippe est un peu plus absconse,(mêlant pour clementmarcotte), celle de Robert me plait beaucoup car c'est une bonne façon de contourner le problème et a le mérite de démontrer que tout, ou presque, est possible avec un peu de connaissance.
Eric