Programme produit de deux matrices

Version imprimable

Bonsoir à tous,
J'ai quelques soucis pour réaliser un programme qui doit permettre de réaliser le produit de deux matrices. Si j'ai bien réussi à déclarer celles-ci et à les afficher correctement dans le tableau excel je sèche sur la manière de procéder pour réaliser le produit en lui même. Voici mon code que j'ai réalisé jusqu'ici :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 Option Explicit Option Base 1 Sub exo2() Dim matrice1() As Double Dim matrice2() As Double Dim matrice3() As Double Dim i, j, k As Integer Dim a, b As Integer Dim c, d As Integer i = InputBox("Entrer le nombre de lignes de la première matrice") j = InputBox("Entrer le nombre de colonnes de la première matrice (qui sera également le nombre de lignes de la seconde matrice).") k = InputBox("Entrer me nombres de colonnes de la seconde matrice") ReDim matrice1(i, j) ReDim matrice2(j, k) ReDim matrice3(i, k) For a = 1 To i For b = 1 To j matrice1(i, j) = InputBox("Entrer le coefficient de la colonne numéro " & b & " de la ligne " & a & " de la matrice 1.") Range("H2").Offset(a - 1, b - 1) = matrice1(i, j) Next b Next a For c = 1 To j For d = 1 To k matrice2(j, k) = InputBox("Entrer le coefficient de la colonne numéro " & d & " de la ligne " & c & " de la matrice 2.") Range("H2").Offset(c - 1, j + d) = matrice2(j, k) Next d Next c End Sub
Matrice3(i,k) désignant la matrice résultante du produit des deux matrices.

Merci d'avance pour votre aide.:)

Tu as sur Excel PRODUITMAT

Sinon, je crois que tu as un exercice pédagogique, ci-joint ma réponse

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
Option Base 1
 
 
Sub exo2()
Dim Matrice1() As Double
Dim Matrice2() As Double
Dim Matrice3() As Double
Dim S As Double
Dim i As Integer, j As Integer, k As Integer
Dim a As Integer, b As Integer
Dim c As Integer, d As Integer
 
i = InputBox("Entrer le nombre de lignes de la première matrice")
j = InputBox("Entrer le nombre de colonnes de la première matrice (qui sera également le nombre de lignes de la seconde matrice).")
k = InputBox("Entrer me nombres de colonnes de la seconde matrice")
 
ReDim Matrice1(i, j)
For a = 1 To i
    For b = 1 To j
        Matrice1(a, b) = InputBox("Entrer le coefficient de la colonne numéro " & b & " de la ligne " & a & " de la matrice 1.")
        Range("H2").Offset(a - 1, b - 1) = Matrice1(a, b)
    Next b
Next a
 
ReDim Matrice2(j, k)
For c = 1 To j
    For d = 1 To k
        Matrice2(c, d) = InputBox("Entrer le coefficient de la colonne numéro " & d & " de la ligne " & c & " de la matrice 2.")
        Range("H10").Offset(c - 1, d - 1) = Matrice2(c, d)
    Next d
Next c
 
ReDim Matrice3(i, k)
For a = 1 To i
    For b = 1 To k
        For c = 1 To j
            S = S + Matrice1(a, c) * Matrice2(c, b)
        Next c
        Matrice3(a, b) = S
        S = 0
    Next b
Next a
Range("H18").Resize(i, k) = Matrice3
End Sub

01/06/2014, 13h23
onelev

Bonjour mercatog,

Effectivement c'est un exercice pédagogique, la fonction PRODUITMAT d'excel ne s'applique donc pas à cet exercice.

Merci beaucoup pour le programme, il est totalement fonctionnel. :)
Je tournais autour du pot pour la partie de la multiplication des matrices en elles-mêmes, c'est très astucieux de dimensionner une nouvelle variable et de l'initialiser à la fin de chaque boucle de la variable c, je n'y aurais pas pensé moi-même !

Merci encore :)