Combobox en cascade problème

Version imprimable

04/08/2014, 11h26
Shini28

1 pièce(s) jointe(s)

Combobox en cascade problème

Bonjour tout le monde,

J'ai créé un projet qui consiste à faire un moteur de recherche. Ce moteur permet de rechercher des fichiers Excel dans un dossier spécifique.

Je remplis mes combobox avec un tableau qui se situe dans une feuille. Quand on sélectionne un item dans le combobox 1, ça rempli la deuxième automatiquement, et un si de suite pour les autres.

Mon problème est que certaines combobox ne se remplissent pas quand il y a des chiffres dedans.

J'ai essayé en mettant "blabla" et ça fonctionne.

Je suis bloqué depuis quelques jours, et cela m'aiderai énormément si quelqu'un connait la solution.

Le fichier est dans les pièces jointes.

Pour information, le problème est dans le Userform4, le Userform 1 étant un essai au début du projet.

Merci d'avance
04/08/2014, 12h25
mercatog

Au lieu d'un fichier, il serait mieux de poster le code.

Peut être, tu ne compare pas un String à un Nombre?

Ah oui excusez moi, voici le morceau de code en question qui me permet d'alimenter une combobox, c'est le même pour toute, juste les colonnes qui changent :

les variables sont inscrites en amont de mon code :

Code:

1
2
3
4
5
6
7
8
9
10
Option Explicit
 
Dim Ws As Worksheet
Dim NbLignes As Integer
Dim a As Integer
Dim b As Integer
Dim c As Integer
Dim mat_fonct As String
Dim mat_comp As String
Dim x As Variant

Et voici le code d'une combobox

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub liste1_2_Change()
Dim cell As Range
 
UserForm4.liste1_3.Clear
Sheets("Listes").Columns(22).Clear
With Sheets("Listes")
    For x = 2 To .Range("A65536").End(xlUp).Row
        If .Range("B" & x) = liste1_2.Value Then
             Sheets("Listes").Cells(x, 22).Value = Sheets("Listes").Range("C" & x).Value
        End If
    Next
End With
 
For Each cell In Worksheets("Listes").Range("V2:V300")
    UserForm4.liste1_3 = cell
    If UserForm4.liste1_3.ListIndex = -1 And cell <> "" Then UserForm4.liste1_3.AddItem cell
Next
 
End Sub

Pour les 3 première combos, pas besoin d'utiliser la colonne Z, ensuite effectivement il faudra comparer des string à l'aide de Cstr

Exemple fait autrement à adapter pour les autres

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Option Explicit
 
Private Sub UserForm_Initialize()
Dim LastLig As Long
Dim c As Range
 
With Worksheets("Listes")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For Each c In .Range("A2:A" & LastLig)
        If c <> "" Then
            Me.liste1 = c
            If Me.liste1.ListIndex = -1 Then Me.liste1.AddItem c
        End If
    Next c
End With
Me.liste1.ListIndex = -1
End Sub
 
Private Sub liste1_Change()
Dim LastLig As Long
Dim c As Range
 
Me.liste1_2.Clear
If Me.liste1.ListIndex > -1 Then
    With Worksheets("Listes")
        LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
        For Each c In .Range("A2:A" & LastLig)
            If c.Offset(, 1) <> "" Then
                If CStr(c.Value) = Me.liste1.Value Then
                    Me.liste1_2 = c.Offset(, 1)
                    If Me.liste1_2.ListIndex = -1 Then Me.liste1_2.AddItem c.Offset(, 1)
                End If
            End If
        Next
    End With
End If
Me.liste1_2.ListIndex = -1
End Sub
 
Private Sub liste1_2_Change()
Dim LastLig As Long
Dim c As Range
 
Me.liste1_3.Clear
If Me.liste1_2.ListIndex > -1 Then
    With Worksheets("Listes")
        LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
        For Each c In .Range("B2:B" & LastLig)
            If c.Offset(, 1) <> "" Then
                If CStr(c) = Me.liste1_2.Value Then
                    Me.liste1_3 = c.Offset(, 1)
                    If Me.liste1_3.ListIndex = -1 Then Me.liste1_3.AddItem c.Offset(, 1)
                End If
            End If
        Next
    End With
End If
Me.liste1_3.ListIndex = -1
End Sub

04/08/2014, 13h44
Shini28

Je ne comprends pas ta réponse, je veux dire, mes combobox fonctionnent très bien, sauf quand la cellule comporte des numéros.

Quand j'ai testé avec "blabla", toutes mes combobox sont remplis pour faire la recherche.

La ligne 8 de ton code #3, il fallait faire ce test

Code:

If cstr(.Range("B" & x)) = liste1_2.Value Then

Sinon, pas besoin d'utiliser la colonne temporaire Z, il suffit de tester directement

Je ferai comme ceci à la place de tes codes (tu n'est pas obligé)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
Option Explicit
 
Private Sub UserForm_Initialize()
Dim LastLig As Long
Dim c As Range
 
With Worksheets("Listes")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For Each c In .Range("A2:A" & LastLig)
        'Remplissage de Liste1
        If c <> "" Then
            Me.liste1 = c
            If Me.liste1.ListIndex = -1 Then Me.liste1.AddItem c
        End If
        'Remplissage de Liste2
        If c.Offset(, 3) <> "" Then
            Me.liste2 = c.Offset(, 3)
            If Me.liste2.ListIndex = -1 Then Me.liste2.AddItem c.Offset(, 3)
        End If
 
        'Remplissage de Liste3
        If c.Offset(, 4) <> "" Then
            Me.liste3 = c.Offset(, 4)
            If Me.liste3.ListIndex = -1 Then Me.liste3.AddItem c.Offset(, 4)
        End If
 
        'Remplissage de Liste4
        If c.Offset(, 6) <> "" Then
            Me.liste4 = c.Offset(, 6)
            If Me.liste4.ListIndex = -1 Then Me.liste4.AddItem c.Offset(, 6)
        End If
        'Remplissage de Liste5
        If c.Offset(, 7) <> "" Then
            Me.liste5 = c.Offset(, 7)
            If Me.liste5.ListIndex = -1 Then Me.liste5.AddItem c.Offset(, 7)
        End If
 
    Next c
End With
Me.liste1.ListIndex = -1
Me.liste2.ListIndex = -1
Me.liste3.ListIndex = -1
Me.liste4.ListIndex = -1
Me.liste5.ListIndex = -1
End Sub
 
Private Sub liste1_Change()
Dim LastLig As Long
Dim c As Range
 
Me.liste1_2.Clear
If Me.liste1.ListIndex > -1 Then
    With Worksheets("Listes")
        LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
        For Each c In .Range("A2:A" & LastLig)
            If c.Offset(, 1) <> "" Then
                If CStr(c.Value) = Me.liste1.Value Then
                    Me.liste1_2 = c.Offset(, 1)
                    If Me.liste1_2.ListIndex = -1 Then Me.liste1_2.AddItem c.Offset(, 1)
                End If
            End If
        Next
    End With
End If
Me.liste1_2.ListIndex = -1
End Sub
 
Private Sub liste1_2_Change()
Dim LastLig As Long
Dim c As Range
 
Me.liste1_3.Clear
If Me.liste1_2.ListIndex > -1 Then
    With Worksheets("Listes")
        LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
        For Each c In .Range("B2:B" & LastLig)
            If c.Offset(, 1) <> "" Then
                If CStr(c) = Me.liste1_2.Value Then
                    Me.liste1_3 = c.Offset(, 1)
                    If Me.liste1_3.ListIndex = -1 Then Me.liste1_3.AddItem c.Offset(, 1)
                End If
            End If
        Next
    End With
End If
Me.liste1_3.ListIndex = -1
End Sub
 
Private Sub liste3_Change()
Dim LastLig As Long
Dim c As Range
 
Me.liste3_2.Clear
If Me.liste3.ListIndex > -1 Then
    With Worksheets("Listes")
        LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
        For Each c In .Range("E2:E" & LastLig)
            If c.Offset(, 1) <> "" Then
                If CStr(c.Value) = Me.liste3.Value Then
                    Me.liste3_2 = c.Offset(, 1)
                    If Me.liste3_2.ListIndex = -1 Then Me.liste3_2.AddItem c.Offset(, 1)
                End If
            End If
        Next
    End With
End If
Me.liste3_2.ListIndex = -1
End Sub

PS. Ma proposition pourra facilement être compactée vu la similitude des codes

En utilisant un code générique
La totalité sera

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Option Explicit
 
Private Sub Remplissage(ByVal Lst As ComboBox, ByVal Col As Integer, Optional ByVal Crit As String, Optional ColPere As Integer = 1)
Dim LastLig As Long
Dim c As Range
 
If Crit = "" Then Crit = "*"
With Worksheets("Listes")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For Each c In .Cells(2, Col).Resize(LastLig - 2)
        If c <> "" Then
            If CStr(c.Offset(, ColPere - Col).Value) Like Crit Then
                Lst.Value = c
                If Lst.ListIndex = -1 Then Lst.AddItem c
            End If
        End If
    Next
End With
Lst.ListIndex = -1
End Sub
 
Private Sub UserForm_Initialize()
 
Remplissage Me.liste1, 1
Remplissage Me.liste2, 4
Remplissage Me.liste3, 5
Remplissage Me.liste4, 7
Remplissage Me.liste5, 8
End Sub
 
Private Sub liste1_Change()
 
Me.liste1_2.Clear
If Me.liste1.ListIndex > -1 Then Remplissage Me.liste1_2, 2, Me.liste1.Value, 1
End Sub
 
Private Sub liste1_2_Change()
 
Me.liste1_3.Clear
If Me.liste1_2.ListIndex > -1 Then Remplissage Me.liste1_3, 3, Me.liste1_2.Value, 2
End Sub
 
Private Sub liste3_Change()
 
Me.liste3_2.Clear
If Me.liste3.ListIndex > -1 Then Remplissage Me.liste3_2, 6, Me.liste3.Value, 5
End Sub

05/08/2014, 07h34
Shini28

Bonjour,

Merci beaucoup pour ton aide, mais si je comprends bien ton code, tu ne fais pas de combobox conditionnelles comme moi dans mon code ?

Je ne cherche pas à faire un liste de tout ce qui a dans mes tableaux, mais les informations se trouvant dans les combobox doivent coïncider.

P.S. : j'ai testé ton code et il marche très bien, sauf que tes listes ne sont pas conditionnelles.
05/08/2014, 10h26
mercatog

liste1_2 dépend de liste1
liste1_3 dépend de liste1_2
liste 3_2 dépend de liste3

Sinon tu as le code générique,

Code:

Private Sub Remplissage(ByVal Lst As ComboBox, ByVal Col As Integer, Optional ByVal Crit As String, Optional ColPere As Integer = 1)

tu fais dépendre n'importe quelle combobox Lst remplie à partir de la colonne Col en tenant compte du texte Crit se trouvant dans la colonne ColPere (Oups, j'aurais nommé ColMere, mais bon)
Crit et ColPere sont optionnelles: Si Crit et ColPere sont omis, la combobobx Lst se remplit indépendamment.

Voilà, le code est facilement adaptable.

Si tu as des difficulté, tu n'as qu'à préciser les listes qui dépendent d'autres
05/08/2014, 10h58
Shini28

Je te remercie beaucoup pour ton aide, je vais voir si je continue avec mon code ou avec les morceaux que tu m'as donné.

J'avoue que j'aime pas trop utiliser les codes des autres mais je vais essayer d'adapter le miens :).
05/08/2014, 11h14
mercatog

Citation:

J'avoue que j'aime pas trop utiliser les codes des autres mais je vais essayer d'adapter le miens

:ccool:
Bonne idée, sauf que tu ne perdras rien d'étudier et de comprendre chaque proposition et éventuellement les adapter en cherchant la visibilité, la simplicité et éviter les redondances.

Exemple, au lieu de faire une boucle pour chaque combobobx, il est mieux d'utiliser une seule boucle pour l'ensemble des Combos.

Ensuite, n’oublie pas à la question de maintenance ou d'évolution. Changer quelque chose une seule fois pour l'ensemble vaudra mieux que pour chaque chose changer quelque chose.
05/08/2014, 11h53
Shini28

Je suis tout à fait d'accord avec toi, je vais essayer de tout regrouper en une boucle.

Cependant comme mes combobox sont conditionnelles, je ne peux pas les même dans la même boucle, si ?

Pour répondre à ta question, voici comment les listes fonctionnent :

Liste1 remplit liste1_2 et liste2
Liste1 et Liste 1_2 remplissent liste1_3
Liste2 remplit liste 2_2
Liste2 et liste 2_2 remplissent liste2_3
Liste1 et liste2 remplissent liste3
Liste1 et liste2 remplissent liste4
06/08/2014, 09h48
Shini28

Bonjour,

Mercatog, je te remercie pour ton aide, j'ai réussi à adapter ton code dans mon projet.

Toutes mes combobox fonctionnent, même celles qui ont des chiffres dans les cellules.

Je vais pouvoir passer aux restes :). Maintenant je dois faire un code qui va remplir mon tableau automatiquement, avec les données de tous les fichiers se trouvant dans le dossier.

Mais pour ceux que ça intéresse, je pourrais envoyer mon fichier de recherches, ça peut servir à tout le monde.

Merci encore