Extraction du prénom et du nom parfois sans le prénom

Bonjour à tous,
Mes cellules contiennent 1 ou 2 informations :

1. - Le prénom toujours en minuscule sauf la première lettre (exemples de formulation : Patrice ou Jean-Paul).
2. - Le nom toujours en majuscule (exemples de formulation : DUBOIS ou MARTIN-DURAND ou DE LAMAISON).

Ce qui pose problème est que le prénom n’est pas toujours notifié.
Certaines cellules ne contiennent donc que le nom toujours en majuscule (DUBOIS ou MARTIN-DURAND ou DE LAMAISON.
Comment extraire le prénom et le nom dans 2 cellules distinctes en tenant compte de cette difficulté (absence de prénom possible) ?
Idée : Dans le cas où dans les cellules sans prénom figurerait un message d'erreur du type #N/A ou #VALEUR!, il serait peut-être intéressant de remplacer ce message d'erreur par un tiret ("-").
Merci pour votre précieuse aide.
Bonne soirée à tous.
bolide7

Bonsoir,
Proposition pour le Prénom et NOM en colonne A
Prénom

Code:

---

=SIERREUR(GAUCHE($A2;TROUVE(" ";$A2));"")

---

Pour le nom

Code:

---

=SIERREUR(MAJUSCULE(DROITE($A2;NBCAR($A2)-TROUVE(" ";$A2)));MAJUSCULE(DROITE($A2;NBCAR($A2))))

---

Formules à mettre sur la même ligne que les deux Prénom et NOM de la cellule en Ax

Bonsoir rjamin,
Pour le prénom, ta formule fonctionne bien, sauf lorsqu’il n’y a pas de prénom ET que le nom est à particule (comme avec DE LAMAISON). EXCEL prend la particule (qu’elle soit écrite en minuscule ou en majuscule) pour le prénom.
Pour le nom, ta formule fonctionne bien, sauf lorsqu’il n’y a pas de prénom ET que le nom est à particule. EXCEL ignore la particule et ne figure que le la deuxième partie du nom.
Aucun soucis avec un nom simple sans le prénom notifié (la case du prénom est vide sans message d’erreur).
Merci beaucoup pour avoir pris le temps de te pencher sur mon problème épineux.
Très bonne nuit.
bolide7

J'ai ajouté une vérification de casse sur le deuxième caractère, traité comme nom ou prénom selon le cas. Ca fonctionne bien dans les cas évoqués, mais je n'ai pas traité si les prénoms composés étaient séparés par un espace.

Pour le prénom

Code:

---

=SI(EXACT(STXT(A2;2;1);MAJUSCULE(STXT(A2;2;1)));"";SIERREUR(GAUCHE(A2;TROUVE(" ";A2));A2))

---

Pour le nom

Code:

---

=SIERREUR(DROITE(A2;NBCAR(A2)-SI(EXACT(STXT(A2;2;2);MAJUSCULE(STXT(A2;2;2)));0;TROUVE(" ";A2)));DROITE(A2;NBCAR(A2)))

---

Bonsoir Lux (le noob)
Je n’ai pas d’espace dans les prénoms composés.
En conséquence, tes 2 formules fonctionnent très bien et répondent exactement à mes demandes et contraintes.
De mon côté, après de nombreux tests, j’ai trouvé également trouvé 2 formules qui répondent à mes nombreuses exigences :
Pour le prénom :

Code:

---

=SI(EXACT(MAJUSCULE(A1);A1);"-";GAUCHE(A1;TROUVE(" ";A1)))

---

Pour le nom :

Code:

---

=SI(EXACT(MAJUSCULE(A1);A1);A1;DROITE(A1;NBCAR(A1)-TROUVE(" ";A1))

---

Une seule petite différence avec toi : En cas d’absence de prénom, EXCEL place un tiret dans la cellule « Prénom ».
N’étant pas un grand spécialiste d’EXCEL, il doit certainement y avoir plus simple.
Je suis d’autant plus content de moi, que ces formules ne sont pas un simple copier coller de la toile.
Grand merci à vous deux.
Très bonne soirée.
bolide7