[vbs] Ouvrire un fichier en utilisant une variable ex: %ProgramFiles%

Version imprimable

19/04/2014, 13h24
positrons

[vbs] Ouvrire un fichier en utilisant une variable ex: %ProgramFiles%

Bonjour a tous,

Je revien encourt une foi ver vous en espérant obtenir de l'aide et Merci D'avance,
Je veux ouvrire un fichier en utilisant une variable ex: %ProgramFiles% en vbs :roll:
19/04/2014, 14h08
hackoofr

Recherche %ProgramFiles%

:recherch: sur le forum de Vbscript avec ce mot clé ==> %ProgramFiles% ,tu trouvera sûrement ton bonheur :mouarf:
Sinon, postes ton code source et :tagcode: et poses tes questions :zoubi:
20/04/2014, 01h41
positrons

[vbs] Ouvrire un fichier en utilisant une variable ex: %ProgramFiles%

Bonjour,

J'ai trouvé 2 solution sur 10 page que j'avais fouiller mais aucune ne marche pour mon système ( Windows 7-64 )

Solution 1: ici
Solution 2: ici

Cordialement.
20/04/2014, 01h45
hackoofr

:salut:
Alors dans ce cas postez votre code et :tagcode:

Un Exemple pour exécuter FireFox,Winrar et FileZilla

:salut:
Un Exemple pour exécuter FireFox,Winrar et FileZilla :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Explicit 
Dim FireFox,Winrar,FileZilla
FireFox = "CD /D "& DblQuote("%Programfiles%\Mozilla Firefox\") &" & Start FireFox.exe"
Winrar = "CD /D "& DblQuote("%Programfiles%\WinRAR\") &" & Start Winrar.exe"
FileZilla = "CD /D "& DblQuote("%Programfiles%\FileZilla FTP Client\") &" & Start filezilla.exe"
Call Executer(FireFox,0) 'Sans affichage de la console
Call Executer(Winrar,1) 'Avec affichage de la console
Call Executer(FileZilla,0) 'Sans affichage de la console
'****************************************************************************************************
Function Executer(StrCmd,Console)
    Dim ws,MyCmd,Resultat
    Set ws = CreateObject("wscript.Shell")
'La valeur 0 pour cacher la console MS-DOS
    If Console = 0 Then
        MyCmd = "CMD /C " & StrCmd & ""
        Resultat = ws.run(MyCmd,Console,True)
        If Resultat = 0 Then
        Else
            MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
        End If
    End If
'La valeur 1 pour montrer la console MS-DOS
    If Console = 1 Then
        MyCmd = "CMD /K " & StrCmd & ""
        Resultat = ws.run(MyCmd,Console,False)
        If Resultat = 0 Then
        Else
            MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
        End If
    End If
    Executer = Resultat
End Function
'****************************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'****************************************************************************************************

20/04/2014, 03h06
positrons

[vbs] Ouvrire un fichier en utilisant une variable ex: %ProgramFiles%

Salut,

Merci pour ta réponse la méthode cmd je connais déjà je cherche une façon 100% vbs

100% vbs

Citation:

Envoyé par positrons

Je cherche une façon 100% vbs

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Option Explicit
Dim fso,ws,DossierProgramfiles,Winrar,FileZilla,FireFox
Set fso = CreateObject("Scripting.FileSystemObject")
Set ws = CreateObject("WScript.Shell")
DossierProgramfiles = ws.ExpandEnvironmentStrings("%PROGRAMFILES%")
Winrar = DblQuote(DossierProgramfiles & "\Winrar\Winrar.exe")
If fso.FileExists(DossierProgramfiles & "\Winrar\Winrar.exe") Then
    MsgBox Winrar,Vbinformation,Winrar
    ws.run Winrar
Else
    MsgBox "Le fichier " & Winrar & " n'existe pas",VbCritical,"Le fichier " & Winrar & " n'existe pas"
End If
FileZilla = DblQuote(DossierProgramfiles & "\FileZilla FTP Client\filezilla.exe")
If fso.FileExists(DossierProgramfiles & "\FileZilla FTP Client\filezilla.exe") Then
    MsgBox FileZilla,Vbinformation,FileZilla
    Ws.run FileZilla
Else
    MsgBox "Le fichier " & FileZilla & " n'existe pas",VbCritical,"Le fichier " & FileZilla & " n'existe pas"
End If
FireFox = DblQuote(DossierProgramfiles & "\Mozilla Firefox\FireFox.exe")
If fso.FileExists(DossierProgramfiles & "\Mozilla Firefox\FireFox.exe") Then
    MsgBox FireFox,Vbinformation,FireFox
    ws.run FireFox
Else
    MsgBox "Le fichier " & FireFox & " n'existe pas",VbCritical,"Le fichier " & FireFox & " n'existe pas"
End If
'****************************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'****************************************************************************************************

21/04/2014, 07h54
positrons

[vbs] Ouvrire un fichier en utilisant une variable ex: %ProgramFiles%

Merci Hackoofr,

C'est pile ce que je cherche Merci Pour L'aide.