Problème de condition dans une bouche WHILE

Version imprimable

Bonjour à tous !!

Afin de faciliter la mise en forme de fichiers Excel, j'ai essayé de créer une macro sous Excel avec mes notions de débutante.

Mon projet est le suivant: J'ai crée une boucle pour supprimer tous les sauts de pages et intégrer des nouveaux sauts toutes les 60 lignes, jusqu'à la fin de mon tableau. Je ne souhaites pas avoir de sauts de page après la dernière ligne utilisée. L'ajout des bordures est pour l'impression car ces dernières disparaissent lors de l'aperçu avant impression.

Pour cela:
- je déclare une variable "Dern_Saut_Page" qui récupère la dernière ligne utilisée
- la condition d'application de la boucle est la différence entre la "Dern_Saut_Page" et la ligne du saut de page à intégrer. Si elle est négative, on est en dessous du tableau.

Mon problème avec la boucle suivante est qu'un dernier saut de page est crée et surtout les bordures apparaissent en dessous du tableau. Comment procéder, s'il vous plait, pour ne pas créer ce dernier saut de page??

Je vous remercie par avance de votre aide.

Voici le code de ma macro:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 Sub MEF_DETAIL() 'Mettre en forme la page "DETAIL" Dim h As Integer Dim Dern_Saut_Page As Integer Sheets("DETAIL").Select 'Supprimer tous les sauts de pages automatiques Sheets("DETAIL").ResetAllPageBreaks ' Insérer des sauts de page toutes les 60 lignes h = 60 Dern_Saut_Page = Range("A" & Rows.Count).End(xlUp).Row [A9].Select Do While (Dern_Saut_Page - ActiveCell.Offset(h - 1, 0).Row) > 0 'MsgBox (Dern_Saut_Page - ActiveCell.Offset(h - 1, 0).Row) ActiveCell.Offset(h, 0).Select ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=ActiveCell ActiveCell.Offset(h - 1, 0).Borders(xlEdgeBottom).LineStyle = xlContinuous ActiveCell.Offset(h - 1, 1).Borders(xlEdgeBottom).LineStyle = xlContinuous ActiveCell.Offset(h - 1, 2).Borders(xlEdgeBottom).LineStyle = xlContinuous ActiveCell.Offset(h - 1, 3).Borders(xlEdgeBottom).LineStyle = xlContinuous ActiveCell.Offset(h - 1, 4).Borders(xlEdgeBottom).LineStyle = xlContinuous Loop Range("A1").Select End Sub

Bonjour,

Personnellement j'aurais pas fait comme cela (attention je dis pas que c'est mauvais mais il me semble qu'il y a plus simple surtout quand on débute)

Avec l'utilisation de l'objet Cells (Cells(N°ligne, N°Colonne) on peut facilement se déplacer sur les cellules.

algo proposé
Code:

1 2 3 4 5 6 7 8 9 10 ' J'apelle lign une variable qui contient mon N°ligne Lign =1 faire tant que valeur de la cellule(lign,1) <>"" 'ici je fait mes bordures si Lign = 60 alors ' ici mon saut de page lign = 0 fin si lign = lign+1 boucle
pour avoir la valeur d'une cellule en VBA c'est : cells(lign,1).value (si je considère que mon test est sur la 1ère colonne)

tu dis, si tu as des doutes n'hésite pas

Peut-être peux tu mettres un fichier sans données sensible pour clarifié tes demandes (voir 1er post de Pierre Fauconnier sur le Forum)

A Bientôt

Bonjour,

Teste ceci. Evite autant que possible les "Select et autres Activate, ça ralentit et en plus ça fait scintiller l'écran ce qui est plutôt désagréable :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Sub MEF_DETAIL()
 
    Dim Fe As Worksheet
    Dim h As Integer
    Dim Dern_Saut_Page As Integer
 
    Set Fe = Sheets("DETAIL")
 
    With Fe
 
        'Supprimer tous les sauts de pages automatiques
        .ResetAllPageBreaks
 
        Dern_Saut_Page = .Range("A" & .Rows.Count).End(xlUp).Row
 
        ' Insérer des sauts de page toutes les 60 lignes
        h = 60
 
        Do While h < Dern_Saut_Page
 
            .HPageBreaks.Add .Cells(h, 1)
            .Range(.Cells(h - 1, 1), .Cells(h - 1, 4)).Borders(9).LineStyle = 1
 
            h = h + 60
 
        Loop
 
    End With
 
End Sub

Hervé.

03/09/2014, 16h38
jessylfoh

Bonjour Theze,

Je te remercie pour le code fourni qui a résolu mon problème de dernier saut de page.
Par contre, mon tableau commence en ligne 9 et par conséquent, je souhaiterai intégrer les sauts de page qu'à partir de cette ligne.
Pouvez- vous me dire comment je peux intégrer ceci dans votre code??

Je vous remercie par avance.

Jessica

Bonjour,

Il suffit de rajouter 9 à l'initialisation de la variable h (h = 69) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Sub MEF_DETAIL()
 
    Dim Fe As Worksheet
    Dim h As Integer
    Dim Dern_Saut_Page As Integer
 
    Set Fe = Sheets("DETAIL")
 
    With Fe
 
        'Supprimer tous les sauts de pages automatiques
        .ResetAllPageBreaks
 
        Dern_Saut_Page = .Range("A" & .Rows.Count).End(xlUp).Row
 
        ' Insérer des sauts de page toutes les 60 lignes à partir de la ligne 9
        h = 69
 
        Do While h < Dern_Saut_Page
 
            .HPageBreaks.Add .Cells(h, 1)
            .Range(.Cells(h - 1, 1), .Cells(h - 1, 4)).Borders(9).LineStyle = 1
 
            h = h + 60
 
        Loop
 
    End With
 
End Sub

Hervé.

16/09/2014, 17h34
jessylfoh

Merci beaucoup !!!

Bonjour !!

Mieux vaut tard que jamais mais cela marche nickel.
Merci beaucoup

Jess