Rechercher un fichier et afficher le chemin dans variable string

Bonjour! Je cherche à pouvoir rechercher un fichier en navigant à travers une fenêtre et afficher le chemin du fichier ainsi que l'extension du fichier dans une variable type string. Pouvez-vous m'aider je n'ai pas trouvé d'exemple concret avec des explications (car je suis débutant)? Merci d'avance!

Personne pour m'aider?

bonjour,
pour quelle version de windows ?

Bonjour,

Je suis sur Windows 7!

Fonction BrowseForFile()

:salut:
Avec cette petite fonction BrowseForFile(), vous pouvez atteindre votre but :zoubi: :mouarf:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Option Explicit
Dim Copyright,MonFichier
Copyright = " © Florian68 © 2014"
MonFichier = BrowseForFile() 'La variable MonFichier est affecté par la fonction BrowseForFile qui retourne le chemin du fichier sélectionné
MsgBox "Le chemin du fichier sélectionné est : " & DblQuote(MonFichier),64,"Afficher le chemin du fichier " & Copyright
'****************************************************************************************************
Function BrowseForFile()
 Dim shell : Set shell = CreateObject("WScript.Shell")
 Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")
 Dim tempFolder : Set tempFolder = fso.GetSpecialFolder(2)
 Dim tempName : tempName = fso.GetTempName()
 Dim tempFile : Set tempFile = tempFolder.CreateTextFile(tempName & ".hta")
 tempFile.Write _
 "<html>" & _
 "    <head>" & _
 "        <title>Browse</title>" & _
 "    </head>" & _
 "    <body>" & _
 "        <input type='file' id='f'>" & _
 "        <script type='text/javascript'>" & _
 "            var f = document.getElementById('f');" & _
 "            f.click();" & _
 "            var shell = new ActiveXObject('WScript.Shell');" & _
 "            shell.RegWrite('HKEY_CURRENT_USER\\Volatile Environment\\MsgResp" & tempName & _
 "', f.value);" & _
 "            window.close();" & _
 "        </script>" & _
 "    </body>" & _
 "</html>"
 tempFile.Close
 shell.Run tempFolder & "\" & tempName & ".hta",0,True
 BrowseForFile = shell.RegRead("HKEY_CURRENT_USER\Volatile Environment\MsgResp" & tempName)
 shell.RegDelete "HKEY_CURRENT_USER\Volatile Environment\MsgResp" & tempName
 fso.DeleteFile(tempFolder & "\" & tempName & ".hta")
 End Function
'****************************************************************************************************
Function DblQuote(Str)
	DblQuote = Chr(34) & Str & Chr(34)
End Function
'**********************************************************************************************

Un autre exemple qui utilise cette même fonction ==> [VBS] Upload2FTP.vbs

Citation:

rechercher un fichier en navigant à travers une fenêtre et afficher le chemin du fichier....

Fenêtre : tu veux dire dossier !?
naviguant : tu veux dire en regardant cette fenêtre(utilisant souris ou clavier) ou par le code !?

Super merci hackoofr! C'est exactement ce que je souhaitais faire!

Citation:

Envoyé par Florian68

Super merci hackoofr! C'est exactement ce que je souhaitais faire!

:salut:
Oui c'est Super cette astuce, mais elle devient plus super quand je vois ce +1 :plusser: car cette dernière marche sur tous les systèmes windows à priori :mouarf:
@+ et Bonne Chance à vous :pc: