Coller des cellules filtrées a partir d'une cellule

Version imprimable

17/01/2014, 11h22
g.dupin.gemma

1 pièce(s) jointe(s)

Coller des cellules filtrées a partir d'une cellule

Bonjour à tous,

Etant débutant dans la programmation VBA j'ai des difficultés pour développer un fichier permettant a partir de la cellule "S4" de la feuille "Inducateur_Qualite" de :
- Filtrer dans la colonne "G" de la feuille "Table" toute les lignes correspondant à mon critère de recherche (cellule "S4" de la feuille "Inducateur_Qualite")
- Copier les colonnes filtrées G, E et H de la feuille "Table"
- Coller les valeurs correspondantes dans la première cellule vide du tableau dans la feuille "Indicateur_Qualite"

J'ai réalisé de nombreuses recherches pour développer ces fonctions mais sans succès.

Cous pourrez trouver ci-joint le fichier Excel.

Merci par avance de l'aide que vous pourrez m'apporter

Cordialement,
17/01/2014, 11h30
Philippe Tulliez

Bonjour,
Si tu veux exporter des données vers une autre feuille suivant des critères, je te conseille l'utilisation des filtres élaborés d'excel.
A lire Les filtres avancés ou élaborés dans Excel
17/01/2014, 11h34
Kimy_Ire

Bonjour g.dupin.gemma,

Il me semble que l'éditeur de macro est très approprié dans ton cas. As-tu essayé ? :)

Cordialement,
Kimy
17/01/2014, 11h37
g.dupin.gemma

Bonjour,

J'ai bien identifié que je pouvais utiliser l'approche des filtres élaborés toutefois j'ai du mal à la mettre en œuvre avec VBA malgré l'utilisation de l'outil enregistrement de macro.
En effet, j'arrive à faire mon filtre mais j'ai quelques difficultés pour copier dans ma feuille "indicateur qualité"

Cordialement,
17/01/2014, 11h39
Philippe Tulliez

Bonjour,
D'où le lien que je t'ai référencé et que je te conseille de lire. Il y a un fichier à télécharger avec exemple en VBA
17/01/2014, 11h50
g.dupin.gemma

Bonjour,

Je travail dessus en essayant de comprendre le fonctionnement.

Cordialement,

Bonjour,

Voici un exemple commenté. Je n'ai copié que la colonne G; à toi de compléter.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub Copie()
    Dim Plage As Range, Sh As Worksheet, Ligne As Long
    Set Sh = Sheets("Indicateur_Qualite")
    With Sheets("Table")
        'définition de la plage source
        Set Plage = .Range(.[A3], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 64)
        .AutoFilterMode = False
        'filtre sur la colonne G
        Plage.AutoFilter 7, Sh.[S4]
        'élimination de la ligne des entêtes
        Set Plage = Plage.Offset(1).Resize(Plage.Rows.Count - 1)
        's'il; y a des lignes filtrées
        If Application.Subtotal(103, Plage) > 0 Then
            ' détermination de la ligne où écrire
            Ligne = Sh.Cells(Rows.Count, 1).End(xlUp).Row + 1
            If Ligne < 5 Then Ligne = 5
            'sélection de la colonne G
            Set Plage = Plage.Resize(, 1).Offset(, 6)
            Plage.Copy
            Sh.Cells(Ligne, 1).PasteSpecial xlPasteValues
            'sélection de la colonne E
        End If
        .AutoFilterMode = False
    End With
End Sub

Merci beaucoup, je vais poursuivre le développement avec ces données.

Toutefois quand j'applique le code pour les autres colonnes :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
 
 
Sub Copie()
    Dim Plage As Range, Sh As Worksheet, Ligne As Long
    Set Sh = Sheets("Indicateur_Qualite")
    With Sheets("Table")
        'définition de la plage source
        Set Plage = .Range(.[A3], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 64)
        .AutoFilterMode = False
        'filtre sur la colonne G
        Plage.AutoFilter 7, Sh.[S4]
        'élimination de la ligne des entêtes
        Set Plage = Plage.Offset(1).Resize(Plage.Rows.Count - 1)
        's'il; y a des lignes filtrées
        If Application.Subtotal(103, Plage) > 0 Then
            ' détermination de la ligne où écrire
            Ligne = Sh.Cells(Rows.Count, 1).End(xlUp).Row + 1
            If Ligne < 5 Then Ligne = 5
            'sélection de la colonne G
            Set Plage = Plage.Resize(, 1).Offset(, 6)
            Plage.Copy
            Sh.Cells(Ligne, 1).PasteSpecial xlPasteValues
            'sélection de la colonne E
            Set Plage = Plage.Resize(, 1).Offset(, 4)
            Plage.Copy
            Sh.Cells(Ligne, 2).PasteSpecial xlPasteValues
            'sélection de la colonne H
            Set Plage = Plage.Resize(, 1).Offset(, 7)
            Plage.Copy
            Sh.Cells(Ligne, 3).PasteSpecial xlPasteValues
                    End If
        .AutoFilterMode = False
    End With
End Sub

Mais cela ne me met pas la valeur correspondant, pourriez vous m'indiquer si je retourne bien les valeurs des colonnes correspondantes.

Merci d'avance,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub Copie()
    Dim Plage As Range, Sh As Worksheet, Ligne As Long
    Set Sh = Sheets("Indicateur_Qualite")
    With Sheets("Table")
        'définition de la plage source
        Set Plage = .Range(.[A3], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 64)
        .AutoFilterMode = False
        'filtre sur la colonne G
        Plage.AutoFilter 7, Sh.[S4]
        'élimination de la ligne des entêtes
        Set Plage = Plage.Offset(1).Resize(Plage.Rows.Count - 1)
        's'il n'y a des lignes filtrées
        If Application.Subtotal(103, Plage) > 0 Then
            ' détermination de la ligne où écrire
            Ligne = Sh.Cells(Rows.Count, 1).End(xlUp).Row + 1
            If Ligne < 5 Then Ligne = 5
            'sélection de la colonne G
            Set Plage = Plage.Resize(, 1).Offset(, 6)
            Plage.Copy
            Sh.Cells(Ligne, 1).PasteSpecial xlPasteValues
            'sélection de la colonne E
            Set Plage = Plage.Offset(, -2)
            Plage.Copy
            Sh.Cells(Ligne, 2).PasteSpecial xlPasteValues
            'sélection de la colonne H
            Set Plage = Plage.Offset(, 3)
            Plage.Copy
            Sh.Cells(Ligne, 3).PasteSpecial xlPasteValues
        End If
        .AutoFilterMode = False
    End With
End Sub

Code:

Set Plage = Plage.Resize(, 1)

Réduit la plage à la colonne A.

Code:

Set Plage = Plage.Resize(, 1).Offset(, 6)

décale de 6 par rapport à A (donc G).

Code:

Set Plage = Plage.Offset(, -2)

décale de 2 vers la gauche donc il s'agit de la colonne E.

Code:

Set Plage = Plage.Offset(, 3)

décale de 3 vers la droite donc il s'agit de la colonne H.

17/01/2014, 14h51
g.dupin.gemma

Parfait !!! Tout fonctionne je vais voir les étapes suivantes !