Sélectionner plusieurs colonnes d'un tableau

Version imprimable

28/03/2014, 23h07
stargui30

Sélectionner plusieurs colonnes d'un tableau
Bonjour,
Je n'arrive pas à sélectionner plusieurs colonnes d'un tableau "Listobject". La formule suivante fonctionne pour sélectionner 1 seule colonne mais je ne sais pas comment en sélectionner plusieurs avec le même code.
Code:

1 2 NomTableau = "Tableau41" Sheets("Feuil1").ListObjects(NomTableau).Range.Columns(3).Select
Comme la variable NomTableau Change plusieurs fois dans le code, je dois utiliser une formule du genre. Quelqu'un peut m'aider s.v.p? Je suis sûr que je ne suis pas loin mais je n'arrive pas à trouver:(

Salut et bienvenu

Voila un exemple

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub teste()
Dim CellToSelect As Range
Dim TheCell As Range
Dim NomTableau As String
 
    NomTableau = "Tableau41"
 
    With ThisWorkbook.Sheets("Feuil1").ListObjects(NomTableau).Range
        'Tu crées la zone dont tu as besoin
        Set CellToSelect = Union(.Columns(3), .Columns(1))
 
        'Si tu as besoin d'en ajouter
        Set CellToSelect = Union(CellToSelect, .Columns(8))
 
        'Si tu as besoin de les faire apparaitre en surbrillance
        CellToSelect.Select 'Inutil pour travailler avec les cellule pointées
 
    End With
 
    'Si tu ne veux pas prendre en compte les entêtes de tableau tu fais comme ça
    With ThisWorkbook.Sheets("Feuil1").ListObjects(NomTableau).DataBodyRange
        Set CellToSelect = Union(.Columns(3), .Columns(1))
    End With
 
    'Si tu souhaites uniquement boucler sur ces cellules, unitil de faire un select avant, tu peux travailler directement en pointant les cellules
    For Each TheCell In CellToSelect
        If TheCell.Value <> "" Then TheCell.Interior.ColorIndex = 6
    Next
 
End Sub

++
Qwaz

PS: Lorsque tu mets un code dans ton message, merci d'utiliser la balise code. Pour ajouter ces balise, il faut sélectionner le code et utiliser le bouton # dans le menu de l'éditeur.

29/03/2014, 14h08
stargui30

Ah! Merci Qwazerty:mrgreen:

J'ai cherché longtemps et je ne trouvait rien! Très apprécié!