plannificateur windows 7

Version imprimable

19/12/2013, 14h37
ctrl32

plannificateur windows 7
Bonjour,
tout d'abord, je n'y connais absolument rien en script, voilà qui est dit.
j'ai un besoin, lancer un .bat toute les 5 mn
via le planificateur d'évènement Win 7, le bat se lance, mais en fait, rien ne se passe. (aucune idée sur la raison, c'est un fait, seulement, si je lance à la main ce .bat, il fonctionne.)
actuellement j'utilise le .vbs ci dessous qui me permet de lancer le .bat sans avoir de fenêtre dos
Code:

1 2 3 4 DIM oWsh, commande Set oWsh = WScript.CreateObject("WScript.Shell") commande = "copiefichier.bat" oWsh.Run commande,0
est il possible, via encore un bout de script, d'utiliser ce .vbs afin de donner l'ordre au .bat de se lancer toute les 5 mn ?

pour info, ce .bat, copie un fichier dans un dossier, et envoie ce fichier en ftp sur une machine distante

merci de vos suggestions

Laurent
19/12/2013, 19h33
ProgElecT

Salut

Dans le planificateur de tâches, onglet Général il faut sûrement cocher Exécuter avec les autorisations maximales.

:salut:
Si vous avez encore des problèmes avec le plannificateur de tâches sur windows 7, vous pouvez tester ce vbscript en boucle avec une pause de 5 minutes :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Dim Ws,command,Execution
Set Ws = CreateObject("WScript.Shell")
command = "copiefichier.bat"
Do
	Execution = Ws.Run(Command,0,False)
	Pause(5) 'pause pour 5 minutes
Loop
'***************************************
Sub Pause(Min)
	WScript.Sleep 60*1000*Min
End Sub
'***************************************

et ce code pour savoir quels sont les scripts VBS en cours d'exécution :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Titre = " Processus "& qq("Wscript.exe") &" en cours d'exécution "
Set fso = CreateObject("Scripting.FileSystemObject")
Set sho = CreateObject( "Wscript.Shell" )
NomFichierLog="Processus VBScript.txt"
temp = sho.ExpandEnvironmentStrings("%temp%")
PathNomFichierLog = temp & "\" & NomFichierLog
Set OutPut = fso.CreateTextFile(temp & "\" & NomFichierLog,1)
count=0 
strComputer = "."
Call FindScript()
Call Explorer(PathNomFichierLog)
'***************************************************************************************************
Function Explorer(File)
	Set ws=CreateObject("wscript.shell")
	ws.run "Explorer "& File & "\",1,True
end Function
'***************************************************************************************************
Sub FindScript()
	Set colItems = GetObject("winmgmts:").ExecQuery("Select * from Win32_Process " _
	& "Where Name like '%wscript.exe%' AND NOT commandline like '%" & wsh.scriptname & "%'",,48)
	For Each objItem in colItems
		'MsgBox "Script : " & objItem.CommandLine,64,Titre
		count= count + 1
		Msgbox Mid(objItem.CommandLine,InStr(objItem.CommandLine,""" """) + 2),64,Titre
		OutPut.WriteLine Mid(objItem.CommandLine,InStr(objItem.CommandLine,""" """) + 2)
	Next
OutPut.WriteLine count & Titre 
End Sub
'***************************************************************************************************
Function qq(strIn)
	qq = Chr(34) & strIn & Chr(34)
End Function
'***************************************************************************************************

20/12/2013, 14h51
ctrl32

Merci à tous !!
j'ai vraiment été gâté !!

pour terminer j'ai besoins de fermer mon script que j'ai lancé en mode "invisible" :arf:
je pensais le trouver dans le gestionnaire de tâche mais non, que les services ou exe.... comment faire ?:boulet:

encore merci pour tes scripts, super sympa !!
20/12/2013, 14h55
ctrl32

:boulet:
euu, comment dire, ben ton script donnant le nombre de scripts en cours m' donné l'exe à tuer = > Wscript.exe
:oops:
20/12/2013, 16h46
ctrl32

scripts testé et approuvé, un vrai bonheur !!
une dernière chose avant clôture de cette discussion,
sans trop vouloir abuser, :mrgreen:
est il possible d'avoir, pour chaque ligne des scripts, une explication ?:kill:
20/12/2013, 16h57
hackoofr

Citation:

Envoyé par ctrl32

Est il possible d'avoir, pour chaque ligne des scripts, une explication ?:kill:

A condition ; il faut me payer cash avec cette devise :plusser: sinon, je laisse tomber :mouarf:

Nouvelle version plus sélective avec question !

:salut:
Voici une nouvelle version plus sélective avec question et commentée ligne par ligne :king:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Set fso = CreateObject("Scripting.FileSystemObject")'création de l'objet fso
Set ws = CreateObject("Wscript.Shell")'création de l'objet ws (objet shell)
NomFichierLog="Processus VBScript.txt" 'Nom du fichier Log
temp = ws.ExpandEnvironmentStrings("%temp%") 'Le chemin du dossier temporaire
PathNomFichierLog = temp & "\" & NomFichierLog'Le chemin du dossier temporaire avec le fichier Log
Set OutPut = fso.CreateTextFile(temp & "\" & NomFichierLog,1)'création du LogFile qui contient le résultat final
count=0 ' initialisation du compteur
strComputer = "." 'Notre ordinateur local
Call FindScript()'Appel de la fonction FindScript()
Call Explorer(PathNomFichierLog)'Appel de la fonction Explorer(PathNomFichierLog)
'***************************************************************************************************
Function Explorer(File)
    Set ws=CreateObject("wscript.shell")'création de l'objet ws (objet shell)
    ws.run "Explorer "& File & "\",1,True 'Ouvrir le fichier Log
end Function
'***************************************************************************************************
Sub FindScript()
    Titre = " Processus "& qq("wscript.exe")' Le Titre
'Trouver toutes les instances du processus "wscript.exe" sauf le mien
    Set colItems = GetObject("winmgmts:").ExecQuery("Select * from Win32_Process " _
    & "Where Name like '%wscript.exe%' AND NOT commandline like '%" & wsh.scriptname & "%'",,48)
    For Each objItem in colItems
        count= count + 1 ' incrémenter le compteur
        Processus = Mid(objItem.CommandLine,InStr(objItem.CommandLine,""" """) + 2) 'Extraction du chemin du script en ligne de commande
'et l'afficher dans un MsgBox
        Question = MsgBox ("Voulez-vous stopper ce script : "& Processus &" ?" ,VBYesNO+VbQuestion,Titre)
        If Question = VbYes then
            OutPut.WriteLine Processus 'Ecrire le même résultat dans le fichier Log
            objItem.Terminate(0)'Tuer ce processus
        else
            count= count - 1 'décrementer le compteur de -1
        End if
    Next
    OutPut.WriteLine String(50,"*") 'écrire une étoile "*" 50 fois
    OutPut.WriteLine count & Titre & " ont été arrêtés !"'Ecrire le compteur du script dans le fichier Log
    OutPut.WriteLine String(50,"*") 'écrire une étoile "*" 50 fois
End Sub
'***************************************************************************************************
'Fonction pour ajouter les doubles quotes dans une variable
Function qq(strIn)
    qq = Chr(34) & strIn & Chr(34)
End Function
'***************************************************************************************************

:salut:
une autre approche pour le 1er script, si vous fixiez le nombre maximale d'itération, donc, on peut utiliser une boucle For...Next

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
Dim Ws,command,Execution,NbMax,i 'Déclaration des variables
Set Ws = CreateObject("WScript.Shell")
command = "cmd /c calc.exe" 'commande pour lancer la calculatrice
NbMax = 10 'ici on a fixer le nombre Max d'itération à 10
For i = 1 To NbMax
	Execution = Ws.Run(Command,0,False)
	If NbMax > 10 Then 'si le nombre d'itération dépasse le Nombre Max alors 
'on sort de la boucle For
		Exit For
		Wscript.Quit ' et on quitte le script
	Else  'sinon 
		Pause(5) 'on fait une pause de 5 minutes
	End if
Next
'***************************************
Sub Pause(Min)
	WScript.Sleep 60*1000*Min
End Sub
'***************************************

20/12/2013, 23h59
ctrl32

Je paie cash :plusser::plusser::plusser: !!!:mrgreen:
vente et sav !
sincèrement un grand merci, que dire de plus...
@ la prochaine
Laurent