[VBA-E]Aide sur les ComboBox

Version imprimable

10/05/2006, 20h37
Alex_Kidd

[VBA-E]Aide sur les ComboBox

Voilà mon problème : je souhaite initialiser une combo box avec les données issues d'une colonne . D'après la documentation sous Excel , je dois utiliser la synthaxe :
combobox1.additem "Valeur de la cellule"

Ce que je ne sais pas gérer , c'est si il y a des doublons dans ma colonne , je souhaiterais ajouter seulement une valeur et que toutes les valeurs dans ma combo box soit classé de manière alphabétique -> en gros , avoir le mettre principe qu'un filtre automatique.

1.Existe-t-il un moyen de récupérer le filtre automatique (combo box) contenu dans la 1ere ligne de ma colonne dans un userform ??

2. Sinon comment faire simplement ??

J'ai lu sur un forum qu'il fallait créer une liste où je stocke toutes les données de ma colonne puisque je fasse un tri avant de supprimer les doublons et enfin d'initialiser ma combo box en lisant cette liste.
:aie: là je suis dépassé ...
10/05/2006, 21h06
jmfmarques

Déjà et avant d'aller plus loin : une combobox est affublée d'unre propriété sorted (tri).
As-tu commencé à lire l'aide en ligne ?
on viendra au reste ensuite !
10/05/2006, 21h11
SfJ5Rpw8

Alex_Kidd , commence par modifier ton titre en le "Taggant" [VBA-E] (je suppose) cela nous évitera de patir dans une mauvaise direction...
10/05/2006, 21h14
ThierryAIM

Citation:

Envoyé par bbil

Alex_Kidd , commence par modifier ton titre en le "Taggant" [VBA-E] (je suppose) cela nous évitera de patir dans une mauvaise direction...

Fait pour lui, parce que si on attend .... :roll:

tiens un peu de code en VBA excel à adapter ... (manque surement aussi des tests de cas de défauts à rajouter...)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Private Sub UserForm_Activate()
 Dim rS As Range 'Donnee Source
 Dim rF As Range 'Donnee Filtrée
 'Définir ici la zone de donnée source
 Set rS = Sheets("mafeuille").Range("A1").CurrentRegion
 'Définition de Rf.. sur la même feuille que zone source
 Set rF = rS.Parent.Range("E1") 'Colonne ou seront copier les donnée filtrée..
 rF.EntireColumn.ClearContents ' Efface la colonne filtrée
 rS.AdvancedFilter Action:=xlFilterCopy, CopyToRange:=rF, Unique:=True 'Copie des donnée unique...
'redefini la Zone rf en y incorporant toutes les donneée
Set rF = rF.CurrentRegion
rF.Sort Key1:=rF.Columns(1), Order1:=xlAscending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
 
'Affecte la zone filtrée au combobox
ComboBox1.RowSource = rF.Address
 
End Sub

bonsoir

ci joint une autre possiblité sans trier dans la feuille

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Option Explicit
Option Base 1
 
Private Sub UserForm_Initialize()
Dim Cell As Range
Dim Tableau()
Dim i As Integer, x As Integer, k As Integer
Dim ValTemp As Variant
 
'remplissage Tableau
For Each Cell In Range("A1:A10")'adapter la  plage de cellules
    i = i + 1
    ReDim Preserve Tableau(i)
    Tableau(i) = Cell
Next Cell
 
'tri par ordre croissant
For i = 1 To UBound(Tableau)
    x = i
 
    For k = x + 1 To UBound(Tableau)
    If Tableau(k) <= Tableau(x) Then x = k
    Next k
 
    If i <> x Then
    ValTemp = Tableau(x): Tableau(x) = Tableau(i): Tableau(i) = ValTemp
    End If
Next i
 
'alimentation Tableau sans doublon
For i = 1 To UBound(Tableau)
    ComboBox1 = Tableau(i)
    If ComboBox1.ListIndex = -1 Then ComboBox1.AddItem Tableau(i)
Next i
End Sub

bonne soiree
michel

11/05/2006, 17h47
Alex_Kidd

Merci pour votre aide