Récupérer le résultat d'une variable dans un tableau (VBA)

Version imprimable

1 pièce(s) jointe(s)

Bonjour,
Je débute en VBA

Merci d'avance pour votre aide

Ma macro me permet de rechercher et récupérer une valeur dans un classeur entier. Elle indique le lieu ou se trouve cette valeur. (par exemple "feuil1 cellule A2")
Les résultats sont affichés dans une cellule A2.
Cependant je souhaiterai si possible d'afficher ses résultats dans un tableau.
Avec dans la 1ere colonne le nom de la feuille et la deuxième le nom de la cellule

Voici mon code (la valeur recherché est "non terminés")

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Macro1()
'
' Macro1 Macro
'
Dim MaRecherche
Dim Ws As Worksheet
Dim c As Range
Dim Message As String, firstAddress As String
    MaRecherche = "non terminés"
    Message = "Voici les travaux " & MaRecherche & " a réaliser :" & Chr(10)
    For Each Ws In Worksheets
        With Ws
            Set c = .Columns("A:Z").Find(What:=MaRecherche, LookIn:=xlValues, LookAt:=xlPart)
            If Not c Is Nothing Then
                firstAddress = c.Address
                Do
                    Message = Message & "- dans la feuille " & Ws.Name & ", cellule " & c.Address & Chr(10)
                    Set c = .Columns("A:Z").FindNext(c)
                Loop While Not c Is Nothing And c.Address <> firstAddress
            End If
        End With
    Next Ws
    Range("A2").Select
Selection.Value = Message

Salut et bienvenu

Je réponds sur ce fil, il serait bien que tu supprimes tes autres messages sur le même sujet.

Essai en modifiant de la sorte

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Do
    'On pointe la feuille où seront notés les résultats
    With ThisWorkbook.Sheets("Feuil1") 'Tu adaptes en fonction de la feuille où tu souhaites voir les résultats s'afficher
        'On pointe la 1ère cellule vide
        With .Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0)
            'On note le nom de la feuille où se trouve le résultat
            .Value = WS.Name
            'Et la cellule dans laquelle il est contenu
            .Offset(0, 1).Value = c.Address
        End With
    End With
    Set c = .Columns("A:Z").FindNext(c)
Loop While Not c Is Nothing And c.Address <> firstAddress

++
Qwaz

16/03/2014, 17h45
fredplusvar

suite

Merci pour ton aide, cependant je vois pas l'endroit ou je dois mettre ce code précisément

désolé mais je suis un novice

Salut

Désolé.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub Macro1()
'
' Macro1 Macro
'
Dim MaRecherche
Dim Ws As Worksheet
Dim c As Range
Dim firstAddress As String
 
    MaRecherche = "non terminés"
    For Each Ws In Worksheets
        With Ws
            Set c = .Columns("A:Z").Find(What:=MaRecherche, LookIn:=xlValues, LookAt:=xlPart)
            If Not c Is Nothing Then
                firstAddress = c.Address
                Do
                    'On pointe la feuille où seront notés les résultats
                    With ThisWorkbook.Sheets("Feuil1") 'Tu adaptes en fonction de la feuille où tu souhaites voir les résultats s'afficher
                        'On pointe la 1ère cellule vide
                        With .Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0)
                            'On note le nom de la feuille où se trouve le résultat
                            .Value = Ws.Name
                            'Et la cellule dans laquelle il est contenu
                            .Offset(0, 1).Value = c.Address
                        End With
                    End With
                    Set c = .Columns("A:Z").FindNext(c)
                Loop While Not c Is Nothing And c.Address <> firstAddress
            End If
        End With
    Next Ws
 
End Sub

++
Qwaz

16/03/2014, 18h25
fredplusvar

merci

Bravo
Je suis impressionné !!!

Merci beaucoup et à une autre fois :)