Textbox ne marche plus si utilisation de Navigate de Webbrowser

Version imprimable

06/06/2014, 11h31
Thiazung

Textbox ne marche plus si utilisation de Navigate de Webbrowser

Bonjour à tous !

Le problème que je rencontre est peut être courant mais je n'ai rien trouvé le concernant.
J'ai un userform dans Excel 2010, j'y ajoute un textbox et un webbrowser.
Si je laisse ainsi et que je lance mon userform je peux taper ce que je veux dans mon textbox, dont les @ comme je le souhaite.

Si en revanche dans le userform_activate j'ajoute la commande suivante ça change.
WebBrowser1.Navigate "ABOUT:<html><body><center><img src='C:\image.png'></center></body></html>"

Le webbrowser affiche bien mon image mais soudainement mon textbox n'accepte plus les caractères comme @
Je pense que ça bloque tous les caractères nécessitant le AltGr mais je ne comprends pas pourquoi.

Si vous avez une piste, merci de m'aider, je suis légèrement perdu.
J'ai une autre question mais je sens que ça va nécessiter un autre post ^^

T.
10/06/2014, 12h24
Invité

Bonjour,
effectivement j'ai rencontré le même problème je suis preneur si qq1 à une solution . perso j'ai contourné le problème en ajoutant un CommandButton!
Code:

1 2 3 Private Sub CommandButton1_Click() Me.TextBox1 = Me.TextBox1 & "@" End Sub
11/06/2014, 09h20
Invité

Citation:

Envoyé par Thiazung

je suis légèrement perdu.
T.

ça ma l'air plus grave:lefou:
12/06/2014, 18h42
Thiazung

Grave, oui. Car tout est grave ^^

Merci pour ta réponse et cette technique de filou mais je ne vais pas réussir à vendre ça comme solution. Je cherche encore ;)
12/06/2014, 19h00
Marc-L

Bonjour,

et Alt 0 6 4 a été testé ?

Sinon trouver un caractère peu commun comme par exemple § et le remplacer automatiquement par l'arobase …

__________________________________________________________________________________________

Merci de cliquer sur :plusser: pour chaque message ayant aidé puis sur :resolu: pour clore cette discussion …

Merci de votre aide !

Technique utilisée pour l'instant mais qui répond uniquement à la moitié du problème
J'ai bien l'arobase qui s'affiche mais je perds le focus ! Mon "setfocus" ne marche pas...
et il faut que je fasse la même chose pour tous mes textbox, c'est... galère !
Je ne comprends pas le problème réel qu'engendre le webbrowser
Code:

1 2 3 4 5 6 Private Sub Txt_Mail_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger) If KeyAscii = 64 Then Txt_Mail.Value = Txt_Mail.Value & Chr(KeyAscii) Txt_Mail.SetFocus End If End Sub

13/06/2014, 17h16
PMO2017

Bonjour,

Essayez la pièce jointe.

Salut,

Essaye ceci:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private m_EnterObject As Object
 
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox1
End Sub
 
Private Sub UserForm_Activate()
    WebBrowser1.Navigate "ABOUT:<html><body><center><img src='C:\AAA.jpg'></center></body></html>"
End Sub
 
Private Sub WebBrowser1_Enter()
    If Not m_EnterObject Is Nothing Then
        m_EnterObject.SetFocus
        Exit Sub
    End If
    '
    ' Code
    '
End Sub

Pour je ne sais quel raison, le WebBrowser s'attribue le focus, alors tu lui enlève dans l'évènement 'Enter' grâce à la variable de type Object en portée Module.

-----------------------------------------------------------------------------------------------------------------------------------------

Avec d'autre TextBox, c'est la même chose:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private m_EnterObject As Object
 
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox1
End Sub
 
Private Sub TextBox2_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox2
End Sub
 
Private Sub TextBox3_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox3
End Sub
 
Private Sub UserForm_Activate()
    WebBrowser1.Navigate "ABOUT:<html><body><center><img src='C:\AAA.jpg'></center></body></html>"
End Sub
 
Private Sub WebBrowser1_Enter()
    If Not m_EnterObject Is Nothing Then
        m_EnterObject.SetFocus
        Exit Sub
    End If
    '
    ' Code
    '
End Sub

---------------------------------------------

Toute petite rectif (par principe, j'ai mis m_EnterObject à Nothing dans le WebBrowser) au cas où:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private m_EnterObject As Object
 
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox1
End Sub
 
Private Sub TextBox2_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox2
End Sub
 
Private Sub TextBox3_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Set m_EnterObject = Me.TextBox3
End Sub
 
Private Sub UserForm_Activate()
    WebBrowser1.Navigate "ABOUT:<html><body><center><img src='C:\AAA.jpg'></center></body></html>"
End Sub
 
Private Sub WebBrowser1_Enter()
    If Not m_EnterObject Is Nothing Then
        m_EnterObject.SetFocus
        Set m_EnterObject = Nothing
        Exit Sub
    End If
    '
    ' Code
    '
End Sub

16/06/2014, 13h48
Thiazung

Bonjour à tous !!!

Merci pour vos réponses, de bonnes idées pour palier au problème rencontré.

PMO2017 j'ai testé votre solution, ça marche bien mais c'est "moche" car j'ai actuellement 50 textbox, il m'en faut donc le double pour corriger mon problème.
Difficile à gérer sachant qu'en plus j'ai des frame je dois avoir des textbox un peu partout pour appliquer cette méthode. (ça ne marche pas avec un textbox dans une frame et un en dehors)

Nouveau2, solution que je préfère mais qui ne marche pas chez moi ! Il entre bien dans la fonction "_enter" mais ne prends pas en compte le setfocus.
Tout simplement parce que mon fichier est composé de 3 frames. Le webbrowser est directement sur le userform mais les textbox sont dans des frame.
Et le textbox que je teste est en plus dans un objet Page dans l'objet frame.

Pour les personnes rencontrant le même problème mais avec une interface plus simple, j'ai testé dans un formulaire simple, avec un webbrowser et un textbox au même niveau (donc pas de frame ou page ou autre), la solution de Nouveau2 marche très bien.

La centralisation de solutions potentielles dans ce post est intéressant mais ça ne répond pas encore entièrement à mon problème.
Je cherche encore la solution ultime ^^

Merci encore pour les pistes !

T.

Salut,

Si il n'est pas trop tard, j'ai essaye ceci, avec :
3 Frames, 3 TextBox, 2 WebBrowser qui ont cette configuration:
...>WebBrowser1
...>Frame1
...>>>WebBrowser2 (contenu dans Frame1)
...>Frame2
...>>>TextBox1 (contenu dans Frame2)
...>Frame3
...>>>TextBox3 (contenu dans Frame3)
...>TextBox2

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Option Explicit
 
Private Enum fmShiftState
    fmShiftMask = 1 ' 001
    fmCtrlMask = 2  ' 010
    fmAltMask = 4   ' 100
End Enum
 
Private m_SenderObject As Object
 
 
' WebBrowser 2 est contenu dans Frame1
Private Sub UserForm_Activate()
    Me.WebBrowser1.Navigate "C:\AAA.jpg"
    Me.WebBrowser2.Navigate "C:\AAA.jpg"
End Sub
 
 
'Ici, Frame2 contient TextBox1
Private Sub Frame2_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    Cancel = CancelFunction
End Sub
 
    Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
        Cancel = CancelFunction
    End Sub
    Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
        Set SenderObject(Shift) = Me.TextBox1
    End Sub
    Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
        Debug.Print "TextBox1_KeyPress" & " : " & Chr$(KeyAscii)
    End Sub
 
 
Private Sub TextBox2_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    Cancel = CancelFunction
End Sub
Private Sub TextBox2_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Set SenderObject(Shift) = Me.TextBox2
End Sub
Private Sub TextBox2_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Debug.Print "TextBox2_KeyPress" & " : " & Chr$(KeyAscii)
End Sub
 
 
'Ici, Frame2 contient TextBox1
Private Sub Frame3_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    Cancel = CancelFunction
End Sub
 
    Private Sub TextBox3_Exit(ByVal Cancel As MSForms.ReturnBoolean)
        Cancel = CancelFunction
    End Sub
    Private Sub TextBox3_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
        Set SenderObject(Shift) = Me.TextBox3
    End Sub
    Private Sub TextBox3_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
        Debug.Print "TextBox3_KeyPress" & " : " & Chr$(KeyAscii)
    End Sub
 
 
 
' ----------------------------------------
'          Fonctions, propriétés
' ----------------------------------------
Private Function CancelFunction() As Boolean
    If Not m_SenderObject Is Nothing Then
        CancelFunction = True
        Set m_SenderObject = Nothing
    End If
End Function
 
Private Property Set SenderObject(ByVal Shift As Integer, Obj As Object)
    If Shift = (fmCtrlMask Or fmAltMask) Then
        Set m_SenderObject = Obj
    End If
End Property

ça devrai marcher je pense.

---------------------------------

Nota : Un module de classe (que je ne ferais pas) qui regrouperait toutes les TexBox et tous les Conteneurs permettrai de simplifier cette tâche répétitive avec seulement quelques Sub indépendamment du nombre de contrôles dans l'UserForm.......... en attendant mieux.

11/07/2014, 09h59
Thiazung

Merci pour cette réponse que je n'avais pas vu !

Je viens de tester, ça ne fonctionne pas au premier abord, mais je vais déjà tester dans formulaire simple avant d'intégrer dans mon application actuelle.

Quand je vois la galère que ça peut être, j'ai quasi l'impression que ce serait plus simple de me poser la question dans l'autre sens : comment remplacer mon webbrowser qui est la source du problème ! Mais repartir sur la grande question "comment intégrer un gif dans un formulaire excel" est un autre plan galère !

@rdurupt : si tu as trouvé mieux comme solution n'hésites pas ^^

Thia toujours en chasse de la solution ultime :)